#debug 5
#######################################
#                                     #
# Edit these Variables before starting#
#                                     #
#######################################

if "$charactername" = "Nebby" then {
var container1 backpack
var container2 carrying bag
var container3 peddler's kit
var dismantle thump
var mode %1
}


#######################################

###########
action var multi_trap ON when is not yet fully disarmed
action var multi_lock ON when discover another lock protecting

var multi_trap ON
var multi_lock ON
var container_check Container_check1
#####################
#main body of script#
#####################
Main:

	gosub %container_check

	Disarm_sub:
		gosub disarm_ID
		gosub disarm
	if "%multi_trap" = "ON" then goto disarm_sub

	Lock_sub:
		gosub pick_ID
		gosub pick_anal
	if "%multi_lock" = "ON" then goto lock_sub

	Loot_sub:
		gosub loot
		gosub dismantle
		goto main

####################
#Container checking#
####################

	Container_check1:
		var container_check Container_check1
		var current_container %container1
		matchre get_For_Disarm (coffer|trunk|chest|strongbox|skippet|caddy|crate|casket|box)
		match container_Check2 Encumbrance
		put rummage my %container1;enc
		matchwait

	container_Check2:
		var container_check Container_check2
		var current_container %container2
		matchre get_For_Disarm (coffer|trunk|chest|strongbox|skippet|caddy|crate|casket|box)
		match container_Check3 Encumbrance
		put look in my %container2;enc
		matchwait

	container_Check3:
		var container_check Container_check3
		var current_container %container3
		matchre get_For_Disarm (coffer|trunk|chest|strongbox|skippet|caddy|crate|casket|box)
		match done Encumbrance
		put look in my %container3;enc
		matchwait

	get_For_Disarm:
		var disarmit $1
		get_Box:
			var LAST get_Box
			matchre PAUSE ^\.\.\.wait|^Sorry, you may only type
			matchre return You get|You are already
			put get %disarmit from my %current_container
			matchwait


#############################
#Disarming section of Script#
#############################

Disarmmain:

	disarm_ID:
		var LAST disarm_ID
		matchre PAUSE ^\.\.\.wait|^Sorry, you may only type
		match disarm_ID fails to reveal to you
		matchre return You guess it is already disarmed|Surely any fool|Even your memory can not be that short|Roundtime|Somebody has already located
		#matchre return coffer|trunk|chest|strongbox|skippet|caddy|crate|casket|box
		put disarm ID
		matchwait

	disarm:
		var multi_trap OFF

	disarmIt_Cont:
		var LAST disarmIt_Cont
		matchre PAUSE ^\.\.\.wait|^Sorry, you may only type
		matchre return You are certain the %disarmit is not trapped|Roundtime|You guess it is already disarmed|DISARM HELP for syntax help
		matchre disarmIt_Cont fumbling fails to disarm|This is not likely to be a good thing|unable to make any progress
	put disarm %mode
	matchwait



###########################
#Picking section of script#
###########################

Pickmain:

	pick_ID:
		var LAST pick_ID
		matchre PAUSE ^\.\.\.wait|^Sorry, you may only type
		matchre disarm_ID However,
		matchre pick_ID fails to teach you anything about the lock guarding it|just broke
		matchre return Somebody has already|not even locked|Roundtime
		put pick ID
		matchwait

	pick_anal:
	var multi_lock OFF
	var LAST pick_anal
		matchre PAUSE ^\.\.\.wait|^Sorry, you may only type
		matchre pick_Cont Roundtime|has already helpfully been analyzed|not even locked
		put pick anal
		matchwait

	pick_Cont:
	var LAST pick_Cont
		matchre PAUSE ^\.\.\.wait|^Sorry, you may only type
		match pick_cont You are unable to make
		matchre return With a soft click|not even locked|Roundtime
		put pick quick
		matchwait


####################################
#Loot & Dismantle section of script#
####################################

Lootmain:

	Loot:
		open_Box:
		var LAST open_Box
			matchre PAUSE ^\.\.\.wait|^Sorry, you may only type
			match fill_gem_pouch open
			put open my %disarmit
			matchwait

		fill_Gem_Pouch:
		var LAST fill_Gem_Pouch
			matchre PAUSE ^\.\.\.wait|^Sorry, you may only type
			matchre get_coin You take|any gems|anything else|You open your|You fill
			put fill my gem pouch with my %disarmit
			matchwait

		get_Coin:
		var LAST get_Coin
			matchre PAUSE ^\.\.\.wait|^Sorry, you may only type
			matchre get_Coin You pick up
			match return What were you
			put get coin from my %disarmit
			matchwait

	Dismantle:
		var LAST dismantle
		matchre PAUSE ^\.\.\.wait|^Sorry, you may only type
		match return Roundtime
		match dismantle next 15 seconds.
		put disman my %disarmit %dismantle
		matchwait

######################

return:
	return

pause:
	pause
	goto %LAST
done:
	pause 1
	put glance
exit

#######################