m3u generator

@ECHO OFF
SETLOCAL EnableDelayedExpansion
CLS

REM !!! SET THE PATHS HERE !!!
SET BasePath=%~dp0
SET PlaylistOutputPath=%~dp0
REM !!! SET THE PATHS HERE !!!

ECHO.
ECHO +--------------------------------------------------------
ECHO + Checking files in folders to make into playlists
ECHO +                                          Please wait...
ECHO +--------------------------------------------------------
ECHO.

REM ---------------
REM PROCESS FOLDERS
REM ---------------
SET COUNTFOLDERS=0
FOR /D %%A IN (*) DO (

	REM -------------
	REM SET VARIABLES
	REM -------------
	SET fullfoldername=%%A
	SET fulldir=!BasePath!%%A\

	SET /A COUNTFOLDERS+=1

	ECHO   MAKING PLAYLIST ^-^> !fullfoldername!.M3U
	CD !fullfoldername!
	ECHO #EXTM3U > "!PlaylistOutputPath!!fullfoldername!.M3U"
	FOR /F "tokens=*" %%B IN ('DIR /o:n /b *.flac *.mp3 ') DO (
		SET fullfilename=%%B
		SET filename=!fullfilename:~0,-4!
		SET filename1=!filename:,=!
		SET filename2=!filename1:^)=!
		SET filename3=!filename2:(=!
		SET filename4=!filename3:- =!

		REM ECHO !fullfilename!
		ECHO #EXTINF:,!filename4! >> "!PlaylistOutputPath!!fullfoldername!.M3U"
		ECHO !fullfoldername!\%%B >> "!PlaylistOutputPath!!fullfoldername!.M3U"
	)
	CD ..

)
ECHO.
IF %COUNTFOLDERS%==0 ( ECHO    NO FOLDERS FOUND... )
IF NOT %COUNTFOLDERS%==0 ( ECHO    %COUNTFOLDERS% FOLDERS PROCESSED... )

ECHO.
ECHO.

REM -----------------
REM CREATE TV.TXT - A Complete listing of all folders and files
REM -----------------
ECHO   MAKING "!BasePath!LIST.TXT" ^-^> A Complete listing of all folders and files
TREE /A /F > "!BasePath!LIST.TXT"

ENDLOCAL
ECHO.
ECHO.

ECHO Press ANY KEY to EXIT...
PAUSE >nul