API tools faq
paste
Advertisement
name22

ToolTipEx UDF

name22
Jun 29th, 2011
269
0
Never
Add comment
Not a member of Pastebin yet? Sign Up, it unlocks many cool features!
AutoIt 18.03 KB | None | 0 0
raw download clone embed print report
  1. #include-once
  2.  
  3. ; #INDEX# =======================================================================================================================
  4. ; Title .........: ToolTipEx
  5. ; AutoIt Version : 3.3.6+
  6. ; Language ......: Deutsch
  7. ; Description ...: Funktionen für einen alternativen ToolTip.
  8. ; Author ........: name22 (autoit.de)
  9. ; ===============================================================================================================================
  10.  
  11. ; #CURRENT# =====================================================================================================================
  12. ;_ToolTip_Create
  13. ;_ToolTip_BGSetColor
  14. ;_ToolTip_TextSetColor
  15. ;_ToolTip_BorderSetColor
  16. ;_ToolTip_BorderSetWidth
  17. ;_ToolTip_FontSetOptions
  18. ; ===============================================================================================================================
  19.  
  20. ; #INTERNAL_USE_ONLY# ===========================================================================================================
  21. ;__ToolTip_Shutdown
  22. ;__ToolTip_ReDraw
  23. ; ===============================================================================================================================
  24.  
  25. #include <GDIP.au3>
  26. #include <WinApi.au3>
  27. #include <WindowsConstants.au3>
  28.  
  29. OnAutoItExitRegister("__ToolTip_Shutdown")
  30.  
  31. Global $hBitmap_Tip, $hBuffer_Tip, $iRadius_Tip = 3, $iWidth_Win, $iHeight_Win
  32.  
  33. $hWnd_Tip = GUICreate("", 100, 100, Default, Default, BitOR(0x80000000, 0x08000000), BitOR(0x00080000, 0x00000008, 0x00000080))
  34.  
  35. _GDIPlus_Startup()
  36.  
  37. $hFormat_Tip = _GDIPlus_StringFormatCreate()
  38. $hFamily_Tip = _GDIPlus_FontFamilyCreate("Arial")
  39. $hFont_Tip = _GDIPlus_FontCreate($hFamily_Tip, 10)
  40.  
  41. $hGraphic_Tip = _GDIPlus_GraphicsCreateFromHWND($hWnd_Tip)
  42. _GDIPlus_GraphicsSetSmoothingMode($hGraphic_Tip, 2)
  43. _GDIPlus_GraphicsSetTextRenderingHint($hGraphic_Tip, 3)
  44.  
  45. $hBrush_BG_Tip = _GDIPlus_BrushCreateSolid(0xD0202020)
  46. $hBrush_Text_Tip = _GDIPlus_BrushCreateSolid(0xE0E0E0E0)
  47. $hBrush_Hatch_Tip = _GDIPlus_HatchBrushCreate($HatchStyleCross, 0xD0D0D0D0, 0xD0F0F0F0)
  48. $hPen_Border_Tip = _GDIPlus_PenCreate(0xE0E57913, 2)
  49.  
  50. $hDC = _WinAPI_GetDC($hWnd_Tip)
  51. $hCDC = _WinAPI_CreateCompatibleDC($hDC)
  52.  
  53. $tSize = DllStructCreate($tagSIZE)
  54. $pSize = DllStructGetPtr($tSize)
  55. DllStructSetData($tSize, "X", 100)
  56. DllStructSetData($tSize, "Y", 100)
  57. $tSource = DllStructCreate($tagPOINT)
  58. $pSource = DllStructGetPtr($tSource)
  59. $tBlend = DllStructCreate($tagBLENDFUNCTION)
  60. $pBlend = DllStructGetPtr($tBlend)
  61. DllStructSetData($tBlend, "Alpha", 255)
  62. DllStructSetData($tBlend, "Format", 1)
  63. $tPoint = DllStructCreate($tagPOINT)
  64. $pPoint = DllStructGetPtr($tPoint)
  65. DllStructSetData($tPoint, "X", 0)
  66. DllStructSetData($tPoint, "Y", 0)
  67.  
  68. ; #FUNCTION# ====================================================================================================================
  69. ; Name...........: _ToolTip_Create
  70. ; Description ...: Zeigt einen ToolTip an der gewünschten Position an.
  71. ; Syntax.........: _ToolTip_Create($sText_Tip, [$iX = False, [$iY = False, [$iStyle_Tip = 0]]])
  72. ; Parameters ....: $sText_Tip  - Text des ToolTips.
  73. ;                  $iX         - [optional] X-Koordinate des ToolTips.
  74. ;                  $iY         - [optional] Y-Koordinate des ToolTips.
  75. ;                  $iStyle_Tip - [optional] Stil des ToolTips. 0 = Abgerundetes Rechteck mit Pfeil nach unten.
  76. ;                                                              1 = Abgerundetes Rechteck mit Pfeil nach oben.
  77. ;                                                              2 = Rechteck mit kariertem Hintergrund.
  78. ; Return values .: -
  79. ; Author ........: name22 (autoit.de)
  80. ; Remarks .......: Ein Leerstring als Text, löscht den zuvor gesetzten ToolTip.
  81. ;                  Werden keine Koordinaten angegeben, wird der ToolTip in die Nähe des Mauszeigers gesetzt.
  82. ; ===============================================================================================================================
  83. Func _ToolTip_Create($sText_Tip, $iX = False, $iY = False, $iStyle_Tip = 0)
  84.     Switch $sText_Tip
  85.         Case ""
  86.             GUIRegisterMsg($WM_PAINT, "")
  87.             GUISetState(@SW_HIDE, $hWnd_Tip)
  88.         Case Else
  89.             If $iX = False And $iY = False Then
  90.                 $iX = MouseGetPos(0)
  91.                 $iY = MouseGetPos(1)
  92.             EndIf
  93.  
  94.             GUIRegisterMsg($WM_PAINT, "")
  95.             $tLayout_Tip = _GDIPlus_GraphicsMeasureString($hGraphic_Tip, $sText_Tip, $hFont_Tip, _GDIPlus_RectFCreate(), $hFormat_Tip)
  96.  
  97.             Switch $iStyle_Tip
  98.                 Case 0
  99.                     $iWidth_Tip = DllStructGetData($tLayout_Tip[0], "width") + 6
  100.                     $iHeight_Tip = DllStructGetData($tLayout_Tip[0], "height") + 6
  101.                     $iX_Tip = 1
  102.                     $iY_Tip = 1
  103.                     DllStructSetData($tLayout_Tip[0], "x", $iX_Tip + 3)
  104.                     DllStructSetData($tLayout_Tip[0], "y", $iY_Tip + 3)
  105.  
  106.                     _GDIPlus_BitmapDispose($hBitmap_Tip)
  107.                     _GDIPlus_GraphicsDispose($hBuffer_Tip)
  108.                     $hBitmap_Tip = _GDIPlus_BitmapCreateFromGraphics($iWidth_Tip + $iX_Tip + 2, $iHeight_Tip + $iY_Tip + 13, $hGraphic_Tip)
  109.                     $hBuffer_Tip = _GDIPlus_ImageGetGraphicsContext($hBitmap_Tip)
  110.                     _GDIPlus_GraphicsSetSmoothingMode($hBuffer_Tip, 2)
  111.                     _GDIPlus_GraphicsSetTextRenderingHint($hBuffer_Tip, 5)
  112.  
  113.                     DllStructSetData($tSize, "X", $iWidth_Tip + $iX_Tip + 2)
  114.                     DllStructSetData($tSize, "Y", $iHeight_Tip + $iY_Tip + 13)
  115.                     DllStructSetData($tPoint, "X", $iX - DllStructGetData($tSize, "X") / 2)
  116.                     DllStructSetData($tPoint, "Y", $iY - DllStructGetData($tSize, "Y"))
  117.  
  118.                     $hPath_Tip = _GDIPlus_PathCreate()
  119.                     _GDIPlus_PathAddArc($hPath_Tip, $iX_Tip, $iY_Tip, $iRadius_Tip * 2, $iRadius_Tip * 2, -180, 90)
  120.                     _GDIPlus_PathAddLine($hPath_Tip, $iX_Tip + $iRadius_Tip, $iY_Tip, $iX_Tip + $iWidth_Tip - $iRadius_Tip, $iY_Tip)
  121.                     _GDIPlus_PathAddArc($hPath_Tip, $iX_Tip + $iWidth_Tip - $iRadius_Tip * 2, $iY_Tip, $iRadius_Tip * 2, $iRadius_Tip * 2, -90, 90)
  122.                     _GDIPlus_PathAddLine($hPath_Tip, $iX_Tip + $iWidth_Tip, $iY_Tip + $iRadius_Tip, $iX_Tip + $iWidth_Tip, $iY_Tip + $iHeight_Tip - $iRadius_Tip)
  123.                     _GDIPlus_PathAddArc($hPath_Tip, $iX_Tip + $iWidth_Tip - $iRadius_Tip * 2, $iY_Tip + $iHeight_Tip - $iRadius_Tip * 2, $iRadius_Tip * 2, $iRadius_Tip * 2, 0, 90)
  124.                     _GDIPlus_PathAddLine($hPath_Tip, $iX_Tip + $iWidth_Tip - $iRadius_Tip, $iY_Tip + $iHeight_Tip, $iX_Tip + $iWidth_Tip / 2 + 5, $iY_Tip + $iHeight_Tip)
  125.                     _GDIPlus_PathAddLine($hPath_Tip, $iX_Tip + $iWidth_Tip / 2 + 5, $iY_Tip + $iHeight_Tip, $iX_Tip + $iWidth_Tip / 2, $iY_Tip + $iHeight_Tip + 10)
  126.                     _GDIPlus_PathAddLine($hPath_Tip, $iX_Tip + $iWidth_Tip / 2, $iY_Tip + $iHeight_Tip + 10, $iX_Tip + $iWidth_Tip / 2 - 5, $iY_Tip + $iHeight_Tip)
  127.                     _GDIPlus_PathAddLine($hPath_Tip, $iX_Tip + $iWidth_Tip / 2 - 5, $iY_Tip + $iHeight_Tip, $iX_Tip + $iRadius_Tip, $iY_Tip + $iHeight_Tip)
  128.                     _GDIPlus_PathAddArc($hPath_Tip, $iX_Tip, $iY_Tip + $iHeight_Tip - $iRadius_Tip * 2, $iRadius_Tip * 2, $iRadius_Tip * 2, 90, 90)
  129.                     _GDIPlus_PathAddLine($hPath_Tip, $iX_Tip, $iY_Tip + $iHeight_Tip - $iRadius_Tip, $iX_Tip, $iY_Tip + $iRadius_Tip)
  130.  
  131.                     _GDIPlus_GraphicsFillPath($hBuffer_Tip, $hPath_Tip, $hBrush_BG_Tip)
  132.                     _GDIPlus_GraphicsDrawPath($hBuffer_Tip, $hPath_Tip, $hPen_Border_Tip)
  133.                     _GDIPlus_PathDispose($hPath_Tip)
  134.                 Case 1
  135.                     $iWidth_Tip = DllStructGetData($tLayout_Tip[0], "width") + 6
  136.                     $iHeight_Tip = DllStructGetData($tLayout_Tip[0], "height") + 6
  137.                     $iX_Tip = 1
  138.                     $iY_Tip = 12
  139.                     DllStructSetData($tLayout_Tip[0], "x", $iX_Tip + 3)
  140.                     DllStructSetData($tLayout_Tip[0], "y", $iY_Tip + 3)
  141.  
  142.                     _GDIPlus_BitmapDispose($hBitmap_Tip)
  143.                     _GDIPlus_GraphicsDispose($hBuffer_Tip)
  144.                     $hBitmap_Tip = _GDIPlus_BitmapCreateFromGraphics($iWidth_Tip + $iX_Tip + 2, $iHeight_Tip + $iY_Tip + 2, $hGraphic_Tip)
  145.                     $hBuffer_Tip = _GDIPlus_ImageGetGraphicsContext($hBitmap_Tip)
  146.                     _GDIPlus_GraphicsSetSmoothingMode($hBuffer_Tip, 2)
  147.                     _GDIPlus_GraphicsSetTextRenderingHint($hBuffer_Tip, 5)
  148.  
  149.                     DllStructSetData($tSize, "X", $iWidth_Tip + $iX_Tip + 2)
  150.                     DllStructSetData($tSize, "Y", $iHeight_Tip + $iY_Tip + 2)
  151.                     DllStructSetData($tPoint, "X", $iX - DllStructGetData($tSize, "X") / 2)
  152.                     DllStructSetData($tPoint, "Y", $iY)
  153.  
  154.                     $hPath_Tip = _GDIPlus_PathCreate()
  155.                     _GDIPlus_PathAddArc($hPath_Tip, $iX_Tip, $iY_Tip, $iRadius_Tip * 2, $iRadius_Tip * 2, -180, 90)
  156.                     _GDIPlus_PathAddLine($hPath_Tip, $iX_Tip + $iRadius_Tip, $iY_Tip, $iX_Tip + $iWidth_Tip / 2 - 5, $iY_Tip)
  157.                     _GDIPlus_PathAddLine($hPath_Tip, $iX_Tip + $iWidth_Tip / 2 - 5, $iY_Tip, $iX_Tip + $iWidth_Tip / 2, $iY_Tip - 10)
  158.                     _GDIPlus_PathAddLine($hPath_Tip, $iX_Tip + $iWidth_Tip / 2, $iY_Tip - 10, $iX_Tip + $iWidth_Tip / 2 + 5, $iY_Tip)
  159.                     _GDIPlus_PathAddLine($hPath_Tip, $iX_Tip + $iWidth_Tip / 2 + 5, $iY_Tip, $iX_Tip + $iWidth_Tip - $iRadius_Tip, $iY_Tip)
  160.                     _GDIPlus_PathAddArc($hPath_Tip, $iX_Tip + $iWidth_Tip - $iRadius_Tip * 2, $iY_Tip, $iRadius_Tip * 2, $iRadius_Tip * 2, -90, 90)
  161.                     _GDIPlus_PathAddLine($hPath_Tip, $iX_Tip + $iWidth_Tip, $iY_Tip + $iRadius_Tip, $iX_Tip + $iWidth_Tip, $iY_Tip + $iHeight_Tip - $iRadius_Tip)
  162.                     _GDIPlus_PathAddArc($hPath_Tip, $iX_Tip + $iWidth_Tip - $iRadius_Tip * 2, $iY_Tip + $iHeight_Tip - $iRadius_Tip * 2, $iRadius_Tip * 2, $iRadius_Tip * 2, 0, 90)
  163.                     _GDIPlus_PathAddLine($hPath_Tip, $iX_Tip + $iWidth_Tip - $iRadius_Tip, $iY_Tip + $iHeight_Tip, $iX_Tip + $iRadius_Tip, $iY_Tip + $iHeight_Tip)
  164.                     _GDIPlus_PathAddArc($hPath_Tip, $iX_Tip, $iY_Tip + $iHeight_Tip - $iRadius_Tip * 2, $iRadius_Tip * 2, $iRadius_Tip * 2, 90, 90)
  165.                     _GDIPlus_PathAddLine($hPath_Tip, $iX_Tip, $iY_Tip + $iHeight_Tip - $iRadius_Tip, $iX_Tip, $iY_Tip + $iRadius_Tip)
  166.  
  167.                     _GDIPlus_GraphicsFillPath($hBuffer_Tip, $hPath_Tip, $hBrush_BG_Tip)
  168.                     _GDIPlus_GraphicsDrawPath($hBuffer_Tip, $hPath_Tip, $hPen_Border_Tip)
  169.                     _GDIPlus_PathDispose($hPath_Tip)
  170.                 Case 2
  171.                     $iWidth_Tip = DllStructGetData($tLayout_Tip[0], "width") + 6
  172.                     $iHeight_Tip = DllStructGetData($tLayout_Tip[0], "height") + 6
  173.                     DllStructSetData($tLayout_Tip[0], "x", 3)
  174.                     DllStructSetData($tLayout_Tip[0], "y", 3)
  175.  
  176.                     _GDIPlus_BitmapDispose($hBitmap_Tip)
  177.                     _GDIPlus_GraphicsDispose($hBuffer_Tip)
  178.                     $hBitmap_Tip = _GDIPlus_BitmapCreateFromGraphics($iWidth_Tip, $iHeight_Tip, $hGraphic_Tip)
  179.                     $hBuffer_Tip = _GDIPlus_ImageGetGraphicsContext($hBitmap_Tip)
  180.                     _GDIPlus_GraphicsSetSmoothingMode($hBuffer_Tip, 2)
  181.                     _GDIPlus_GraphicsSetTextRenderingHint($hBuffer_Tip, 5)
  182.  
  183.                     DllStructSetData($tSize, "X", $iWidth_Tip)
  184.                     DllStructSetData($tSize, "Y", $iHeight_Tip)
  185.                     DllStructSetData($tPoint, "X", $iX)
  186.                     DllStructSetData($tPoint, "Y", $iY)
  187.  
  188.                     _GDIPlus_GraphicsFillRect($hBuffer_Tip, 0, 0, $iWidth_Tip, $iHeight_Tip, $hBrush_Hatch_Tip)
  189.             EndSwitch
  190.  
  191.             _GDIPlus_GraphicsDrawStringEx($hBuffer_Tip, $sText_Tip, $hFont_Tip, $tLayout_Tip[0], $hFormat_Tip, $hBrush_Text_Tip)
  192.             __ToolTip_ReDraw()
  193.  
  194.             If BitAND(WinGetState($hWnd_Tip), 2) <> 2 Then GUISetState(@SW_SHOWNOACTIVATE, $hWnd_Tip)
  195.  
  196.             GUIRegisterMsg($WM_PAINT, "__ToolTip_ReDraw")
  197.     EndSwitch
  198.  
  199. EndFunc   ;==>_ToolTip_Create
  200.  
  201. ; #FUNCTION# ====================================================================================================================
  202. ; Name...........: __ToolTip_ReDraw
  203. ; Description ...: Zeichnet den ToolTip neu.
  204. ; Syntax.........: __ToolTip_ReDraw()
  205. ; Return values .: -
  206. ; Author ........: name22 (autoit.de)
  207. ; Remarks .......: Intern genutzte Funktion.
  208. ; ===============================================================================================================================
  209. Func __ToolTip_ReDraw()
  210.     Local $hBitmapTmp = _GDIPlus_BitmapCreateHBITMAPFromBitmap($hBitmap_Tip)
  211.     _WinAPI_SelectObject($hCDC, $hBitmapTmp)
  212.     _WinAPI_UpdateLayeredWindow($hWnd_Tip, $hDC, $pPoint, $pSize, $hCDC, $pSource, 0, $pBlend, 2)
  213.     _WinAPI_DeleteObject($hBitmapTmp)
  214. EndFunc   ;==>_ToolTip_ReDraw
  215.  
  216. ; #FUNCTION# ====================================================================================================================
  217. ; Name...........: _ToolTip_BGSetColor
  218. ; Description ...: Ändert die Hintergundfarbe des ToolTips auf den gewünschten ARGB Farbwert ab.
  219. ; Syntax.........: _ToolTip_BGSetColor([$NewColor])
  220. ; Parameters ....: $NewColor - [optional] Neuer Farbwert im Format 0xAARRGGBB. Transparenz wird unterstützt.
  221. ; Return values .: -
  222. ; Author ........: name22 (autoit.de)
  223. ; Remarks .......: Gilt nur für ToolTip Style 0/1.
  224. ; ===============================================================================================================================
  225. Func _ToolTip_BGSetColor($NewColor = 0xD0202020)
  226.     _GDIPlus_BrushSetSolidColor($hBrush_BG_Tip, $NewColor)
  227. EndFunc   ;==>_ToolTip_BGSetColor
  228.  
  229. ; #FUNCTION# ====================================================================================================================
  230. ; Name...........: _ToolTip_TextSetColor
  231. ; Description ...: Ändert die Textfarbe des ToolTips auf den gewünschten ARGB Farbwert ab.
  232. ; Syntax.........: _ToolTip_TextSetColor([$NewColor])
  233. ; Parameters ....: $NewColor - [optional] Neuer Farbwert im Format 0xAARRGGBB. Transparenz wird unterstützt.
  234. ; Return values .: -
  235. ; Author ........: name22 (autoit.de)
  236. ; Remarks .......: -
  237. ; ===============================================================================================================================
  238. Func _ToolTip_TextSetColor($NewColor = 0xE0E0E0E0)
  239.     _GDIPlus_BrushSetSolidColor($hBrush_Text_Tip, $NewColor)
  240. EndFunc   ;==>_ToolTip_TextSetColor
  241.  
  242. ; #FUNCTION# ====================================================================================================================
  243. ; Name...........: _ToolTip_BorderSetColor
  244. ; Description ...: Ändert die Randlinienfarbe des ToolTips auf den gewünschten ARGB Farbwert ab.
  245. ; Syntax.........: _ToolTip_BorderSetColor([$NewColor])
  246. ; Parameters ....: $NewColor - [optional] Neuer Farbwert im Format 0xAARRGGBB. Transparenz wird unterstützt.
  247. ; Return values .: -
  248. ; Author ........: name22 (autoit.de)
  249. ; Remarks .......: Gilt nur für ToolTip Style 0/1.
  250. ; ===============================================================================================================================
  251. Func _ToolTip_BorderSetColor($NewColor = 0xE0E57913)
  252.     _GDIPlus_PenSetColor($hPen_Border_Tip, $NewColor)
  253. EndFunc   ;==>_ToolTip_BorderSetColor
  254.  
  255. ; #FUNCTION# ====================================================================================================================
  256. ; Name...........: _ToolTip_BorderSetWidth
  257. ; Description ...: Ändert die Randliniendicke des ToolTips auf den gewünschten Dezimalwert ab.
  258. ; Syntax.........: _ToolTip_BorderSetWidth([$fWidth])
  259. ; Parameters ....: $fWidth - [optional] Neuer Wert.
  260. ; Return values .: -
  261. ; Author ........: name22 (autoit.de)
  262. ; Remarks .......: Ein zu großer Wert kann Fehldarstellungen verursachen.
  263. ;                  Gilt nur für ToolTip Style 0/1.
  264. ; ===============================================================================================================================
  265. Func _ToolTip_BorderSetWidth($fWidth = 2)
  266.     _GDIPlus_PenSetWidth($hPen_Border_Tip, $fWidth)
  267. EndFunc   ;==>_ToolTip_BorderSetWidth
  268.  
  269. ; #FUNCTION# ====================================================================================================================
  270. ; Name...........: _ToolTip_FontSetOptions
  271. ; Description ...: Ändert die Einstellungen für den Text des ToolTips.
  272. ; Syntax.........: _ToolTip_FontSetOptions($sFont = "Arial", $fSize = 10, $iStyle = 0)
  273. ; Parameters ....: $sFont  - [optional] Schriftart des ToolTips.
  274. ;                  $fSize  - [optional] Schriftgröße des ToolTips.
  275. ;                  $iStyle - [optional] Schriftstil des ToolTips. 0 = "Normal"; 1 = "Fett"; 2 = "Kursiv"; 4 = "Unterstrichen";
  276. ;                            8 = "Durchgestrichen". Werte können kombiniert werden.
  277. ; Return values .: -
  278. ; Author ........: name22 (autoit.de)
  279. ; Remarks .......: -
  280. ; ===============================================================================================================================
  281. Func _ToolTip_FontSetOptions($sFont = "Arial", $fSize = 10, $iStyle = 0)
  282.     _GDIPlus_FontFamilyDispose($hFamily_Tip)
  283.     _GDIPlus_FontDispose($hFont_Tip)
  284.     $hFamily_Tip = _GDIPlus_FontFamilyCreate($sFont)
  285.     $hFont_Tip = _GDIPlus_FontCreate($hFamily_Tip, $fSize, $iStyle)
  286. EndFunc   ;==>_ToolTip_FontSetOptions
  287.  
  288. ; #FUNCTION# ====================================================================================================================
  289. ; Name...........: _ToolTip_HatchSetColors
  290. ; Description ...: Ändert die Einstellungen für den Text des ToolTips.
  291. ; Syntax.........: _ToolTip_HatchSetColors($ARGB_Lines = 0xD0D0D0D0, $ARGB_BG = 0xD0F0F0F0)
  292. ; Parameters ....: $ARGB_Lines - [optional] Linienfarbe des karierten ToolTipMusters.
  293. ;                  $ARGB_BG    - [optional] Hintergrundfarbe des karierten ToolTipMusters.
  294. ; Return values .: -
  295. ; Author ........: name22 (autoit.de)
  296. ; Remarks .......: Gilt nur für den ToolTip Style 2
  297. ; ===============================================================================================================================
  298. Func _ToolTip_HatchSetColors($ARGB_Lines = 0xD0D0D0D0, $ARGB_BG = 0xD0F0F0F0)
  299.     _GDIPlus_BrushDispose($hBrush_Hatch_Tip)
  300.     $hBrush_Hatch_Tip = _GDIPlus_HatchBrushCreate($HatchStyleCross, $ARGB_Lines, $ARGB_BG)
  301. EndFunc   ;==>_ToolTip_FontSetOptions
  302.  
  303. ; #FUNCTION# ====================================================================================================================
  304. ; Name...........: __ToolTip_Shutdown
  305. ; Description ...: Entfernt die von der UDF verwendeten Ressourcen aus dem Arbeitsspeicher.
  306. ; Syntax.........: __ToolTip_Shutdown()
  307. ; Return values .: -
  308. ; Author ........: name22 (autoit.de)
  309. ; Remarks .......: Intern genutzte Funktion.
  310. ; ===============================================================================================================================
  311. Func __ToolTip_Shutdown()
  312.     GUIRegisterMsg($WM_PAINT, "")
  313.     _GDIPlus_GraphicsDispose($hGraphic_Tip)
  314.     _GDIPlus_BitmapDispose($hBitmap_Tip)
  315.     _GDIPlus_GraphicsDispose($hBuffer_Tip)
  316.     _GDIPlus_StringFormatDispose($hFormat_Tip)
  317.     _GDIPlus_FontDispose($hFont_Tip)
  318.     _GDIPlus_FontFamilyDispose($hFamily_Tip)
  319.     _GDIPlus_BrushDispose($hBrush_BG_Tip)
  320.     _GDIPlus_BrushDispose($hBrush_Text_Tip)
  321.     _GDIPlus_BrushDispose($hBrush_Hatch_Tip)
  322.     _GDIPlus_PenDispose($hPen_Border_Tip)
  323.     _GDIPlus_Shutdown()
  324. EndFunc   ;==>_ToolTip_Shutdown
Advertisement
Add Comment
Please, Sign In to add comment
Advertisement
Public Pastes
Advertisement
We use cookies for various purposes including analytics. By continuing to use Pastebin, you agree to our use of cookies as described in the Cookies Policy.  OK, I Understand
Not a member of Pastebin yet?
Sign Up, it unlocks many cool features!