Simple WMI queries

@echo off
TITLE --WMI Info--
SETLOCAL ENABLEDELAYEDEXPANSION

:: Check if the WMIC command is available
WMIC.EXE /? >NUL 2>&1

:: If the ERRORLEVEL is equal to 0 the WMI query routine will run
IF %ERRORLEVEL% EQU 0 (
    FOR /f "tokens=2 delims==" %%a IN ('WMIC Path Win32_NetworkAdapterConfiguration WHERE "IPEnabled=TRUE" Get MACAddress /value') do set MAC=%%a
    FOR /f "tokens=2 delims==" %%a IN ('WMIC Path Win32_ComputerSystem Get MANUFACTURER /value') do set MANUFACTURER=%%a
    FOR /f "tokens=2 delims==" %%a IN ('WMIC Path Win32_ComputerSystem Get MODEL /value') do set MODEL=%%a
    FOR /f "tokens=2 delims==" %%a IN ('WMIC Path Win32_BIOS Get SerialNumber /value') do set SERIAL=%%a
    FOR /f "tokens=2 delims==" %%a IN ('WMIC PRINTER WHERE "Default = TRUE" Get Name /value') do set DEFAULT_PRINTER=%%a
    echo WMI values successfully applied!
    echo.
    echo.
) ELSE (
    SET FAIL=""
    color cf
    echo WMI services NOT INSTALLED
)

REM If the variable "FAIL" has not been defined by the routine above
REM This will output the results of the WMI queries
IF NOT DEFINED FAIL (
    Color 2F
    echo --Computer Info--
    echo Computer Name: %COMPUTERNAME%
    echo Model: %MODEL%
    echo Manufacturer: %MANUFACTURER%
    echo Serial: %SERIAL%
    echo MAC Address: %MAC%
    echo.
    echo --Printer Info--
    echo Default Printer: %DEFAULT_PRINTER%
    echo.
)

Echo DONE! Press any key to exit...
pause>nul

:: Written by HeckDeck 27.1.2014

ENDLOCAL