Achievements.inc

/*
ShowPlayerAchievement Include by SynonymousZ
native ShowPlayerAchievement(playerid, a_Name[], a_Text[], time = 5000, a_Pic[] = "", a_Title[] = "Neues Ereignis!");
*/
#include <a_samp>

#if defined _SPA_inc
    #endinput
#endif
#define _SPA_inc

new Text:A_TD[2];
new PlayerText:A_P_TD[MAX_PLAYERS][4];
new bool:A_Active[MAX_PLAYERS] = false;

forward SPA_OnGameModeInit();
public OnGameModeInit()
{
    A_TD[0] = TextDrawCreate(489.262268, 315.333251, "BG");
    TextDrawLetterSize(A_TD[0], 0.000000, 12.700927);
    TextDrawTextSize(A_TD[0], 150.269393, 0.000000);
    TextDrawAlignment(A_TD[0], 1);
    TextDrawUseBox(A_TD[0], true);
    TextDrawBoxColor(A_TD[0], 255);

    A_TD[1] = TextDrawCreate(474.737884, 334.583343, "Line");
    TextDrawLetterSize(A_TD[1], 0.000000, -0.381479);
    TextDrawTextSize(A_TD[1], 165.730606, 0.000000);
    TextDrawAlignment(A_TD[1], 1);
    TextDrawUseBox(A_TD[1], true);
    TextDrawBoxColor(A_TD[1], 16777215);
    CallLocalFunction("SPA_OnGameModeInit","");
}
#if defined _ALS_OnGameModeInit
    #undef OnGameModeInit
#else
    #define _ALS_OnGameModeInit
#endif
#define OnGameModeInit SPA_OnGameModeInit

stock ShowPlayerAchievement(playerid, a_Name[], a_Text[], time = 5000, a_Pic[] = "", a_Title[] = "Neues Ereignis!")
{
    if(A_Active[playerid])return -1;
    A_Active[playerid] = true;
    TextDrawShowForPlayer(playerid, A_TD[0]);
    TextDrawShowForPlayer(playerid, A_TD[1]);
    A_P_TD[playerid][0] = CreatePlayerTextDraw(playerid, 260.497802, 315.000030, a_Title);
    PlayerTextDrawLetterSize(playerid, A_P_TD[playerid][0], 0.449999, 1.600000);
    PlayerTextDrawAlignment(playerid, A_P_TD[playerid][0], 1);
    PlayerTextDrawColor(playerid, A_P_TD[playerid][0], 65535);
    PlayerTextDrawBackgroundColor(playerid, A_P_TD[playerid][0], 51);

    A_P_TD[playerid][1] = CreatePlayerTextDraw(playerid, 168.199111, 335.416748, a_Name);
    PlayerTextDrawLetterSize(playerid, A_P_TD[playerid][1], 0.343177, 1.600000);
    PlayerTextDrawAlignment(playerid, A_P_TD[playerid][1], 1);
    PlayerTextDrawColor(playerid, A_P_TD[playerid][1], -65281);
    PlayerTextDrawBackgroundColor(playerid, A_P_TD[playerid][1], 51);

    A_P_TD[playerid][2] = CreatePlayerTextDraw(playerid, 168.199111, 359.916717, a_Text);
    PlayerTextDrawLetterSize(playerid, A_P_TD[playerid][2], 0.267276, 1.395832);
    PlayerTextDrawAlignment(playerid, A_P_TD[playerid][2], 1);
    PlayerTextDrawColor(playerid, A_P_TD[playerid][2], -1);
    PlayerTextDrawBackgroundColor(playerid, A_P_TD[playerid][2], 51);

    if(strlen(a_Pic))
    {
        A_P_TD[playerid][3] = CreatePlayerTextDraw(playerid, 416.515563, 353.500061, a_Pic);
        PlayerTextDrawTextSize(playerid, A_P_TD[playerid][3], 55.754013, 51.916625);
        PlayerTextDrawAlignment(playerid, A_P_TD[playerid][3], 1);
        PlayerTextDrawUseBox(playerid, A_P_TD[playerid][3], true);
        PlayerTextDrawFont(playerid, A_P_TD[playerid][3], 4);
        PlayerTextDrawShow(playerid, A_P_TD[playerid][3]);
    }
    PlayerTextDrawShow(playerid, A_P_TD[playerid][0]);
    PlayerTextDrawShow(playerid, A_P_TD[playerid][1]);
    PlayerTextDrawShow(playerid, A_P_TD[playerid][2]);

    SetTimerEx("@a_UnShow", time, false, "i", playerid);
    return 1;
}
@a_UnShow(playerid);
@a_UnShow(playerid)
{
    TextDrawHideForPlayer(playerid, A_TD[0]);
    TextDrawHideForPlayer(playerid, A_TD[1]);
    for(new i = 0; i<3; i++)PlayerTextDrawDestroy(playerid, A_P_TD[playerid][i]);
    if(A_P_TD[playerid][3])PlayerTextDrawDestroy(playerid, A_P_TD[playerid][3]);
    A_Active[playerid] = false;
    return 1;
}