//Aim system
//Author: SDraw
//Original post at pawno.ru

#if defined _aim
    #endinput
#endif
#define _aim

forward OnPlayerStartAim(playerid,aimedplayer);
forward OnPlayerEndAim(playerid,aimedplayer);

new AimedPlayer[MAX_PLAYERS];

public OnPlayerConnect(playerid)
{
    AimedPlayer[playerid] = INVALID_PLAYER_ID;
    if(funcidx("aim_OnPlayerConnect") != -1) return CallLocalFunction("aim_OnPlayerConnect", "d",playerid);
    return 1;
}
#if defined _ALS_OnPlayerConnect
    #undef OnPlayerConnect
#else
    #define _ALS_OnPlayerConnect
#endif
#define OnPlayerConnect aim_OnPlayerConnect
forward aim_OnPlayerConnect(playerid);


public OnPlayerUpdate(playerid)
{
    if(AimedPlayer[playerid] == INVALID_PLAYER_ID)
    {
        new gt = GetPlayerTargetPlayer(playerid);
        if(gt != INVALID_PLAYER_ID)
        {
            AimedPlayer[playerid] = gt;
            if(funcidx("OnPlayerStartAim") != -1) CallLocalFunction("OnPlayerStartAim","dd",playerid,gt);
        }
    }
    else
    {
        new gt = GetPlayerTargetPlayer(playerid);
        if(gt == INVALID_PLAYER_ID)
        {
            if(funcidx("OnPlayerEndAim") != -1) CallLocalFunction("OnPlayerEndAim","dd",playerid,AimedPlayer[playerid]);
            AimedPlayer[playerid] = INVALID_PLAYER_ID;
        }
        else if(gt != AimedPlayer[playerid])
        {
            if(funcidx("OnPlayerEndAim") != -1) CallLocalFunction("OnPlayerEndAim","dd",playerid,AimedPlayer[playerid]);
            AimedPlayer[playerid] = gt;
            if(funcidx("OnPlayerStartAim") != -1) CallLocalFunction("OnPlayerStartAim","dd",playerid,gt);
        }
    }
    if(funcidx("aim_OnPlayerUpdate") != -1) CallLocalFunction("aim_OnPlayerUpdate","d",playerid);
    return 1;
}

#if defined _ALS_OnPlayerUpdate
    #undef OnPlayerUpdate
#else
    #define _ALS_OnPlayerUpdate
#endif
#define OnPlayerUpdate aim_OnPlayerUpdate
forward aim_OnPlayerUpdate(playerid);