Christmas Lights Nov 29

#include <Adafruit_NeoPixel.h>
#ifdef __AVR__
  #include <avr/power.h>
#endif

#define PIN 16

// Parameter 1 = number of pixels in strip
// Parameter 2 = Arduino pin number (most are valid)
// Parameter 3 = pixel type flags, add together as needed:
//   NEO_KHZ800  800 KHz bitstream (most NeoPixel products w/WS2812 LEDs)
//   NEO_KHZ400  400 KHz (classic 'v1' (not v2) FLORA pixels, WS2811 drivers)
//   NEO_GRB     Pixels are wired for GRB bitstream (most NeoPixel products)
//   NEO_RGB     Pixels are wired for RGB bitstream (v1 FLORA pixels, not v2)
Adafruit_NeoPixel strip = Adafruit_NeoPixel(300, PIN, NEO_GRB + NEO_KHZ800);
long randNumber;

// IMPORTANT: To reduce NeoPixel burnout risk, add 1000 uF capacitor across
// pixel power leads, add 300 - 500 Ohm resistor on first pixel's data input
// and minimize distance between Arduino and first pixel.  Avoid connecting
// on a live circuit...if you must, connect GND first.

void setup() {

  randomSeed(analogRead(2));
  strip.begin();
  strip.show(); // Initialize all pixels to 'off'
}

void loop() {
  christmasLights(); // I wrote this pattern.
  colorWipe(strip.Color(255, 0, 0), 2); // Red
  unWipe(2); // I wrote this unwipe routine.
  colorWipe(strip.Color(0, 255, 0), 2); // Green
  unWipe(2);
  colorWipe(strip.Color(0, 0, 255), 2); // Blue
  unWipe(2);
  // I wrote this routine below, it's kind of ugly, but functional.
  colorBricks(strip.Color(random(255), random(255), random(255)),strip.Color(random(255), random(255), random(255)));
  colorBricks(strip.Color(random(255), random(255), random(255)),strip.Color(random(255), random(255), random(255)));
  colorBricks(strip.Color(random(255), random(255), random(255)),strip.Color(random(255), random(255), random(255)));
  colorBricks(strip.Color(random(255), random(255), random(255)),strip.Color(random(255), random(255), random(255)));
  theaterChase(strip.Color(127, 127, 127), 75); // White
  theaterChase(strip.Color(127, 0, 0), 75); // Red
  theaterChase(strip.Color(0, 127, 0), 75); // Blue

  rainbow(15);
  rainbowCycle(5);
  theaterChaseRainbow(60);
}

void christmasLights() {
for (uint16_t loopy=0; loopy<26; loopy++) {
  for (uint16_t i=0; i<strip.numPixels(); i+=5) {
    strip.setPixelColor(i,strip.Color(255,0,0)); // Red
  }
  for (uint16_t i=1; i<strip.numPixels(); i+=5) {
    strip.setPixelColor(i,strip.Color(0,255,0)); // Green
  }
  for (uint16_t i=2; i<strip.numPixels(); i+=5) {
    strip.setPixelColor(i,strip.Color(0,0,255)); // Blue
  }
  for (uint16_t i=3; i<strip.numPixels(); i+=5) {
    strip.setPixelColor(i,strip.Color(200,100,0)); // Orange
  }
  for (uint16_t i=4; i<strip.numPixels(); i+=5) {
    strip.setPixelColor(i,strip.Color(128,0,128)); // Red
  }
  strip.show();
  delay(500);
  for (uint16_t i=0; i<strip.numPixels(); i++) {
    strip.setPixelColor(i,strip.Color(0,0,0)); // Blank
  }
  strip.show();
  delay(500);
}
}


// Fill the dots one after the other with a color
void colorWipe(uint32_t c, uint8_t wait) {
  for(uint16_t i=0; i<strip.numPixels(); i++) {
    strip.setPixelColor(i, c);
    strip.show();
    delay(wait);
  }
}

void colorBricks(uint32_t c1, uint32_t c2) {
  uint16_t backwards=strip.numPixels();
  for(uint16_t forwards=0; forwards<strip.numPixels(); forwards++) {
    if (backwards<299) strip.setPixelColor(backwards+1, 0);
    if (forwards>0) strip.setPixelColor(forwards-1, 0);
    strip.setPixelColor(forwards, c1);
    strip.setPixelColor(backwards, c2);
    strip.setPixelColor(forwards+1, c1);
    strip.setPixelColor(backwards-1, c2);
    strip.setPixelColor(forwards+2, c1);
    strip.setPixelColor(backwards-2, c2);
    strip.setPixelColor(forwards+3, c1);
    strip.setPixelColor(backwards-3, c2);
    strip.setPixelColor(backwards-4, c2);
    strip.setPixelColor(forwards+4, c1);
    strip.show();
    backwards--;
    delay(2);
  }
  strip.setPixelColor(299,0);
}

void unWipe(uint8_t wait) {
  for(uint16_t i=strip.numPixels(); i>0; i--) {
    strip.setPixelColor(i, 0);
    strip.show();
    delay(wait);
  }
}
void rainbow(uint8_t wait) {
  uint16_t i, j;

  for(j=0; j<256; j++) {
    for(i=0; i<strip.numPixels(); i++) {
      strip.setPixelColor(i, Wheel((i+j) & 255));
    }
    strip.show();
    delay(wait);
  }
}

// Slightly different, this makes the rainbow equally distributed throughout
void rainbowCycle(uint8_t wait) {
  uint16_t i, j;

  for(j=0; j<256*5; j++) { // 5 cycles of all colors on wheel
    for(i=0; i< strip.numPixels(); i++) {
      strip.setPixelColor(i, Wheel(((i * 256 / strip.numPixels()) + j) & 255));
    }
    strip.show();
    delay(wait);
  }
}

//Theatre-style crawling lights.
void theaterChase(uint32_t c, uint8_t wait) {
  for (int j=0; j<30; j++) {  //do 10 cycles of chasing
    for (int q=0; q < 5; q++) {
      for (int i=0; i < strip.numPixels(); i=i+5) {
        strip.setPixelColor(i+q, c);    //turn every third pixel on
      }
      strip.show();

      delay(wait);

      for (int i=0; i < strip.numPixels(); i=i+5) {
        strip.setPixelColor(i+q, 0);        //turn every third pixel off
      }
    }
  }
}

//Theatre-style crawling lights with rainbow effect
void theaterChaseRainbow(uint8_t wait) {
  for (int j=0; j < 256; j++) {     // cycle all 256 colors in the wheel
    for (int q=0; q < 5; q++) {
      for (int i=0; i < strip.numPixels(); i=i+5) {
        strip.setPixelColor(i+q, Wheel( (i+j) % 255));    //turn every third pixel on
      }
      strip.show();

      delay(wait);

      for (int i=0; i < strip.numPixels(); i=i+5) {
        strip.setPixelColor(i+q, 0);        //turn every third pixel off
      }
    }
  }
}

// Input a value 0 to 255 to get a color value.
// The colours are a transition r - g - b - back to r.
uint32_t Wheel(byte WheelPos) {
  WheelPos = 255 - WheelPos;
  if(WheelPos < 85) {
    return strip.Color(255 - WheelPos * 3, 0, WheelPos * 3);
  }
  if(WheelPos < 170) {
    WheelPos -= 85;
    return strip.Color(0, WheelPos * 3, 255 - WheelPos * 3);
  }
  WheelPos -= 170;
  return strip.Color(WheelPos * 3, 255 - WheelPos * 3, 0);
}