NMM_MACD

#property indicator_separate_window
#property indicator_buffers 2
#property indicator_color1 Magenta
#property indicator_color2 Silver
#property indicator_level1 0
#property indicator_levelcolor Gray
#property indicator_levelstyle 2

extern int     NMM_MACD_period  = 40;
extern bool    Show_SD          = true;
extern int     SD_len           = 30;
extern double  SD_up            = 2;
extern double  SD_dn            = 2;

double NMM_MACD[];
double SD[];
double NMM[];
double NMM_MA[];

int init()
{
  string nmmmacdname = "NMM_MACD(" + NMM_MACD_period + ")";
  string sdname = "NMM_MACD_SD(" + SD_len + ")";
  IndicatorShortName(nmmmacdname);
  IndicatorBuffers(4);
  SetIndexBuffer(0, NMM_MACD);
  SetIndexLabel(0, nmmmacdname);
  SetIndexBuffer(1, SD);
  SetIndexLabel(1, sdname);
  SetIndexBuffer(2, NMM);
  SetIndexBuffer(3, NMM_MA);
  return(0);
}

int start()
{
  int limit, i, ii, counted_bars = IndicatorCounted();
  double nmm2, sum, abssum, ratio;

  if(Bars <= 2*NMM_MACD_period) return(0);
  if(counted_bars < 0) counted_bars = 0;
  if(counted_bars > NMM_MACD_period) limit = Bars - counted_bars;
  else                               limit = Bars - NMM_MACD_period - 1;

  for(i = limit; i >= 0; i--)
    {
    nmm2 = 0;
    for(ii = 1; ii <= NMM_MACD_period; ii++)
      nmm2 += (MathLog(Close[i]) - MathLog(Close[i+ii])) / MathSqrt(ii);
    NMM[i] = (nmm2 / NMM_MACD_period)  * 1000;
    }

  for(i = limit; i >= 0; i--)
    if(i < Bars - 2*NMM_MACD_period - 1)
      {
      ratio = 0;
      sum = (NMM[i] - NMM[i+1]) + (NMM[i+1] - NMM[i+2]) * (MathSqrt(2)-1);
      for(ii = 2; ii < NMM_MACD_period; ii++)
        sum += (NMM[i+ii] - NMM[i+ii+1]) * (MathSqrt(ii+1) - MathSqrt(ii));
      abssum = MathAbs(sum);
      sum = 0;
      for(ii = 0; ii < NMM_MACD_period; ii++)
        sum += MathAbs(NMM[i+ii] - NMM[i+ii+1]);
      if(sum != 0) ratio = abssum / sum;
      NMM_MA[i] = NMM_MA[i+1] + (NMM[i] - NMM_MA[i+1]) * ratio;
      NMM_MACD[i] = NMM[i] - NMM_MA[i];
      }

  if(Show_SD)
    for(i = limit; i >= 0; i--)
      if(i < Bars - 2*NMM_MACD_period - 1 - SD_len)
        {
        if(NMM_MACD[i] == 0)     SD[i] = 0;
        else if(NMM_MACD[i] > 0) SD[i] = iBandsOnArray(NMM_MACD, 0, SD_len, SD_up, 0, MODE_UPPER, i);
        else if(NMM_MACD[i] < 0) SD[i] = iBandsOnArray(NMM_MACD, 0, SD_len, SD_dn, 0, MODE_LOWER, i);
        }

  return(0);
}