Ocn_NMA_SD_Band_Oscx

#property indicator_separate_window
#property indicator_buffers 2
#property indicator_color1 Yellow
#property indicator_color2 Aqua
#property indicator_level1 50
#property indicator_level2 0
#property indicator_level3 -50
#property indicator_levelcolor Gray
#property indicator_levelstyle 2

extern bool    Show_NMA       = true;
extern int     NMA_period     = 40;
extern int     NMA_SD_len     = 30;
extern double  NMA_SD_up      = 2;
extern double  NMA_SD_dn      = 2;
extern bool    Show_FastNMA   = true;
extern int     FastNMA_period = 40;
extern int     FastNMA_LB_min = 8;
extern int     FastNMA_SD_len = 20;
extern double  FastNMA_SD_up  = 1.5;
extern double  FastNMA_SD_dn  = 1.5;

double NMA_SD_Band_Osc[];
double NMA[];
double NMA_SDup[];
double NMA_SDdn[];
double FastNMA_SD_Band_Osc[];
double FastNMA[];
double FastNMA_SDup[];
double FastNMA_SDdn[];

int init()
{
  IndicatorShortName("NMA_SD_Band_Osc(" + NMA_period + ", " + FastNMA_period + ", " + FastNMA_LB_min + ")");
  IndicatorBuffers(8);
  SetIndexBuffer(0, NMA_SD_Band_Osc);
  SetIndexLabel(0, "NMA_SD_Band_Osc(" + NMA_period + ")");
  SetIndexBuffer(1, FastNMA_SD_Band_Osc);
  SetIndexLabel(1, "FastNMA_SD_Band_Osc(" + FastNMA_period + ", " + FastNMA_LB_min + ")");
  SetIndexBuffer(2, NMA);
  SetIndexBuffer(3, NMA_SDup);
  SetIndexBuffer(4, NMA_SDdn);
  SetIndexBuffer(5, FastNMA);
  SetIndexBuffer(6, FastNMA_SDup);
  SetIndexBuffer(7, FastNMA_SDdn);
  return(0);
}

int start()
{
  int limit, i, ii, counted_bars = IndicatorCounted();
  int max = MathMax(Show_NMA * MathMax(NMA_period, NMA_SD_len), Show_FastNMA * MathMax(FastNMA_period, FastNMA_SD_len));
  double sum, abssum, ratio, nmmnum, maxnmm;

  if(Bars <= max) return(0);
  if(counted_bars < 0) counted_bars = 0;
  if(counted_bars > max) limit = Bars - counted_bars;
  else                   limit = Bars - max - 1;

  if(Show_NMA)
    for(i = limit; i >= 0; i--)
      {
      ratio = 0;
      sum = (MathLog(Close[i]) - MathLog(Close[i+1])) + (MathLog(Close[i+1]) - MathLog(Close[i+2])) * (MathSqrt(2)-1);
      for(ii = 2; ii < NMA_period; ii++)
        sum += (MathLog(Close[i+ii]) - MathLog(Close[i+ii+1])) * (MathSqrt(ii+1) - MathSqrt(ii));
      abssum = MathAbs(sum);
      sum = 0;
      for(ii = 0; ii < NMA_period; ii++)
        sum += MathAbs(MathLog(Close[i+ii]) - MathLog(Close[i+ii+1]));
      if(sum != 0) ratio = abssum / sum;
      NMA[i] = NMA[i+1] + (Close[i] - NMA[i+1]) * ratio;
      NMA_SDup[i] = NMA[i] + NMA_SD_up * iStdDev(NULL, 0, NMA_SD_len, 0, 0, PRICE_CLOSE, i);
      NMA_SDdn[i] = NMA[i] - NMA_SD_dn * iStdDev(NULL, 0, NMA_SD_len, 0, 0, PRICE_CLOSE, i);
      NMA_SD_Band_Osc[i] = ((Close[i] - NMA_SDdn[i]) / (NMA_SDup[i] - NMA_SDdn[i]) * 100) - 50;
      }

  if(Show_FastNMA)
    for(i = limit; i >= 0; i--)
      {
      maxnmm = 0; ratio = 0;
      int NMA_LB_max;
      for(ii = 1; ii <= FastNMA_period; ii++)
        {
        nmmnum = (MathLog(Close[i]) - MathLog(Close[i+ii])) / MathSqrt(ii);
        if(MathAbs(nmmnum) > maxnmm) { maxnmm = MathAbs(nmmnum); NMA_LB_max = ii; }
        }
      if(NMA_LB_max < FastNMA_LB_min) NMA_LB_max = FastNMA_LB_min;
      sum = (MathLog(Close[i]) - MathLog(Close[i+1])) + (MathLog(Close[i+1]) - MathLog(Close[i+2])) * (MathSqrt(2)-1);
      for(ii = 2; ii < NMA_LB_max; ii++)
        sum += (MathLog(Close[i+ii]) - MathLog(Close[i+ii+1])) * (MathSqrt(ii+1) - MathSqrt(ii));
      abssum = MathAbs(sum);
      sum = 0;
      for(ii = 0; ii < NMA_LB_max; ii++)
        sum += MathAbs(MathLog(Close[i+ii]) - MathLog(Close[i+ii+1]));
      if(sum != 0) ratio = abssum / sum;
      FastNMA[i] = FastNMA[i+1] + (Close[i] - FastNMA[i+1]) * ratio;
      FastNMA_SDup[i] = FastNMA[i] + FastNMA_SD_up * iStdDev(NULL, 0, FastNMA_SD_len, 0, 0, PRICE_CLOSE, i);
      FastNMA_SDdn[i] = FastNMA[i] - FastNMA_SD_dn * iStdDev(NULL, 0, FastNMA_SD_len, 0, 0, PRICE_CLOSE, i);
      FastNMA_SD_Band_Osc[i] = ((Close[i] - FastNMA_SDdn[i]) / (FastNMA_SDup[i] - FastNMA_SDdn[i]) * 100) - 50;
      }

  return(0);
}