#UseHook On
; Split meat by holding down alt and click + hold on the stack of meat
Alt & LButton::
Send {lctrl Down}
Loop {
	Sleep 5 ; This is the delay between clicks, in milliseconds.
	GetKeyState, LButtonState, LButton, P
	if LButtonState = U ; User has physically released the button, so end the loop.
		break
	MouseClickDrag, left, 0, 0, 50, 50, 4, R
	MouseMove, -50, -50, 0, R
}
Send {lctrl Up}
return


; Applies shift key a couple times a second, for flying with better stamina. Toggleable.
shiftMoveToggle := 0
` & w::
	shiftMoveToggle := !shiftMoveToggle
    if (shiftMoveToggle) {
        SetTimer, ShiftMove, 300 ; This is the delay between keypresses, in milliseconds.
    } else {
        SetTimer, ShiftMove, Off
    }
return

ShiftMove:
	Send {LShift Down}
	Sleep 50 ; This is the time shift is pressed down, in milliseconds.
	Send {LShift Up}
return




; Places and destroys a boxes automatically! Put box on 9 slot in hotbar. Toggleable.
placeBoxToggle := 0
Alt & b::
	Sleep 500 ; Get around command executing a crouch for some reason
	placeBoxToggle := !placeBoxToggle
    if (placeBoxToggle) {
        SetTimer, PlaceAndDestroyBox, 0
    } else {
        SetTimer, PlaceAndDestroyBox, Off
    }
return

PlaceAndDestroyBox:
	; PlaceBox
	Send {9}
	Click
	Sleep 10
	Click
	Sleep 150

	; DestroyBox
	Send {E Down}
	Sleep 300 ; The time delay for the command wheel to show up
	MouseMove, -300, -100, 10, R
	Sleep 1000 ; The time delay for the destroy command
	Send {E Up}

	Sleep 100 ; The time delay between PlaceAndDestroy method
return