Rolnik_Menu_v-1.6

;Nazwa: Rolnik_Menu_v-1.6.txt
;Autor: Janusz [Fris]
;======================================
set %Max_waga ( #MAXWEIGHT * 2 ) - 40
set %Click_Przerwij_X 187
set %Click_Przerwij_Y 165
set %RedColor 1080      ;czerwony
set %BlueColor 88       ;niebieski
set %YellowColor 53     ;zolty
set #lpc 200
menu hideEUO
menu clear
menu window color btnface
menu window size 210 120
menu window title Rolnik 1.6
;========================================
menu font size 8
menu text mtmiasto 10 1 Co zrywac.
menu font size 10
menu font bgcolor white
menu combo create mcprodukt 10 20 190
menu combo add mcprodukt Pszenica
menu combo add mcprodukt Kukurydza
menu combo add mcprodukt Marchewka
menu combo add mcprodukt Cebula
menu combo add mcprodukt Len
menu combo add mcprodukt Bawelna
menu combo add mcprodukt Dynia
menu combo add mcprodukt Arbuz
menu combo add mcprodukt Rzepa
menu combo add mcprodukt Salata
menu combo add mcprodukt Kapusta
menu combo add mcprodukt Chmiel
menu combo add mcprodukt --------- Owoce ---------
menu combo add mcprodukt Jablka
menu combo add mcprodukt Brzoskwinia
menu combo add mcprodukt Cytryna
menu combo add mcprodukt Gruszka
menu combo add mcprodukt Cytrus
menu combo add mcprodukt Banany
menu combo add mcprodukt Kokosy
menu combo select mcprodukt 1
;------------------- Pole szukania ----------------
menu font bgcolor btnface
menu font size 8
menu text mtmiasto 10 56 Pole szukania.
menu Edit mePoleSz 100 52 25 20
menu font bgcolor btnface
menu font size 9
;=================== przyciski =================
menu font color green
menu font style b
menu font bgcolor btnface
menu button mbstart 10 85 60 24 Start
menu font color black
menu button mbstop 140 85 60 24 Stop
;===============================================
menu show
set #lpc 10
set #menubutton N/A
repeat
    if #menubutton = mbstart
      {
      set #menubutton N/A
      menu delete mbstart

      menu get mcprodukt
      set %nr_produktu #menures
      if %nr_produktu = 1
         set %Roslina pszenica
      if %nr_produktu = 2
         set %Roslina kukurydza
      if %nr_produktu = 3
         set %Roslina marchewka
      if %nr_produktu = 4
         set %Roslina cebula
      if %nr_produktu = 5
         set %Roslina len
      if %nr_produktu = 6
         set %Roslina bawelna
      if %nr_produktu = 7
         set %Roslina dynia
      if %nr_produktu = 8
         set %Roslina arbuz
      if %nr_produktu = 9
         set %Roslina rzepa
      if %nr_produktu = 10
         set %Roslina salata
      if %nr_produktu = 11
         set %Roslina kapusta
      if %nr_produktu = 12
         set %Roslina chmiel
      if %nr_produktu = 13
      {
         Display ok Wybierz warzywo lub owoc.
         gosub Rysuj_przycisk_start
         goto petla
      }
      if %nr_produktu = 14
         set %Roslina jablon
      if %nr_produktu = 15
         set %Roslina brzoskwinia
      if %nr_produktu = 16
         set %Roslina cytrynowe
      if %nr_produktu = 17
         set %Roslina grusza
      if %nr_produktu = 18
         set %Roslina cytrus
      if %nr_produktu = 19
         set %Roslina bananowiec
      if %nr_produktu = 20
         set %Roslina palma
      menu get mePoleSz
      set %Max_odleglosc #menures
      gosub SkanujTeren
      gosub MainLoop
      }
    if #menubutton = CLOSED ;wcisnieto przycisk X
       {
       menu hide
       set #menubutton N/A
       halt
       }
    petla:
until #false
;============================================
sub SkanujTeren
  set #lpc 4000
  set #sysmsgcol %YellowColor
  if %nr_produktu < 13
  {
     event sysmessage Szukam warzyw...
  }
  else
  {
     event sysmessage Szukam owocow...
  }
  tile Init
  set %x_poczatek #charposx - %Max_odleglosc
  set %y_poczatek #charposy - %Max_odleglosc
  set %x_koniec #charposx + %Max_odleglosc
  set %y_koniec #charposy + %Max_odleglosc
  set %licznik 0
  for %x %x_poczatek %x_koniec
    {
    for %y %y_poczatek %y_koniec
      {
      tile Cnt %x %y
      for %i 1 #tilecnt
        {
        tile Get %x %y %i
        if %Roslina in #tilename ;&& ( Background in #tileflags || #tileflags = %null )
          { ;ustawia tablice poletak z warzywami
          set %licznik %licznik + 1
          set %_x . %licznik %x ;tworzenie tablicy
          set %_y . %licznik %y ;tworzenie tablicy
          set %_z . %licznik #tilez ;tworzenie tablicy
          set %_tt . %licznik #tiletype
          break
          }
        }
      }
    }
  set #lpc 10
return
;----------------------------------------------------------------
sub MainLoop
  set #lpc 10
  set #sysmsgcol %YellowColor
  if %nr_produktu < 13
  {
     event sysmessage Znaleziono %licznik warzyw.
  }
  else
  {
     event sysmessage Znaleziono %licznik drzewek owocowych.
  }
  for %j 1 %licznik
  {
      gosub Podejdz_do_rosliny %_x . %j %_y . %j %_z . %j
      gosub Zrywaj_rosliny %_x . %j %_y . %j %_z . %j %_tt . %j
      if #RESULT = PetlaPrzyciskow
      {
         break
      }
  }
  set #sysmsgcol %YellowColor
  event sysmessage Wszystkie warzywa zerwane. KONIEC.
  gosub ZerujTablice
  gosub Rysuj_przycisk_start
return
;--------------------------------------------------
sub Podejdz_do_rosliny
  set %krzaczek_x %1
  set %krzaczek_y %2
  set %krzaczek_z %3

  if %nr_produktu < 13
  {
     move %krzaczek_x %krzaczek_y 0 5s
  }
  else
  {
     move %krzaczek_x %krzaczek_y 1 5s
  }
  if #CHARPOSX <> %krzaczek_x && #CHARPOSY <> %krzaczek_y
     {
      set %czas #scnt + 6
      event pathfind %krzaczek_x %krzaczek_y %krzaczek_z
      repeat
        if %czas < #scnt
        {
           set %czas #scnt + 6
           event pathfind %krzaczek_x %krzaczek_y %krzaczek_z
        }
        gosub CzyJestemNaPozycji
        if #RESULT = NaMiejscu
        {
           set #lpc 10
           return
        }
        scanjournal 1
        if _Can't_get_there in #journal || stoisz_za_daleko in #journal || _That_is_too in #journal
        {
            if %nr_produktu < 13
            {
               move %krzaczek_x %krzaczek_y 0 5s
            }
            else
            {
               move %krzaczek_x %krzaczek_y 1 5s
            }
            return
        }
      until #CHARPOSX = %krzaczek_x && #CHARPOSY = %krzaczek_y
     }
return
;--------------------------------------------------
sub Zrywaj_rosliny
  set #ltargetx %1
  set #ltargety %2
  set #ltargetz %3
  set #ltargetkind 3
  set #ltargettile %4
  set %WyjdzZPetli 0

  finditem fuo C_ , #charid
  if #findkind = -1
  {
    finditem fuo C_ , #backpackid
    if #findkind = -1
       {
       set #sysmsgcol %RedColor
       event sysmessage Nie masz Sierpu!!!
       gosub Rysuj_przycisk_start
       return PetlaPrzyciskow
       }
    else
        {
        set #lobjectid #findid
        event macro 17
        repeat
           finditem fuo C_ , #charid
        until #findkind <> -1
        }
  }

  set #sysmsgcol %YellowColor
  if %nr_produktu < 13
  {
     event sysmessage Zaczynam scinac rosline...
  }
  else
  {
     event sysmessage Zaczynam obcinac drzewko...
  }

  set %jindex #jindex
  set #lobjectid #findid
  event macro 17
  set %TimeSierp #scnt2 + 10

  repeat
     if %TimeSierp < #scnt2
     {
        set #lobjectid #findid
        event macro 17
        set %TimeSierp #scnt2 + 10
     }
  until #targcurs = 1

  event macro 22
  set %TimeCel #scnt2 + 50

  repeat
     if %TimeCel < #scnt2
     {
        event macro 22
        set %TimeCel #scnt2 + 50
     }
     scanjournal 1
     if Nie_widzisz_tego in #journal
     {
        return PetlaPrzyciskow
     }
  until Scinasz_rosline in #journal

  repeat
     set %ji #jindex - %jindex
     set #lpc 2000
     for %i 1 %ji
     {
         if %Max_waga < #WEIGHT || %Max_waga = #WEIGHT
         {
            click %Click_Przerwij_X %Click_Przerwij_Y
            Display ok $Osiagneles/as maksymalny udzwig. $Skrypt wylaczony.
            gosub ZerujTablice
            return PetlaPrzyciskow
         }
         if #menubutton = mbstop
         {
            set #menubutton N/A
            click %Click_Przerwij_X %Click_Przerwij_Y
            gosub ZerujTablice
            gosub Rysuj_przycisk_start
            set #sysmsgcol %RedColor
            event sysmessage Skrypt zatrzymany.
            return PetlaPrzyciskow
         }
         scanjournal %i
         if Nie_masz_miejsca_w_plecaku in #journal
         {
            click %Click_Przerwij_X %Click_Przerwij_Y
            Display ok $Juczniak/Plecak pelny. $Skrypt wylaczony.
            gosub ZerujTablice
            return PetlaPrzyciskow
         }
         if Z_tej_rosliny_juz_nic_wiecej_nie_wytniesz. in #journal || Tego_nie_mozesz_obciac in #journal || Prawie_cos_wycial in #journal
         {
            set %WyjdzZPetli 1
            break
         }
     }
     if %WyjdzZPetli = 1
     {
         set %WyjdzZPetli 0
         break
     }
  until #false
  set #lpc 10
return
;--------------------------------------------------
sub Rysuj_przycisk_start
  set #menubutton N/A
  menu font color green
  menu font style b
  menu font bgcolor btnface
  menu button mbstart 10 85 60 24 Start
return
;--------------------------------------------------
sub ZerujTablice
set #lpc 4000
for %j 1 %licznik
    {
    set %_x . %j
    set %_y . %j
    set %_z . %j
    set %_tt . %j
    }
set #lpc 10
return
;--------------------------------------------------
sub CzyJestemNaPozycji
  if %krzaczek_x > #CHARPOSX && %krzaczek_y = #CHARPOSY ;drzewo na wschod
  {
     set %Cel_x %krzaczek_x - 1
     set %Cel_y %krzaczek_y
     if %Cel_x = #CHARPOSX && %Cel_y = #CHARPOSY
     {
        return NaMiejscu
     }
  }
  if %krzaczek_x > #CHARPOSX && %krzaczek_y < #CHARPOSY ;drzewo na polnocny wschod
  {
     set %Cel_x %krzaczek_x - 1
     set %Cel_y %krzaczek_y + 1
     if %Cel_x = #CHARPOSX && %Cel_y = #CHARPOSY
     {
        return NaMiejscu
     }
  }
  if %krzaczek_x > #CHARPOSX && %krzaczek_y > #CHARPOSY ;drzewo na poludniowy wschod
  {
     set %Cel_x %krzaczek_x - 1
     set %Cel_y %krzaczek_y - 1
     if %Cel_x = #CHARPOSX && %Cel_y = #CHARPOSY
     {
        return NaMiejscu
     }
  }
  if %krzaczek_x = #CHARPOSX && %krzaczek_y > #CHARPOSY ;drzewo poludnie
  {
     set %Cel_x %krzaczek_x
     set %Cel_y %krzaczek_y - 1
     if %Cel_x = #CHARPOSX && %Cel_y = #CHARPOSY
     {
        return NaMiejscu
     }
  }
  if %krzaczek_x < #CHARPOSX && %krzaczek_y > #CHARPOSY ;drzewo poludniowy zachod
  {
     set %Cel_x %krzaczek_x + 1
     set %Cel_y %krzaczek_y - 1
     if %Cel_x = #CHARPOSX && %Cel_y = #CHARPOSY
     {
        return NaMiejscu
     }
  }
  if %krzaczek_x < #CHARPOSX && %krzaczek_y = #CHARPOSY ;drzewo na zachod
  {
     set %Cel_x %krzaczek_x + 1
     set %Cel_y %krzaczek_y
     if %Cel_x = #CHARPOSX && %Cel_y = #CHARPOSY
     {
        return NaMiejscu
     }
  }
  if %krzaczek_x < #CHARPOSX && %krzaczek_y < #CHARPOSY ;drzewo na zachodni polnoc
  {
     set %Cel_x %krzaczek_x + 1
     set %Cel_y %krzaczek_y + 1
     if %Cel_x = #CHARPOSX && %Cel_y = #CHARPOSY
     {
        return NaMiejscu
     }
  }
  if %krzaczek_x = #CHARPOSX && %krzaczek_y < #CHARPOSY ;drzewo na polnoc
  {
     set %Cel_x %krzaczek_x
     set %Cel_y %krzaczek_y + 1
     if %Cel_x = #CHARPOSX && %Cel_y = #CHARPOSY
     {
        return NaMiejscu
     }
  }
return