API tools faq
paste
Advertisement
Guest User

QTGMC for avs 2.60

a guest
Jan 1st, 2017
455
0
Never
Add comment
Not a member of Pastebin yet? Sign Up, it unlocks many cool features!
Avisynth 80.31 KB | None | 0 0
raw download clone embed print report diff
  1. #-------------------------------------------------------------------#
  2. #                                                                   #
  3. #           QTGMC 3.352, by Vit, 2012, 2016 mod by A.SONY           #
  4. #                                                                   #
  5. #   A high quality deinterlacer using motion-compensated temporal   #
  6. #  smoothing, with a range of features for quality and convenience  #
  7. #          Originally based on TempGaussMC_beta2 by Didée           #
  8. #                                                                   #
  9. #-------------------------------------------------------------------#
  10. #
  11. # Full documentation is in the 'QTGMC' html file that comes with this script
  12. #
  13. # --- LATEST CHANGES ---
  14. #
  15. # v3.352s
  16. # - added useEdiExt
  17. # - added tr0=-1 to use the EdiExt clip (if there is no EdiExt clip then it will not work)
  18. # - rep0 now will be 0 if tr0 < 1
  19. #
  20. # v3.347s
  21. # - fix SourceMatch (bug after new YUY2 method, thanks to ndjamena for report it)
  22. #
  23. # v3.346s
  24. # - EEDI3+NNEDI3 bug fix by ndjamena
  25. # - Renamed DftThreads parameter to FftThreads, to set the ncpu argument of FFT3DFilter (from VS)
  26. # - FFT3DFilter will work now in YUY2, use it with Denoiser="fft3df" (or use NoisePreset)
  27. #
  28. # v3.345s
  29. # - work with SMDegrain_KNLMeansCL now to process chroma too
  30. #
  31. # v3.343s
  32. # - edit in ChromaEdi
  33. # - others
  34. #
  35. # v3.34s (mod) 2016 12 18 (ravewulf idea in another way)
  36. # - Added yadifmod2 (if you need old one use it like this EdiMode="cYadif" or EdiMode="RepcYadif")
  37. # - fast and clean up YUY2 (will work in x64 now, no need to SSETools)
  38. #
  39. # v3.33s (mod) 2016 12 06
  40. # - Add TR2=4 and TR2=5
  41. # - add TV_range bool and dither_luma_rebuild (from SMDegrain) Str and Amp
  42. # - for avsplus now QTGMC_Bob is ready for any 420, not only yv12
  43. #
  44. # v3.33s (mod) 2016 04 11
  45. # - Add KNLMeansCL as another Denoiser to NoiseProcess
  46. # - others
  47. #
  48. # v3.33s (mod) 2016 01 19
  49. # - make QTGMC_deflate/QTGMC_inflate work with YUY2 using masktool2 for avs 2.60
  50. #
  51. # v3.33s (mod) 2015 10 23
  52. # - revert to QTGMC_deflate/QTGMC_inflate quoted from Dogway
  53. #
  54. # v3.33s (mod) 2015 9 10
  55. # - fix Multiple QTGMC Calls
  56. # - others fix
  57. #
  58. # v3.33s (mod) 2015 8 6
  59. # - some changes in bob to speed up
  60. #
  61. # v3.33s (mod) 2015 8 4
  62. # - fix bug in YUY2 with SourceMatch
  63. # - add slice=false to ditherpost to avoid artefacts
  64. #
  65. # v3.33s (mod)
  66. # - fix bob chroma
  67. # - work with new masktool2 for avs 2.60 in YUY2
  68. #
  69. # v3.33d (mod)
  70. # - Added 32 bit precision option through the lsbd (for dfttest and knlmeanscl) and lsb (mdegrain) options.
  71. # - optimized some mask handling a bit as originally suggested by Vit
  72. # - others
  73. #
  74. # v3.33
  75. # - Increased maximum value for Rep0, Rep1 and Rep2 to 7 (from 5). Higher values help with flicker on static detail, potential for minor motion blur
  76. # - Bug fix for the fact that Bob always outputs a BFF clip regardless of field order of input (thanks ajp_anton)
  77. # - Improved generation of noise (NoiseDeint="Generate") for noise bypass / EZKeepGrain
  78. # - Minor change to denoising
  79. #
  80. # v3.32
  81. # - Bugfix with shutter blur and ChromaMotion (thanks Heaud)
  82. # - Tweaked vector recalculation for shutter motion blur
  83. # - Changed defaults for TR2 when using source-match
  84. # - Minor bugfix with SLMode/SLRad on pass-through settings
  85. #
  86. # --- REQUIREMENTS ---
  87. #
  88. # Input colorspaces: YV12, YUY2, others as plugins supports
  89. #
  90. # Core plugins:
  91. #   MVTools2 (2.7.5.22 or above from pinterf https://github.com/pinterf/mvtools/releases)
  92. #   MaskTools v2 (2.0b1 or above)
  93. #   NNEDI3 (0.9.4.6 or above)
  94. #   RgTools
  95. #
  96. # Additional plugins:
  97. #   NNEDI2, NNEDI, EEDI3, EEDI2, TDeInt - if selected directly or via a source-match preset
  98. #   yadifmod2 - for Preset="Ultra Fast" or if selected directly
  99. #   FFT3DFilter - if selected for noise processing
  100. #   dfttest (1.9.4 or above) - if selected for noise processing
  101. #       For FFT3DFilter & ddftest you also need the FFTW3 library (FFTW.org). On Windows the file needed for both is libfftw3f-3.dll. However, for FFT3DFilter
  102. #       the file needs to be called FFTW3.dll, so you will need two copies and rename one. On Windows put the files in your System32 or SysWow64 folder
  103. #   KNLMeansCL - if selected for noise processing
  104. #   AddGrainC - if NoiseDeint="Generate" selected for noise bypass
  105.  
  106.  
  107. # --- GETTING STARTED ---
  108. #
  109. # Install AviSynth and ensure you have at least the core plugins listed in the requirements section above. Put them in the plugins autoload folder.
  110. # To use QTGMC write a script like this:
  111. #   YourSource("yourfile")   # DGDecode_mpeg2source, FFVideoSource, AviSource, whatever your source requires
  112. #   QTGMC( Preset="Slow" )
  113. #   SelectEven()             # Add this line to keep original frame rate, leave it out for smoother doubled frame rate
  114. #
  115. # Save this script with an ".avs" extension. You can now use it as an AVI source for encoding.
  116. #
  117. # The "Preset" used selects sensible settings for a given encoding speed. Choose a preset from:
  118. #   "Placebo", "Very Slow", "Slower", "Slow", "Medium", "Fast", "Faster", "Very Fast", "Super Fast", "Ultra Fast" & "Draft"
  119. # The default preset is "Slower"
  120. # Don't be obsessed with using slower settings as the differences can be small. HD material benefits little from extreme settings (and will be very slow)
  121. # For much faster speeds read the full documentation, the section on 'Multi-threading'
  122. #
  123. # There are many settings for tweaking the script, full details in the main documentation. You can display settings currently being used with "ShowSettings":
  124. #   QTGMC( Preset="Slow", ShowSettings=true )
  125.  
  126.  
  127. function QTGMC( clip Input, string "Preset", int "TR0", int "TR1", int "TR2", int "Rep0", int "Rep1", int "Rep2", string "EdiMode", bool "RepChroma", \
  128.                     int "NNSize", int "NNeurons", int "EdiQual", int "EdiMaxD", string "ChromaEdi", int "EdiThreads", clip "EdiExt", float "Sharpness", \
  129.                     int "SMode", int "SLMode", int "SLRad", int "SOvs", float "SVThin", int "Sbb", int "SrchClipPP", int "SubPel", int "SubPelInterp", \
  130.                     int "BlockSize", int "Overlap", int "Search", int "SearchParam", int "PelSearch", bool "ChromaMotion", bool "TrueMotion", int "Lambda", \
  131.                     int "LSAD", int "PNew", int "PLevel", bool "GlobalMotion", int "DCT", int "ThSAD1", int "ThSAD2", int "ThSCD1", int "ThSCD2", \
  132.                     int "SourceMatch", string "MatchPreset", string "MatchEdi", string "MatchPreset2", string "MatchEdi2", int "MatchTR2", \
  133.                     float "MatchEnhance", int "Lossless", int "NoiseProcess", float "EZDenoise", float "EZKeepGrain", string "NoisePreset", string "Denoiser", \
  134.                     int "FftThreads", bool "DenoiseMC", int "NoiseTR", float "Sigma", bool "ChromaNoise", val "ShowNoise", float "GrainRestore", \
  135.                     float "NoiseRestore", string "NoiseDeint", bool "StabilizeNoise", int "InputType", float "ProgSADMask", int "FPSDivisor", \
  136.                     int "ShutterBlur", float "ShutterAngleSrc", float "ShutterAngleOut", int "SBlurLimit", bool "Border", bool "Precise", string "Tuning", \
  137.                     bool "ShowSettings", string "GlobalNames", string "PrevGlobals", int "ForceTR", \
  138.                     val "BT", val "DetailRestore", val "MotionBlur", val "MBlurLimit", val "NoiseBypass", float "Str", float "Amp", bool "TV_range", bool "useEdiExt", bool "lsbd", bool "lsb" )
  139. {
  140.     # EdiMode="RepcYadif"/"cYadif" require the Yadif plugin, which doesn't autoload. Typically the calling script would load it.
  141.  
  142.     # Temporary Warnings
  143.     Assert( !defined(BT),            "QTGMC: Setting BT has been replaced by setting NoiseTR" )
  144.     Assert( !defined(DetailRestore), "QTGMC: Setting DetailRestore has been renamed to GrainRestore" )
  145.     Assert( !defined(MotionBlur),    "QTGMC: Setting MotionBlur has been renamed to ShutterBlur" )
  146.     Assert( !defined(MBlurLimit),    "QTGMC: Setting MBlurLimit has been renamed to SBlurLimit" )
  147.     Assert( !defined(NoiseBypass),   "QTGMC: Setting NoiseBypass has been renamed to NoiseProcess" )
  148.  
  149.     #---------------------------------------
  150.     # Presets
  151.     lsbd         = default( lsbd,      false)
  152.     lsb          = default( lsb,       false)
  153.     useEdiExt    = default( useEdiExt, false)
  154.     Str          = default( Str,        1.0 )
  155.     Amp          = default( Amp,     0.0625 )
  156.     TV_range     = default( TV_range,   true)
  157.  
  158.     # Select presets / tuning
  159.     Preset = default( Preset, "Slower" )
  160.     pNum = (Preset == "Placebo"   ) ? 0 : \
  161.            (Preset == "Very Slow" ) ? 1 : \
  162.            (Preset == "Slower"    ) ? 2 : \
  163.            (Preset == "Slow"      ) ? 3 : \
  164.            (Preset == "Medium"    ) ? 4 : \
  165.            (Preset == "Fast"      ) ? 5 : \
  166.            (Preset == "Faster"    ) ? 6 : \
  167.            (Preset == "Very Fast" ) ? 7 : \
  168.            (Preset == "Super Fast") ? 8 : \
  169.            (Preset == "Ultra Fast") ? 9 : \
  170.            (Preset == "Draft"     ) ? 10 : 11
  171.     Assert( pNum  < 11, "'Preset' choice is invalid" )
  172.  
  173.     mpNum1 = (!defined(MatchPreset))       ? ((pNum + 3 <= 9) ? (pNum + 3) : 9) : \
  174.              (MatchPreset == "Placebo"   ) ? 0 : \
  175.              (MatchPreset == "Very Slow" ) ? 1 : \
  176.              (MatchPreset == "Slower"    ) ? 2 : \
  177.              (MatchPreset == "Slow"      ) ? 3 : \
  178.              (MatchPreset == "Medium"    ) ? 4 : \
  179.              (MatchPreset == "Fast"      ) ? 5 : \
  180.              (MatchPreset == "Faster"    ) ? 6 : \
  181.              (MatchPreset == "Very Fast" ) ? 7 : \
  182.              (MatchPreset == "Super Fast") ? 8 : \
  183.              (MatchPreset == "Ultra Fast") ? 9 : \
  184.              (MatchPreset == "Draft"     ) ? 10 : 11
  185.     Assert( mpNum1 < 10, "'MatchPreset' choice is invalid/unsupported" )
  186.     MatchPreset = Select( mpNum1, "Placebo", "Very Slow", "Slower", "Slow", "Medium", "Fast", "Faster", "Very Fast", "Super Fast", "Ultra Fast", "Draft" )
  187.  
  188.     mpNum2 = (!defined(MatchPreset2))       ? ((mpNum1 + 2 <= 9) ? (mpNum1 + 2) : 9) : \
  189.              (MatchPreset2 == "Placebo"   ) ? 0 : \
  190.              (MatchPreset2 == "Very Slow" ) ? 1 : \
  191.              (MatchPreset2 == "Slower"    ) ? 2 : \
  192.              (MatchPreset2 == "Slow"      ) ? 3 : \
  193.              (MatchPreset2 == "Medium"    ) ? 4 : \
  194.              (MatchPreset2 == "Fast"      ) ? 5 : \
  195.              (MatchPreset2 == "Faster"    ) ? 6 : \
  196.              (MatchPreset2 == "Very Fast" ) ? 7 : \
  197.              (MatchPreset2 == "Super Fast") ? 8 : \
  198.              (MatchPreset2 == "Ultra Fast") ? 9 : \
  199.              (MatchPreset2 == "Draft"     ) ? 10 : 11
  200.     Assert( mpNum2 < 10, "'MatchPreset2' choice is invalid/unsupported" )
  201.     MatchPreset2 = Select( mpNum2, "Placebo", "Very Slow", "Slower", "Slow", "Medium", "Fast", "Faster", "Very Fast", "Super Fast", "Ultra Fast", "Draft" )
  202.  
  203.     NoisePreset = default( NoisePreset, "Fast" )
  204.     npNum = (NoisePreset == "Slower" ) ? 0 : \
  205.             (NoisePreset == "Slow"   ) ? 1 : \
  206.             (NoisePreset == "Medium" ) ? 2 : \
  207.             (NoisePreset == "Fast"   ) ? 3 : \
  208.             (NoisePreset == "Faster" ) ? 4 : 5
  209.     Assert( npNum < 5, "'NoisePreset' choice is invalid" )
  210.  
  211.     Tuning = default( Tuning, "None" )
  212.     tNum = (Tuning == "None"  ) ? 0 : \
  213.            (Tuning == "DV-SD" ) ? 1 : \
  214.            (Tuning == "DV-HD" ) ? 2 : 3
  215.     Assert( tNum < 3, "'Tuning' choice is invalid" )
  216.  
  217.     # Tunings only affect blocksize in this version
  218.     bs = Select( tNum,  16, 16, 32 )
  219.     bs2 = (bs >= 16) ? 32 : bs * 2
  220.  
  221.     #                                                               Very                                                        Very      Super      Ultra
  222.     # Preset groups:                                     Placebo    Slow      Slower    Slow      Medium    Fast      Faster    Fast      Fast       Fast       Draft
  223.     TR0          = default( TR0,          Select( pNum,  2,         2,        2,        2,        2,        2,        1,        1,        1,         1,         0      ) )
  224.     TR1          = default( TR1,          Select( pNum,  2,         2,        2,        1,        1,        1,        1,        1,        1,         1,         1      ) )
  225.     TR2X         = default( TR2,          Select( pNum,  3,         2,        1,        1,        1,        0,        0,        0,        0,         0,         0      ) )
  226.     Rep0         = defined(Rep0) ? Rep0 : TR0 < 1 ? 0 : undefined()
  227.     Rep0         = default( Rep0,         Select( pNum,  4,         4,        4,        4,        3,        3,        0,        0,        0,         0,         0      ) )
  228.     Rep1         = default( Rep1,         Select( pNum,  0,         0,        0,        0,        0,        0,        0,        0,        0,         0,         0      ) )
  229.     Rep2         = default( Rep2,         Select( pNum,  4,         4,        4,        4,        4,        4,        4,        4,        3,         3,         0      ) )
  230.     EdiMode      = default( EdiMode,      Select( pNum, "NNEDI3",  "NNEDI3", "NNEDI3", "NNEDI3", "NNEDI3", "NNEDI3", "NNEDI3", "NNEDI3", "NNEDI3",  "RepYadif","Bob"   ) )
  231.     NNSize       = default( NNSize,       Select( pNum,  1,         1,        1,        1,        5,        5,        4,        4,        4,         4,         4      ) )
  232.     NNeurons     = default( NNeurons,     Select( pNum,  2,         2,        1,        1,        1,        0,        0,        0,        0,         0,         0      ) )
  233.     EdiQual      = default( EdiQual,      Select( pNum,  1,         1,        1,        1,        1,        1,        1,        1,        1,         1,         1      ) )
  234.     EdiMaxD      = default( EdiMaxD,      Select( pNum,  12,        10,       8,        7,        7,        6,        6,        5,        4,         4,         4      ) )
  235.     SMode        = default( SMode,        Select( pNum,  2,         2,        2,        2,        2,        2,        2,        2,        2,         2,         0      ) )
  236.     SLModeX      = default( SLMode,       Select( pNum,  2,         2,        2,        2,        2,        2,        2,        2,        0,         0,         0      ) )
  237.     SLRad        = default( SLRad,        Select( pNum,  3,         1,        1,        1,        1,        1,        1,        1,        1,         1,         1      ) )
  238.     Sbb          = default( Sbb,          Select( pNum,  3,         1,        1,        0,        0,        0,        0,        0,        0,         0,         0      ) )
  239.     SrchClipPP   = default( SrchClipPP,   Select( pNum,  3,         3,        3,        3,        3,        2,        2,        2,        1,         1,         0      ) )
  240.     SubPel       = default( SubPel,       Select( pNum,  2,         2,        2,        2,        1,        1,        1,        1,        1,         1,         1      ) )
  241.     Blocksize    = default( Blocksize,    Select( pNum,  bs,        bs,       bs,       bs,       bs,       bs,       bs2,      bs2,      bs2,       bs2,       bs2    ) )
  242.     bs = Blocksize
  243.     Overlap      = default( Overlap,      Select( pNum,  bs/2,      bs/2,     bs/2,     bs/2,     bs/2,     bs/2,     bs/2,     bs/4,     bs/4,      bs/4,      bs/4   ) )
  244.     Search       = default( Search,       Select( pNum,  5,         4,        4,        4,        4,        4,        4,        4,        0,         0,         0      ) )
  245.     SearchParam  = default( SearchParam,  Select( pNum,  2,         2,        2,        2,        2,        2,        2,        1,        1,         1,         1      ) )
  246.     PelSearch    = default( PelSearch,    Select( pNum,  2,         2,        2,        2,        1,        1,        1,        1,        1,         1,         1      ) )
  247.     ChromaMotion = default( ChromaMotion, Select( pNum,  true,      true,     true,     false,    false,    false,    false,    false,    false,     false,     false  ) )
  248.     Precise      = default( Precise,      Select( pNum,  true,      true,     false,    false,    false,    false,    false,    false,    false,     false,     false  ) )
  249.     ProgSADMask  = default( ProgSADMask,  Select( pNum,  10.0,      10.0,     10.0,     10.0,     10.0,     0.0,      0.0,      0.0,      0.0,       0.0,       0.0    ) )
  250.  
  251.     # Noise presets                                           Slower     Slow       Medium     Fast       Faster
  252.     Denoiser       = default( Denoiser,       Select( npNum, "dfttest", "dfttest", "dfttest", "fft3df",  "fft3df" ) )
  253.     DenoiseMC      = default( DenoiseMC,      Select( npNum,  true,      true,      false,     false,     false   ) )
  254.     NoiseTR        = default( NoiseTR,        Select( npNum,  2,         1,         1,         1,         0       ) )
  255.     NoiseDeint     = default( NoiseDeint,     Select( npNum, "Generate","Bob",      "",        "",        ""      ) )
  256.     StabilizeNoise = default( StabilizeNoise, Select( npNum,  true,      true,      true,      false,     false   ) )
  257.  
  258.     # The basic source-match step corrects and re-runs the interpolation of the input clip. So it initialy uses same interpolation settings as the main preset
  259.     SourceMatch   = default( SourceMatch, 0 )
  260.     MatchNNSize   = NNSize
  261.     MatchNNeurons = NNeurons
  262.     MatchEdiMaxD  = EdiMaxD
  263.     MatchEdiQual  = EdiQual
  264.  
  265.     # However, can use a faster initial interpolation when using source-match allowing the basic source-match step to "correct" it with higher quality settings
  266.     Assert( SourceMatch == 0 || mpNum1 >= pNum, "'MatchPreset' cannot use a slower setting than 'Preset'" )
  267.     #                                                                    Very                                                        Very      Super     Ultra
  268.     # Basic source-match presets                                Placebo  Slow      Slower    Slow      Medium    Fast      Faster    Fast      Fast      Fast
  269.     NNSize   = (SourceMatch == 0) ? NNSize   : Select( mpNum1,  1,       1,        1,        1,        5,        5,        4,        4,        4,        4     )
  270.     NNeurons = (SourceMatch == 0) ? NNeurons : Select( mpNum1,  2,       2,        1,        1,        1,        0,        0,        0,        0,        0     )
  271.     EdiMaxD  = (SourceMatch == 0) ? EdiMaxD  : Select( mpNum1,  12,      10,       8,        7,        7,        6,        6,        5,        4,        4     )
  272.     EdiQual  = (SourceMatch == 0) ? EdiQual  : Select( mpNum1,  1,       1,        1,        1,        1,        1,        1,        1,        1,        1     )
  273.     TempEdi  = EdiMode # Main interpolation is actually done by basic-source match step when enabled, so a little swap and wriggle is needed
  274.     EdiMode  = (SourceMatch == 0) ? EdiMode  : default( MatchEdi, ((mpNum1 < 9) ?  EdiMode : "Yadif") ) # Force Yadif for "Ultra Fast" basic source match
  275.     MatchEdi = TempEdi
  276.  
  277.     #                                                          Very                                                        Very      Super     Ultra
  278.     # Refined source-match presets                   Placebo   Slow      Slower    Slow      Medium    Fast      Faster    Fast      Fast      Fast
  279.     MatchEdi2 = default( MatchEdi2, Select( mpNum2, "NNEDI3", "NNEDI3", "NNEDI3", "NNEDI3", "NNEDI3", "NNEDI3", "NNEDI3", "NNEDI3", "TDeint",  ""    ) )
  280.     MatchNNSize2                  = Select( mpNum2,  1,        1,        1,        1,        5,        5,        4,        4,        4,        4     )
  281.     MatchNNeurons2                = Select( mpNum2,  2,        2,        1,        1,        1,        0,        0,        0,        0,        0     )
  282.     MatchEdiMaxD2                 = Select( mpNum2,  12,       10,       8,        7,        7,        6,        6,        5,        4,        4     )
  283.     MatchEdiQual2                 = Select( mpNum2,  1,        1,        1,        1,        1,        1,        1,        1,        1,        1     )
  284.  
  285.  
  286.     #---------------------------------------
  287.     # Settings
  288.  
  289.     # Core and Interpolation defaults
  290.     TR2        = (SourceMatch > 0) ? default(TR2, ((TR2X == 0) ? 1 : TR2X)) : TR2X  # ***TR2 defaults always at least 1 when using source-match***
  291.     RepChroma  = default( RepChroma,  true )
  292.     EdiThreads = default( EdiThreads, 0    )
  293.     ChromaEdi  = default( ChromaEdi,  ""   )
  294.     NNeurons   = (EdiMode == "NNEDI2" && NNeurons > 2) ? 2 : NNeurons # Smaller range for NNeurons in NNEDI2 (which calls it nsize)
  295.     EdiQual    = (EdiMode == "EEDI3+NNEDI3" || EdiMode == "NNEDI3") && EdiQual > 2 ? 2 : EdiQual  # Smaller range for EdiQual in NNEDI3
  296.  
  297.     # Source-match / lossless defaults
  298.     MatchTR1     = TR1
  299.     MatchTR2     = default( MatchTR2,     1   )
  300.     MatchEnhance = default( MatchEnhance, 0.5 )
  301.     Lossless     = default( Lossless,     0   )
  302.     Assert( Lossless <= 2, "Lossless setting only supports mode 1 ('true lossless') and mode 2 ('fake lossless') - see documentation in script and consider source-match settings" )
  303.  
  304.     # Sharpness defaults. Sharpness default is always 1.0 (0.2 with source-match), but adjusted to give roughly same sharpness for all settings
  305.     SMode      = (defined(Sharpness) && Sharpness == 0.0) ? 0 : SMode
  306.     SLMode     = (SourceMatch > 0) ? default(SLMode, 0) : SLModeX  # ***Sharpness limiting disabled by default for source-match***
  307.     SLMode     = (SLRad <= 0)      ? 0 : SLMode
  308.     spatialSL  = (SLMode == 1 || SLMode == 3)
  309.     temporalSL = (SLMode == 2 || SLMode == 4)
  310.     Sharpness  = default( Sharpness, (SMode == 0) ? 0.0 : ((SourceMatch > 0) ? 0.2 : 1.0) )      # Default sharpness is 1.0, or 0.2 if using source-match
  311.     sharpMul   = (temporalSL) ? 2 : (spatialSL) ? 1.5 : 1                                        # Adjust sharpness based on other settings
  312.     sharpAdj   = Sharpness * (sharpMul * (0.2 + TR1*0.15 + TR2*0.25) + ((SMode == 1) ? 0.1 : 0)) # [This needs a bit more refinement]
  313.     Sbb        = (SMode == 0) ? 0 : Sbb
  314.     SOvs       = default( SOvs,   0   )
  315.     SVThin     = default( SVThin, 0.0 )
  316.  
  317.     # Noise processing settings
  318.     Assert( !defined(EZDenoise) || EZDenoise <= 0.0 || !defined(EZKeepGrain) || EZKeepGrain <= 0.0, "QTGMC: EZDenoise and EZKeepGrain cannot be used together" )
  319.     NoiseProcess = defined(NoiseProcess) ? NoiseProcess : \
  320.                    (defined(EZDenoise)   && EZDenoise   > 0.0)    ? 1 : \
  321.                    (defined(EZKeepGrain) && EZKeepGrain > 0.0)    ? 2 : \
  322.                    (Preset == "Placebo" || Preset == "Very Slow") ? 2 : 0
  323.     GrainRestore = defined(GrainRestore) ? GrainRestore : \
  324.                    (defined(EZDenoise)   && EZDenoise   > 0.0) ? 0.0 : \
  325.                    (defined(EZKeepGrain) && EZKeepGrain > 0.0) ? 0.3 * sqrt(EZKeepGrain) : \
  326.                                                                 Select( NoiseProcess, 0.0, 0.7, 0.3 )
  327.     NoiseRestore = defined(NoiseRestore) ? NoiseRestore : \
  328.                    (defined(EZDenoise)   && EZDenoise   > 0.0) ? 0.0 : \
  329.                    (defined(EZKeepGrain) && EZKeepGrain > 0.0) ? 0.1 * sqrt(EZKeepGrain) : \
  330.                                                                 Select( NoiseProcess, 0.0, 0.3, 0.1 )
  331.     Sigma        = defined(Sigma)       ? Sigma : \
  332.                    (defined(EZDenoise)   && EZDenoise   > 0.0) ? EZDenoise : \
  333.                    (defined(EZKeepGrain) && EZKeepGrain > 0.0) ? 4.0 * EZKeepGrain : 2.0
  334.     FftThreads   = default( FftThreads, EdiThreads )
  335.     ChromaNoise  = default( ChromaNoise, false )
  336.     ShowNoise    = default( ShowNoise, 0.0 )
  337.     ShowNoise    = IsBool( ShowNoise ) ? (ShowNoise ? 10.0 : 0.0) : ShowNoise
  338.     NoiseProcess = (ShowNoise > 0.0)   ? 2   : NoiseProcess
  339.     NoiseRestore = (ShowNoise > 0.0)   ? 1.0 : NoiseRestore
  340.     NoiseTR      = (NoiseProcess == 0) ? 0   : NoiseTR
  341.     GrainRestore = (NoiseProcess == 0) ? 0.0 : GrainRestore
  342.     NoiseRestore = (NoiseProcess == 0) ? 0.0 : NoiseRestore
  343.     totalRestore = GrainRestore + NoiseRestore
  344.     StabilizeNoise = (totalRestore <= 0) ? false : StabilizeNoise
  345.     noiseTD  = Select( NoiseTR, 1, 3, 5 )
  346.     noiseCentre = (Denoiser == "dfttest") ? "128" : "128.5"
  347.  
  348.     # MVTools settings
  349.     SubPelInterp = default( SubPelInterp, 2     )
  350.     TrueMotion   = default( TrueMotion,   false )
  351.     GlobalMotion = default( GlobalMotion, true  )
  352.     Lambda       = default( Lambda, ((TrueMotion) ? 1000 : 100 ) * (BlockSize*BlockSize)/(8*8) )
  353.     LSAD         = default( LSAD,    (TrueMotion) ? 1200 : 400 )
  354.     PNew         = default( PNew,    (TrueMotion) ? 50   : 25  )
  355.     PLevel       = default( PLevel,  (TrueMotion) ? 1    : 0   )
  356.     DCT          = default( DCT,     0          )
  357.     ThSAD1       = default( ThSAD1,  10 * 8*8   )
  358.     ThSAD2       = default( ThSAD2,   4 * 8*8   )
  359.     ThSCD1       = default( ThSCD1,  180        )
  360.     ThSCD2       = default( ThSCD2,  98         )
  361.  
  362.     # Motion blur settings
  363.     FPSDivisor  = default( FPSDivisor, 1 )
  364.     ShutterBlur = default( ShutterBlur, 0 )
  365.     ShutterAngleSrc = default( ShutterAngleSrc, 180 )
  366.     ShutterAngleOut = default( ShutterAngleOut, 180 )
  367.     SBlurLimit  = default( SBlurLimit, 4 )
  368.     ShutterBlur = (ShutterAngleOut * FPSDivisor == ShutterAngleSrc) ? 0 : ShutterBlur  # If motion blur output is same as input
  369.  
  370.     # Miscellaneous
  371.     InputType      = default( InputType,     0        )
  372.     Border         = default( Border,        false    )
  373.     ShowSettings   = default( ShowSettings,  false    )
  374.     GlobalNames    = default( GlobalNames,  "QTGMC"   )
  375.     PrevGlobals    = default( PrevGlobals,  "Replace" )
  376.     ForceTR        = default( ForceTR,       0        )
  377.     ReplaceGlobals = (PrevGlobals == "Replace" || PrevGlobals == "Reuse") # If reusing existing globals put them back afterwards - simplifies logic later
  378.     ReuseGlobals   = (PrevGlobals == "Reuse")
  379.     ProgSADMask    = (InputType != 2 && InputType != 3) ? 0.0 : ProgSADMask
  380.     rgBlur         = (Precise) ? 11 : 12
  381.  
  382.     # Get maximum temporal radius needed
  383.     maxTR = (temporalSL)       ? SLRad : 0
  384.     maxTR = (MatchTR2 > maxTR) ? MatchTR2 : maxTR
  385.     maxTR = (TR1 > maxTR)      ? TR1 : maxTR
  386.     maxTR = (TR2 > maxTR)      ? TR2 : maxTR
  387.     maxTR = (NoiseTR > maxTR)  ? NoiseTR : maxTR
  388.     maxTR = (ProgSADMask > 0.0 || StabilizeNoise || ShutterBlur > 0) ? (maxTR > 1 ? maxTR : 1) : maxTR
  389.     maxTR = (ForceTR > MaxTR)  ? ForceTR : maxTR
  390.  
  391.  
  392.     #---------------------------------------
  393.     # Pre-Processing
  394.  
  395.     w = Input.Width()
  396.     h = Input.Height()
  397.     yuy2 = Input.IsYUY2()
  398.     epsilon = 0.0001
  399.  
  400.     # Reverse "field" dominance for progressive repair mode 3 (only difference from mode 2)
  401.     compl = (InputType == 3) ? Input.ComplementParity() : Input
  402.  
  403.     # Pad vertically during processing (to prevent artefacts at top & bottom edges)
  404.     clip = (Border) ? compl.PointResize( w,h+8, 0,-4,0,h+8+epsilon ) : compl
  405.     h = (Border) ? h+8 : h
  406.  
  407.     # Calculate padding needed for MVTools super clips to avoid crashes [fixed in latest MVTools, but keeping this code for a while]
  408.     hpad = w - (Int((w - Overlap) / (Blocksize - Overlap)) * (Blocksize - Overlap) + Overlap)
  409.     vpad = h - (Int((h - Overlap) / (Blocksize - Overlap)) * (Blocksize - Overlap) + Overlap)
  410.     hpad = (hpad > 8) ? hpad : 8 # But match default padding if possible
  411.     vpad = (vpad > 8) ? vpad : 8
  412.  
  413.  
  414.     #---------------------------------------
  415.     # Motion Analysis
  416.  
  417.     # >>> Planar YUY2 for motion analysis, interleaved whilst blurring search clip
  418.     planarClip = yuy2 ? clip.converttoyv16() : clip
  419.  
  420.     # Bob the input as a starting point for motion search clip
  421.     bobbed = (InputType == 0) ? useEdiExt ? isyuy2(EdiExt) ? EdiExt.converttoyv16() : EdiExt : planarClip.QTGMC_Bob( 0,0.5 ) : \
  422.              (InputType == 1) ? planarClip : \
  423.                                 planarClip.Blur( 0,1 )
  424.  
  425.     # If required, get any existing global clips with a matching "GlobalNames" setting. Unmatched values get NOP (= 0)
  426.     srchClip  = QTGMC_GetUserGlobal( GlobalNames, "srchClip",  ReuseGlobals )
  427.     srchSuper = QTGMC_GetUserGlobal( GlobalNames, "srchSuper", ReuseGlobals )
  428.     bVec1     = QTGMC_GetUserGlobal( GlobalNames, "bVec1",     ReuseGlobals )
  429.     fVec1     = QTGMC_GetUserGlobal( GlobalNames, "fVec1",     ReuseGlobals )
  430.     bVec2     = QTGMC_GetUserGlobal( GlobalNames, "bVec2",     ReuseGlobals )
  431.     fVec2     = QTGMC_GetUserGlobal( GlobalNames, "fVec2",     ReuseGlobals )
  432.     bVec3     = QTGMC_GetUserGlobal( GlobalNames, "bVec3",     ReuseGlobals )
  433.     fVec3     = QTGMC_GetUserGlobal( GlobalNames, "fVec3",     ReuseGlobals )
  434.     bVec4     = QTGMC_GetUserGlobal( GlobalNames, "bVec4",     ReuseGlobals )
  435.     fVec4     = QTGMC_GetUserGlobal( GlobalNames, "fVec4",     ReuseGlobals )
  436.     bVec5     = QTGMC_GetUserGlobal( GlobalNames, "bVec5",     ReuseGlobals )
  437.     fVec5     = QTGMC_GetUserGlobal( GlobalNames, "fVec5",     ReuseGlobals )
  438.  
  439.     CMmt = ChromaMotion ? 3   :  1
  440.     CMts = ChromaMotion ? 255 :  0
  441.     CMrg = ChromaMotion ? 12  : -1
  442.  
  443.     # The bobbed clip will shimmer due to being derived from alternating fields. Temporally smooth over the neighboring frames using a binomial kernel. Binomial
  444.     # kernels give equal weight to even and odd frames and hence average away the shimmer. The two kernels used are [1 2 1] and [1 4 6 4 1] for radius 1 and 2.
  445.     # These kernels are approximately Gaussian kernels, which work well as a prefilter before motion analysis (hence the original name for this script)
  446.     # Create linear weightings of neighbors first                                                 -2    -1     0    1     2
  447.     ts1 = (!IsClip(srchClip) && TR0 > 0) ? bobbed.TemporalSoften( 1, 255,CMts, 28, 2 ) : NOP()  # 0.00  0.33  0.33  0.33  0.00
  448.     ts2 = (!IsClip(srchClip) && TR0 > 1) ? bobbed.TemporalSoften( 2, 255,CMts, 28, 2 ) : NOP()  # 0.20  0.20  0.20  0.20  0.20
  449.  
  450.     # Combine linear weightings to give binomial weightings - TR0=0: (1), TR0=1: (1:2:1), TR0=2: (1:4:6:4:1)
  451.     binomial0 = IsClip(srchClip) ? NOP() : \
  452.     TR0 == -1 && defined(EdiExt) ? isyuy2(EdiExt) ? EdiExt.converttoyv16() : EdiExt : \
  453.                 (TR0 == 0)       ? bobbed : \
  454.                 (TR0 == 1)       ? (ChromaMotion ? ts1.Merge( bobbed, 0.25 ) : ts1.MergeLuma( bobbed, 0.25 )) : \
  455.                                    (ChromaMotion ? ts1.Merge( ts2, 0.357 ).Merge( bobbed, 0.125 ) : ts1.MergeLuma( ts2, 0.357 ).MergeLuma( bobbed, 0.125 ))
  456.  
  457.     # Remove areas of difference between temporal blurred motion search clip and bob that are not due to bob-shimmer - removes general motion blur
  458.     repair0 = (IsClip(srchClip) || Rep0 == 0) ? binomial0 : binomial0.QTGMC_KeepOnlyBobShimmerFixes( bobbed, Rep0, (RepChroma && ChromaMotion) )
  459.  
  460.     # Blur image and soften edges to assist in motion matching of edge blocks. Blocks are matched by SAD (sum of absolute differences between blocks), but even
  461.     # a slight change in an edge from frame to frame will give a high SAD due to the higher contrast of edges
  462.     spatialBlur = (IsClip(srchClip) || SrchClipPP == 0) ? NOP() : \
  463.                   (SrchClipPP == 1) ? repair0.BilinearResize( w/2, h/2 ).RemoveGrain( 12,CMrg).BilinearResize( w, h ) : \
  464.                                       repair0.RemoveGrain( 12,CMrg).GaussResize( w,h, 0,0, w+epsilon,h+epsilon, p=2 )
  465.  
  466.     spatialBlur = (IsClip(spatialBlur) && SrchClipPP > 1) ? (ChromaMotion ? spatialBlur.Merge( repair0, 0.1 ) : spatialBlur.MergeLuma( repair0, 0.1 )) : spatialBlur
  467.     tweaked     = (!IsClip(srchClip) && SrchClipPP > 1) ? mt_lutxy( repair0, bobbed, "x 3 + y < x 3 + x 3 - y > x 3 - y ? ?", U=CMmt,V=CMmt ) : NOP()
  468.     srchcheck   = IsClip(srchClip)
  469.     srchClip    = srchcheck         ? srchClip : \
  470.                   (SrchClipPP == 0) ? repair0 : \
  471.                   (SrchClipPP < 3)  ? spatialBlur : \
  472.                                       spatialBlur.mt_lutxy( tweaked, "x 7 + y < x 2 + x 7 - y > x 2 - x 51 * y 49 * + 100 / ? ?", U=CMmt,V=CMmt )
  473.     srchClip    = tv_range && !srchcheck ? srchClip.Dither_Luma_Rebuild(S0=Str,c=Amp,slice=false,lsb=lsb,uv=CMmt) : srchClip
  474.     # Calculate forward and backward motion vectors from motion search clip
  475.     srchSuper = IsClip(srchSuper) ? srchSuper : \
  476.                 (maxTR > 0)       ? srchClip.MSuper( pel=SubPel, sharp=SubPelInterp, hpad=hpad, vpad=vpad, chroma=ChromaMotion ) : NOP()
  477.     bVec5 = IsClip(bVec5) ? bVec5 : \
  478.             (maxTR > 4)   ? srchSuper.MAnalyse( isb=true,  delta=5, blksize=BlockSize, overlap=Overlap, search=Search, searchparam=SearchParam, \
  479.                                                 pelsearch=PelSearch, truemotion=TrueMotion, lambda=Lambda, lsad=LSAD, pnew=PNew, plevel=PLevel, \
  480.                                                 global=GlobalMotion, DCT=DCT, chroma=ChromaMotion ) : NOP()
  481.     bVec4 = IsClip(bVec4) ? bVec4 : \
  482.             (maxTR > 3)   ? srchSuper.MAnalyse( isb=true,  delta=4, blksize=BlockSize, overlap=Overlap, search=Search, searchparam=SearchParam, \
  483.                                                 pelsearch=PelSearch, truemotion=TrueMotion, lambda=Lambda, lsad=LSAD, pnew=PNew, plevel=PLevel, \
  484.                                                 global=GlobalMotion, DCT=DCT, chroma=ChromaMotion ) : NOP()
  485.     bVec3 = IsClip(bVec3) ? bVec3 : \
  486.             (maxTR > 2)   ? srchSuper.MAnalyse( isb=true,  delta=3, blksize=BlockSize, overlap=Overlap, search=Search, searchparam=SearchParam, \
  487.                                                 pelsearch=PelSearch, truemotion=TrueMotion, lambda=Lambda, lsad=LSAD, pnew=PNew, plevel=PLevel, \
  488.                                                 global=GlobalMotion, DCT=DCT, chroma=ChromaMotion ) : NOP()
  489.     bVec2 = IsClip(bVec2) ? bVec2 : \
  490.             (maxTR > 1)   ? srchSuper.MAnalyse( isb=true,  delta=2, blksize=BlockSize, overlap=Overlap, search=Search, searchparam=SearchParam, \
  491.                                                 pelsearch=PelSearch, truemotion=TrueMotion, lambda=Lambda, lsad=LSAD, pnew=PNew, plevel=PLevel, \
  492.                                                 global=GlobalMotion, DCT=DCT, chroma=ChromaMotion ) : NOP()
  493.     bVec1 = IsClip(bVec1) ? bVec1 : \
  494.             (maxTR > 0)   ? srchSuper.MAnalyse( isb=true,  delta=1, blksize=BlockSize, overlap=Overlap, search=Search, searchparam=SearchParam, \
  495.                                                 pelsearch=PelSearch, truemotion=TrueMotion, lambda=Lambda, lsad=LSAD, pnew=PNew, plevel=PLevel, \
  496.                                                 global=GlobalMotion, DCT=DCT, chroma=ChromaMotion ) : NOP()
  497.     fVec1 = IsClip(fVec1) ? fVec1 : \
  498.             (maxTR > 0)   ? srchSuper.MAnalyse( isb=false, delta=1, blksize=BlockSize, overlap=Overlap, search=Search, searchparam=SearchParam, \
  499.                                                 pelsearch=PelSearch, truemotion=TrueMotion, lambda=Lambda, lsad=LSAD, pnew=PNew, plevel=PLevel, \
  500.                                                 global=GlobalMotion, DCT=DCT, chroma=ChromaMotion ) : NOP()
  501.     fVec2 = IsClip(fVec2) ? fVec2 : \
  502.             (maxTR > 1)   ? srchSuper.MAnalyse( isb=false, delta=2, blksize=BlockSize, overlap=Overlap, search=Search, searchparam=SearchParam, \
  503.                                                 pelsearch=PelSearch, truemotion=TrueMotion, lambda=Lambda, lsad=LSAD, pnew=PNew, plevel=PLevel, \
  504.                                                 global=GlobalMotion, DCT=DCT, chroma=ChromaMotion ) : NOP()
  505.     fVec3 = IsClip(fVec3) ? fVec3 : \
  506.             (maxTR > 2)   ? srchSuper.MAnalyse( isb=false, delta=3, blksize=BlockSize, overlap=Overlap, search=Search, searchparam=SearchParam, \
  507.                                                 pelsearch=PelSearch, truemotion=TrueMotion, lambda=Lambda, lsad=LSAD, pnew=PNew, plevel=PLevel, \
  508.                                                 global=GlobalMotion, DCT=DCT, chroma=ChromaMotion ) : NOP()
  509.     fVec4 = IsClip(fVec4) ? fVec4 : \
  510.             (maxTR > 3)   ? srchSuper.MAnalyse( isb=false, delta=4, blksize=BlockSize, overlap=Overlap, search=Search, searchparam=SearchParam, \
  511.                                                 pelsearch=PelSearch, truemotion=TrueMotion, lambda=Lambda, lsad=LSAD, pnew=PNew, plevel=PLevel, \
  512.                                                 global=GlobalMotion, DCT=DCT, chroma=ChromaMotion ) : NOP()
  513.     fVec5 = IsClip(fVec5) ? fVec5 : \
  514.             (maxTR > 4)   ? srchSuper.MAnalyse( isb=false, delta=5, blksize=BlockSize, overlap=Overlap, search=Search, searchparam=SearchParam, \
  515.                                                 pelsearch=PelSearch, truemotion=TrueMotion, lambda=Lambda, lsad=LSAD, pnew=PNew, plevel=PLevel, \
  516.                                                 global=GlobalMotion, DCT=DCT, chroma=ChromaMotion ) : NOP()
  517.  
  518.     # Expose search clip, motion search super clip and motion vectors to calling script through globals
  519.     QTGMC_SetUserGlobal( GlobalNames, "srchClip",  srchClip,  ReplaceGlobals )
  520.     QTGMC_SetUserGlobal( GlobalNames, "srchSuper", srchSuper, ReplaceGlobals )
  521.     QTGMC_SetUserGlobal( GlobalNames, "bVec1",     bVec1,     ReplaceGlobals )
  522.     QTGMC_SetUserGlobal( GlobalNames, "fVec1",     fVec1,     ReplaceGlobals )
  523.     QTGMC_SetUserGlobal( GlobalNames, "bVec2",     bVec2,     ReplaceGlobals )
  524.     QTGMC_SetUserGlobal( GlobalNames, "fVec2",     fVec2,     ReplaceGlobals )
  525.     QTGMC_SetUserGlobal( GlobalNames, "bVec3",     bVec3,     ReplaceGlobals )
  526.     QTGMC_SetUserGlobal( GlobalNames, "fVec3",     fVec3,     ReplaceGlobals )
  527.     QTGMC_SetUserGlobal( GlobalNames, "bVec4",     bVec4,     ReplaceGlobals )
  528.     QTGMC_SetUserGlobal( GlobalNames, "fVec4",     fVec4,     ReplaceGlobals )
  529.     QTGMC_SetUserGlobal( GlobalNames, "bVec5",     bVec5,     ReplaceGlobals )
  530.     QTGMC_SetUserGlobal( GlobalNames, "fVec5",     fVec5,     ReplaceGlobals )
  531.  
  532.  
  533.     #---------------------------------------
  534.     # Noise Processing
  535.  
  536.     # >>>> Interleaved YUY2 for denoising, planar whilst pre-motion compensating
  537.  
  538.     # Expand fields to full frame size before extracting noise (allows use of motion vectors which are frame-sized)
  539.     fullClip  = (NoiseProcess == 0) ? NOP() : \
  540.                 (InputType > 0)     ? clip : \
  541.                                       clip.QTGMC_Bob( 0,1.0 )
  542.     fullClip  = (yuy2 && NoiseTR > 0) ? fullClip.converttoyv16() : fullClip
  543.     fullSuper = (NoiseTR > 0)         ? fullClip.MSuper( pel=SubPel, levels=1, hpad=hpad, vpad=vpad, chroma=ChromaNoise ) : NOP() #TEST chroma OK?
  544.  
  545.     # Create a motion compensated temporal window around current frame and use to guide denoisers
  546.     noiseWindow = (NoiseProcess == 0) ? NOP() : \
  547.                   (!DenoiseMC)        ? fullClip : \
  548.                   (NoiseTR == 0)      ? fullClip : \
  549.                   (NoiseTR == 1)      ? Interleave( fullClip.MCompensate( fullSuper, fVec1, thSCD1=ThSCD1,thSCD2=ThSCD2 ), \
  550.                                                     fullClip, \
  551.                                                     fullClip.MCompensate( fullSuper, bVec1, thSCD1=ThSCD1,thSCD2=ThSCD2 ) ) : \
  552.                                         Interleave( fullClip.MCompensate( fullSuper, fVec2, thSCD1=ThSCD1,thSCD2=ThSCD2 ), \
  553.                                                     fullClip.MCompensate( fullSuper, fVec1, thSCD1=ThSCD1,thSCD2=ThSCD2 ), \
  554.                                                     fullClip, \
  555.                                                     fullClip.MCompensate( fullSuper, bVec1, thSCD1=ThSCD1,thSCD2=ThSCD2 ), \
  556.                                                     fullClip.MCompensate( fullSuper, bVec2, thSCD1=ThSCD1,thSCD2=ThSCD2 ) )
  557.     noiseWindow = yuy2 && (Denoiser == "fft3df") && NoiseTR > 0 ? noiseWindow.ConvertToYUY2() : noiseWindow
  558.     dnWindow = (NoiseProcess == 0)      ? NOP() : \
  559.                (Denoiser == "dfttest")  ? noiseWindow.dfttest( Y=true, U=ChromaNoise, V=ChromaNoise, sigma=Sigma*4, tbsize=noiseTD, threads=FftThreads, lsb=lsbd ) : \
  560.             (Denoiser == "KNLMeansCL")  ? noiseWindow.SMDegrain_KNLMeansCL(Chroma=ChromaNoise, lsb=lsbd, a=2, d=NoiseTR, h=Sigma, device_type="GPU" ) : \
  561.                                           noiseWindow.FFT3DFilter( plane=(ChromaNoise ? 4 : 0), sigma=Sigma, bt=noiseTD, ncpu=FftThreads )
  562.     dnwindow = (Denoiser == "KNLMeansCL" || Denoiser == "dfttest") && (NoiseProcess != 0) && lsbd ? dnWindow.ditherpost(mode=6, U=ChromaNoise?3:2, V=ChromaNoise?3:2, slice=false) : dnWindow
  563.     dnwindow = (Denoiser == "KNLMeansCL" || Denoiser == "dfttest") && (NoiseProcess != 0) && yuy2 ? dnWindow.ConvertToYUY2() : dnWindow
  564.  
  565.     # Rework denoised clip to match source format - various code paths here: discard the motion compensation window, discard doubled lines (from point resize)
  566.     # Also reweave to get interlaced noise if source was interlaced (could keep the full frame of noise, but it will be poor quality from the point resize)
  567.     denoised = (NoiseProcess == 0) ? NOP() : \
  568.                (!DenoiseMC)        ? ((InputType > 0) ? dnWindow : dnWindow.SeparateFields().SelectEvery( 4, 0,3 ).Weave()) : \
  569.                (InputType > 0)     ? ((NoiseTR == 0)  ? dnWindow : dnWindow.SelectEvery( noiseTD, NoiseTR )) : \
  570.                                      dnWindow.SeparateFields().SelectEvery( noiseTD*4, NoiseTR*2,NoiseTR*6+3 ).Weave()
  571.  
  572.     # >>>> Switch to planar YUY2 for noise bypass
  573.  
  574.     CNmt1   = ChromaNoise ? 3 : 1
  575.     CNmt2   = ChromaNoise ? 3 : 2
  576.     CNmt128 = ChromaNoise ? 3 : -128
  577.  
  578.     # Get actual noise from difference. Then 'deinterlace' where we have weaved noise - create the missing lines of noise in various ways
  579.     planarDenoised = (NoiseProcess == 0) ? NOP() : yuy2 ? denoised.converttoyv16() : denoised
  580.     noise = (totalRestore > 0.0)  ? mt_makediff( planarClip, planarDenoised, U=CNmt1,V=CNmt1 ) : NOP()
  581.     deintNoise = (NoiseProcess == 0 || totalRestore == 0.0) ? NOP() : \
  582.                  (InputType != 0)                           ? noise : \
  583.                  (NoiseDeint == "Bob")                      ? noise.QTGMC_Bob( 0,0.5 ) : \
  584.                  (NoiseDeint == "Generate")                 ? noise.QTGMC_Generate2ndFieldNoise( denoised, ChromaNoise ) : \
  585.                                                               noise.DoubleWeave()
  586.     # Motion-compensated stabilization of generated noise
  587.     noiseSuper = (StabilizeNoise) ? deintNoise.MSuper( pel=SubPel, sharp=SubPelInterp, levels=1, hpad=hpad, vpad=vpad, chroma=ChromaNoise ) : NOP()
  588.     mcNoise    = (StabilizeNoise) ? deintNoise.MCompensate( noiseSuper, bVec1, thSCD1=ThSCD1,thSCD2=ThSCD2 ) : NOP()
  589.     finalNoise = (StabilizeNoise) ? mt_lutxy( deintNoise, mcNoise, "x 128 - abs y 128 - abs > x y ? 0.6 * x y + 0.2 * +", U=CNmt1,V=CNmt1 ) : deintNoise
  590.  
  591.     # If NoiseProcess=1 denoise input clip. If NoiseProcess=2 leave noise in the clip and let the temporal blurs "denoise" it for a stronger effect
  592.     innerClip = (NoiseProcess == 1) ? denoised : clip
  593.  
  594.  
  595.     #---------------------------------------
  596.     # Interpolation
  597.  
  598.     # >>>> Interleaved YUY2 for interpolation
  599.  
  600.     # Support badly deinterlaced progressive content - drop half the fields and reweave to get 1/2fps interlaced stream appropriate for QTGMC processing
  601.     ediInput = (InputType == 2 || InputType == 3) ? innerClip.SeparateFields().SelectEvery(4,0,3).Weave() : innerClip
  602.  
  603.     # Create interpolated image as starting point for output
  604.     edi1 = defined(EdiExt) ? EdiExt.PointResize( w,h, 0,(EdiExt.Height()-h)/2, -0,h+epsilon ) : \
  605.                              QTGMC_Interpolate( ediInput, InputType, EdiMode, NNSize, NNeurons, EdiQual, EdiMaxD, EdiThreads, bobbed, ChromaEdi )
  606.  
  607.     # >>>> Switch to planar YUY2 during next step - remains planar until very end of script except blurring for back blending & SVThin
  608.  
  609.     # InputType=2,3: use motion mask to blend luma between original clip & reweaved clip based on ProgSADMask setting. Use chroma from original clip in any case
  610.     inputTypeBlend = (ProgSADMask > 0.0) ? MMask( srchClip, bVec1, kind=1, ml=ProgSADMask ) : NOP()
  611.     edi = (InputType != 2 && InputType != 3) ? (!yuy2 ? edi1 : edi1.ConvertToYV16()) :\
  612.           (ProgSADMask <= 0.0)               ? (!yuy2 ? edi1.MergeChroma( innerClip ) : edi1.MergeChroma( innerClip ).ConvertToYV16()) : \
  613.                                                (!yuy2 ? mt_merge( innerClip, edi1, inputTypeBlend, U=2,V=2 ) : \
  614.                                                         mt_merge( innerClip.ConvertToYV16(), edi1.ConvertToYV16(), inputTypeBlend, U=2,V=2 ))
  615.  
  616.     # Get the max/min value for each pixel over neighboring motion-compensated frames - used for temporal sharpness limiting
  617.     ediSuper = (TR1 > 0 || temporalSL)   ? edi.MSuper( pel=SubPel, sharp=SubPelInterp, levels=1, hpad=hpad, vpad=vpad ) : NOP()
  618.     bComp1   = (temporalSL)              ? edi.MCompensate( ediSuper, bVec1, thSCD1=ThSCD1,thSCD2=ThSCD2              ) : NOP()
  619.     fComp1   = (temporalSL)              ? edi.MCompensate( ediSuper, fVec1, thSCD1=ThSCD1,thSCD2=ThSCD2              ) : NOP()
  620.     tMax     = (temporalSL)              ? edi.mt_logic( fComp1, "max", U=3,V=3 ).mt_logic( bComp1, "max", U=3,V=3 )    : NOP()
  621.     tMin     = (temporalSL)              ? edi.mt_logic( fComp1, "min", U=3,V=3 ).mt_logic( bComp1, "min", U=3,V=3 )    : NOP()
  622.     bComp3   = (SLRad > 1 && temporalSL) ? edi.MCompensate( ediSuper, bVec3, thSCD1=ThSCD1,thSCD2=ThSCD2              ) : NOP()
  623.     fComp3   = (SLRad > 1 && temporalSL) ? edi.MCompensate( ediSuper, fVec3, thSCD1=ThSCD1,thSCD2=ThSCD2              ) : NOP()
  624.     tMax     = (SLRad > 1 && temporalSL) ? tMax.mt_logic( fComp3, "max", U=3,V=3 ).mt_logic( bComp3, "max", U=3,V=3 )   : tMax
  625.     tMin     = (SLRad > 1 && temporalSL) ? tMin.mt_logic( fComp3, "min", U=3,V=3 ).mt_logic( bComp3, "min", U=3,V=3 )   : tMin
  626.  
  627.  
  628.     #---------------------------------------
  629.     # Create basic output
  630.  
  631.     # Use motion vectors to blur interpolated image (edi) with motion-compensated previous and next frames. As above, this is done to remove shimmer from
  632.     # alternate frames so the same binomial kernels are used. However, by using motion-compensated smoothing this time we avoid motion blur. The use of
  633.     # MDegrain1 (motion compensated) rather than TemporalSmooth makes the weightings *look* different, but they evaluate to the same values
  634.     # Create linear weightings of neighbors first                                                                                -2    -1     0    1     2
  635.     degrain1 = (TR1 > 0) ? edi.MDegrain1( ediSuper, bVec1,fVec1, thSAD=ThSAD1, thSCD1=ThSCD1,thSCD2=ThSCD2, lsb=lsb) : NOP()  # 0.00  0.33  0.33  0.33  0.00
  636.     degrain2 = (TR1 > 1) ? edi.MDegrain1( ediSuper, bVec2,fVec2, thSAD=ThSAD1, thSCD1=ThSCD1,thSCD2=ThSCD2, lsb=lsb) : NOP()  # 0.33  0.00  0.33  0.00  0.33
  637.     degrain1 = (TR1 > 0) && lsb ? degrain1.ditherpost(mode=6, slice=false) : degrain1
  638.     degrain2 = (TR1 > 1) && lsb ? degrain2.ditherpost(mode=6, slice=false) : degrain2
  639.  
  640.     # Combine linear weightings to give binomial weightings - TR1=0: (1), TR1=1: (1:2:1), TR1=2: (1:4:6:4:1)
  641.     binomial1 = (TR1 == 0) ? edi : \
  642.                 (TR1 == 1) ? degrain1.Merge( edi, 0.25 ) : \
  643.                              degrain1.Merge( degrain2, 0.2 ).Merge( edi, 0.0625 )
  644.  
  645.     # Remove areas of difference between smoothed image and interpolated image that are not bob-shimmer fixes: repairs residual motion blur from temporal smooth
  646.     repair1 = (Rep1 == 0) ? binomial1 : binomial1.QTGMC_KeepOnlyBobShimmerFixes( edi, Rep1, RepChroma )
  647.  
  648.     # Apply source match - use difference between output and source to succesively refine output [extracted to function to clarify main code path]
  649.     match = (SourceMatch == 0) ? repair1 : \
  650.                                  repair1.QTGMC_ApplySourceMatch( InputType, ediInput, bVec1,fVec1, bVec2,fVec2, SubPel, SubPelInterp, hpad, vpad, \
  651.                                                                  ThSAD1, ThSCD1, ThSCD2, SourceMatch, MatchTR1, MatchEdi, MatchNNSize, MatchNNeurons, \
  652.                                                                  MatchEdiQual, MatchEdiMaxD, MatchTR2, MatchEdi2, MatchNNSize2, MatchNNeurons2, MatchEdiQual2, \
  653.                                                                  MatchEdiMaxD2, MatchEnhance, EdiThreads, lsb )
  654.  
  655.     # Lossless=2 - after preparing an interpolated, de-shimmered clip, restore the original source fields into it and clean up any artefacts.
  656.     # This mode will not give a true lossless result because the resharpening and final temporal smooth are still to come, but it will add further detail.
  657.     # However, it can introduce minor combing. This setting is best used together with source-match (it's effectively the final source-match stage).
  658.     lossed1 = (Lossless == 2) ? QTGMC_MakeLossless( match, innerClip, InputType ) : match
  659.  
  660.  
  661.     #---------------------------------------
  662.     # Resharpen / retouch output
  663.  
  664.     # Resharpen to counteract temporal blurs. Little sharpening needed for source-match mode since it has already recovered sharpness from source
  665.     vresharp1 = (SMode == 2) ? Merge( lossed1.mt_expand( mode="vertical", U=3,V=3 ), lossed1.mt_inpand( mode="vertical", U=3,V=3 ) ) : NOP()
  666.     vresharp  = (Precise && SMode == 2) ? vresharp1.mt_lutxy( lossed1, "x y < x 1 + x y > x 1 - x ? ?", U=3,V=3 ) : vresharp1 # Precise mode: reduce tiny overshoot
  667.     resharp   = (SMode == 0) ? lossed1 : \
  668.                 (SMode == 1) ? lossed1.mt_lutxy( lossed1.RemoveGrain( rgBlur ),  "x x y - "+ string(sharpAdj) + " * +", U=3,V=3 ) : \
  669.                                lossed1.mt_lutxy( vresharp.RemoveGrain( rgBlur ), "x x y - "+ string(sharpAdj) + " * +", U=3,V=3 )
  670.  
  671.     # Slightly thin down 1-pixel high horizontal edges that have been widened into neigboring field lines by the interpolator
  672.     SVThinSc = SVThin * 6.0
  673.     vertMedD = (SVthin > 0.0) ? mt_lutxy( lossed1, lossed1.VerticalCleaner( mode=1, modeU=-1, modeV=-1 ), "y x - " + string(SVThinSc) + " * 128 +", U=1,V=1 ) : NOP()
  674.     vertMedD = (SVthin > 0.0) ? (vertMedD.Blur( 1,0 )) : NOP()
  675.     neighborD = (SVthin > 0.0) ? mt_lutxy( vertMedD, vertMedD.RemoveGrain( rgBlur,-1 ), "y 128 - abs x 128 - abs > y 128 ?" ) : NOP()
  676.     thin      = (SVthin > 0.0) ? resharp.mt_adddiff( neighborD, U=2,V=2 ) : resharp
  677.  
  678.     # Back blend the blurred difference between sharpened & unsharpened clip, before (1st) sharpness limiting (Sbb == 1,3). A small fidelity improvement
  679.     backBlend1 = (Sbb != 1 && Sbb != 3) ? thin : \
  680.                          thin.mt_makediff( mt_makediff( thin, lossed1, U=1,V=1 ).RemoveGrain( 12, -1 ) \
  681.                              .GaussResize( w,h, 0,0, w+epsilon,h+epsilon, p=5 ), U=2,V=2 )
  682.  
  683.     # Limit over-sharpening by clamping to neighboring (spatial or temporal) min/max values in original
  684.     # Occurs here (before final temporal smooth) if SLMode == 1,2. This location will restrict sharpness more, but any artefacts introduced will be smoothed
  685.     sharpLimit1 = (SLMode == 1) ? backBlend1.Repair( ((SLrad <= 1) ? edi : backBlend1.Repair( edi, 12 )), 1 ) : \
  686.                   (SLMode == 2) ? backBlend1.mt_clamp( tMax,tMin, Sovs,Sovs, U=3,V=3 ) : \
  687.                                   backBlend1
  688.  
  689.     # Back blend the blurred difference between sharpened & unsharpened clip, after (1st) sharpness limiting (Sbb == 2,3). A small fidelity improvement
  690.     backBlend2 = (Sbb < 2) ? sharpLimit1 : \
  691.                          sharpLimit1.mt_makediff( mt_makediff( sharpLimit1, lossed1, U=1,V=1 ).RemoveGrain( 12, -1 ) \
  692.                                         .GaussResize( w,h, 0,0, w+epsilon,h+epsilon, p=5 ), U=2,V=2 )
  693.  
  694.     # Add back any extracted noise, prior to final temporal smooth - this will restore detail that was removed as "noise" without restoring the noise itself
  695.     # Average luma of FFT3DFilter extracted noise is 128.5, so deal with that too
  696.     addNoise1 = (GrainRestore <= 0.0) ? backBlend2 : \
  697.                                         backBlend2.mt_adddiff( finalNoise.mt_lut( "x " + noiseCentre + " - " + string(GrainRestore) + " * 128 +", U=CNmt1,V=CNmt1 ), U=CNmt2,V=CNmt2 )
  698.  
  699.     # Final light linear temporal smooth for denoising
  700.     stableSuper = (TR2 > 0) ? addNoise1.MSuper( pel=SubPel, sharp=SubPelInterp, levels=1, hpad=hpad, vpad=vpad ) : NOP()
  701.     stable  = (TR2 == 0) ? addNoise1 : \
  702.               (TR2 == 1) ? addNoise1.MDegrain1( stableSuper, bVec1,fVec1,                                                     thSAD=ThSAD2, thSCD1=ThSCD1,thSCD2=ThSCD2, lsb=lsb ) : \
  703.               (TR2 == 2) ? addNoise1.MDegrain2( stableSuper, bVec1,fVec1, bVec2,fVec2,                                        thSAD=ThSAD2, thSCD1=ThSCD1,thSCD2=ThSCD2, lsb=lsb ) : \
  704.               (TR2 == 3) ? addNoise1.MDegrain3( stableSuper, bVec1,fVec1, bVec2,fVec2, bVec3,fVec3,                           thSAD=ThSAD2, thSCD1=ThSCD1,thSCD2=ThSCD2, lsb=lsb ) : \
  705.               (TR2 == 4) ? addNoise1.MDegrain4( stableSuper, bVec1,fVec1, bVec2,fVec2, bVec3,fVec3, bVec4,fVec4,              thSAD=ThSAD2, thSCD1=ThSCD1,thSCD2=ThSCD2, lsb=lsb ) : \
  706.                            addNoise1.MDegrain5( stableSuper, bVec1,fVec1, bVec2,fVec2, bVec3,fVec3, bVec4,fVec4, bVec5,fVec5, thSAD=ThSAD2, thSCD1=ThSCD1,thSCD2=ThSCD2, lsb=lsb )
  707.     stable  = (TR2 > 0) && lsb ? stable.ditherpost(mode=6, slice=false) : stable
  708.  
  709.     # Remove areas of difference between final output & basic interpolated image that are not bob-shimmer fixes: repairs motion blur caused by temporal smooth
  710.     repair2 = (Rep2 == 0) ? stable : stable.QTGMC_KeepOnlyBobShimmerFixes( edi, Rep2, RepChroma )
  711.  
  712.     # Limit over-sharpening by clamping to neighboring (spatial or temporal) min/max values in original
  713.     # Occurs here (after final temporal smooth) if SLMode == 3,4. Allows more sharpening here, but more prone to introducing minor artefacts
  714.     sharpLimit2 = (SLMode == 3) ? repair2.Repair( ((SLrad <= 1) ? edi : repair2.Repair( edi, 12 )), 1 ) : \
  715.                   (SLMode == 4) ? repair2.mt_clamp( tMax,tMin, Sovs,Sovs, U=3,V=3 ) : \
  716.                                   repair2
  717.  
  718.     # Lossless=1 - inject source fields into result and clean up inevitable artefacts. Provided NoiseRestore=0.0 or 1.0, this mode will make the script result
  719.     # properly lossless, but this will retain source artefacts and cause some combing (where the smoothed deinterlace doesn't quite match the source)
  720.     lossed2 = (Lossless == 1) ? QTGMC_MakeLossless( sharpLimit2, innerClip, InputType ) : sharpLimit2
  721.  
  722.     # Add back any extracted noise, after final temporal smooth. This will appear as noise/grain in the output
  723.     # Average luma of FFT3DFilter extracted noise is 128.5, so deal with that too
  724.     addNoise2 = (NoiseRestore <= 0.0) ? lossed2 : \
  725.                                         lossed2.mt_adddiff( finalNoise.mt_lut( "x " + noiseCentre + " - " + string(NoiseRestore) + " * 128 +", U=CNmt1,V=CNmt1 ), U=CNmt2,V=CNmt2 )
  726.  
  727.  
  728.     #---------------------------------------
  729.     # Post-Processing
  730.  
  731.     # Shutter motion blur - get level of blur depending on output framerate and blur already in source
  732.     blurLevel = (ShutterAngleOut * FPSDivisor - ShutterAngleSrc) * 100.0 / 360.0
  733.     Assert( blurLevel >= 0, "Cannot reduce motion blur already in source: increase ShutterAngleOut or FPSDivisor" )
  734.     Assert( blurLevel <= 200, "Exceeded maximum motion blur level: decrease ShutterAngleOut or FPSDivisor" )
  735.  
  736.     # ShutterBlur mode 2,3 - get finer resolution motion vectors to reduce blur "bleeding" into static areas
  737.     rBlockDivide = Select( ShutterBlur, 1, 1, 2, 4 )
  738.     rBlockSize = BlockSize / rBlockDivide
  739.     rOverlap   = Overlap   / rBlockDivide
  740.     rBlockSize = (rBlockSize < 4) ? 4 : rBlockSize
  741.     rOverlap   = (rOverlap   < 2) ? 2 : rOverlap
  742.     rBlockDivide = BlockSize / rBlockSize
  743.     rLambda = Lambda / (rBlockDivide * rBlockDivide)
  744.     sbBVec1 = (ShutterBlur > 1) ? srchSuper.MRecalculate( bVec1, thSAD=ThSAD1, blksize=rBlockSize, overlap=rOverlap, search=Search, searchparam=SearchParam, \
  745.                                                           truemotion=TrueMotion, lambda=Lambda, pnew=PNew, DCT=DCT, chroma=ChromaMotion ) : bVec1
  746.     sbFVec1 = (ShutterBlur > 1) ? srchSuper.MRecalculate( fVec1, thSAD=ThSAD1, blksize=rBlockSize, overlap=rOverlap, search=Search, searchparam=SearchParam, \
  747.                                                           truemotion=TrueMotion, lambda=Lambda, pnew=PNew, DCT=DCT, chroma=ChromaMotion ) : fVec1
  748.  
  749.     # Shutter motion blur - use MFlowBlur to blur along motion vectors
  750.     sblurSuper = (ShutterBlur > 0) ? addNoise2.MSuper( pel=SubPel, sharp=SubPelInterp, levels=1, hpad=hpad, vpad=vpad ) : NOP()
  751.     sblur =      (ShutterBlur > 0) ? addNoise2.MFlowBlur( sblurSuper, sbBVec1, sbFVec1, blur=blurLevel, thSCD1=ThSCD1,thSCD2=ThSCD2 ) : NOP()
  752.  
  753.     # Shutter motion blur - use motion mask to reduce blurring in areas of low motion - also helps reduce blur "bleeding" into static areas, then select blur type
  754.     sbMotionMask = (ShutterBlur > 0 && SBlurLimit > 0) ? MMask( srchClip, bVec1, kind=0, ml=SBlurLimit ) : NOP()
  755.     sblurred     = (ShutterBlur == 0) ? addNoise2 : \
  756.                    (SBlurLimit == 0)  ? sblur : \
  757.                                         mt_merge( addNoise2, sblur, sbMotionMask, U=3,V=3 )
  758.     # Reduce frame rate
  759.     decimated = (FPSDivisor != 1) ? sblurred.SelectEvery( FPSDivisor, 0 ) : sblurred
  760.  
  761.     # Crop off temporary vertical padding
  762.     cropped = Border ? decimated.Crop( 0, 4, -0, -4 ) : decimated
  763.     h = Border ? h-8 : h
  764.  
  765.     # Show output of choice + settings
  766.     # >>>> Restore YUY2 to interleaved
  767.     output = (ShowNoise == 0.0) ? cropped : finalNoise.mt_lut( "x 128 - " + string(ShowNoise) + " * 128 +", U=CNmt128,V=CNmt128 )
  768.     output = yuy2 ? output.ConvertToYUY2() : output
  769.     return (ShowSettings == false) ? output : \
  770.         output.Subtitle( "TR0=" + string(TR0) + " | TR1=" + string(TR1) + " | TR2=" + string(TR2) + " | Rep0=" + string(Rep0) + " | Rep1=" + string(Rep1) + \
  771.         " | Rep2=" + string(Rep2) + " | RepChroma=" + string(RepChroma) + "\nEdiMode='" + EdiMode + "' | NNSize=" + string(NNSize) + " | NNeurons=" + \
  772.         string(NNeurons) + " | EdiQual=" + string(EdiQual) + " | EdiMaxD=" + string(EdiMaxD) + " | ChromaEdi='" + ChromaEdi + "' | EdiThreads=" + \
  773.         string(EdiThreads) + "\nSharpness=" + string(Sharpness, "%.2f") + " | SMode=" + string(SMode) + " | SLMode=" + string(SLMode) + " | SLRad=" + \
  774.         string(SLRad) + " | SOvs=" + string(SOvs) + " | SVThin=" + string(SVThin, "%.2f") + " | Sbb=" + string(Sbb) + "\nSrchClipPP=" + string(SrchClipPP) + \
  775.         " | SubPel=" + string(SubPel) + " | SubPelInterp=" + string(SubPelInterp) + " | BlockSize=" + string(BlockSize) + " | Overlap=" + string(Overlap) + \
  776.         "\nSearch=" + string(Search) + " | SearchParam=" + string(SearchParam) + " | PelSearch=" + string(PelSearch) + " | ChromaMotion=" + \
  777.         string(ChromaMotion) + " | TrueMotion=" + string(TrueMotion) + "\nLambda=" + string(Lambda) + " | LSAD=" + string(LSAD) + " | PNew=" + string(PNew) + \
  778.         " | PLevel=" + string(PLevel) + " | GlobalMotion=" + string(GlobalMotion) + " | DCT=" + string(DCT) + "\nThSAD1=" + string(ThSAD1) + " | ThSAD2=" + \
  779.         string(ThSAD2) + " | ThSCD1=" + string(ThSCD1) + " | ThSCD2=" + string(ThSCD2) + "\nSourceMatch=" + string(SourceMatch) + " | MatchPreset='" + \
  780.         MatchPreset + "' | MatchEdi='" + MatchEdi + "'\nMatchPreset2='" + MatchPreset2 + "' | MatchEdi2='" + MatchEdi2 + "' | MatchTR2=" + string(MatchTR2) + \
  781.         " | MatchEnhance=" + string(MatchEnhance, "%.2f") + " | Lossless=" + string(Lossless) + "\nNoiseProcess=" + string(NoiseProcess) + " | Denoiser='" + \
  782.         Denoiser + "' | FftThreads=" + string(FftThreads) + " | DenoiseMC=" + string(DenoiseMC) + " | NoiseTR=" + string(NoiseTR) + " | Sigma=" + \
  783.         string(Sigma, "%.2f") + "\nChromaNoise=" + string(ChromaNoise) + " | ShowNoise=" + string(ShowNoise, "%.2f") + " | GrainRestore=" + \
  784.         string(GrainRestore, "%.2f") + " | NoiseRestore=" + string(NoiseRestore, "%.2f") + "\nNoiseDeint='" + NoiseDeint + "' | StabilizeNoise=" + \
  785.         string(StabilizeNoise) + " | InputType=" + string(InputType) + " | ProgSADMask=" + string(ProgSADMask, "%.2f") + "\nFPSDivisor=" + \
  786.         string(FPSDivisor) + " | ShutterBlur=" + string(ShutterBlur) + " | ShutterAngleSrc=" + string(ShutterAngleSrc, "%.2f") + " | ShutterAngleOut=" + \
  787.         string(ShutterAngleOut, "%.2f") + " | SBlurLimit=" + string(SBlurLimit) + "\nBorder=" + string(Border) + " | Precise=" + string(Precise) + \
  788.         "\nPreset='" + Preset + "' | Tuning='" + Tuning + "' | GlobalNames='" + GlobalNames + "' | PrevGlobals='" + PrevGlobals + "' | ForceTR=" + \
  789.         string(ForceTR), font="Lucida Console", size=11, lsp=12 )
  790. }
  791.  
  792.  
  793. #---------------------------------------
  794. # Helpers
  795.  
  796. # Same as Bob, but keeps the field order the same.
  797. function QTGMC_Bob(clip cp, float "b", float "c", int "height" )
  798. {
  799.   ssispmt = Findstr(VersionString(), "AviSynth+") != 0 && Findstr(VersionString(), "r1576") == 0
  800.   h = Default(height, cp.Height)
  801.   w = cp.Width
  802.   shift = GetParity(cp) ? 0.25 : -0.25
  803.  
  804.   c420 = ssispmt ? Is420(cp) : IsYV12(cp)
  805.  
  806.   c420 ? cp.SeparateFields() : nop()
  807.  
  808.   oeven=c420 ? SelectEven() : nop()
  809.   oodd=c420 ? SelectOdd() : nop()
  810.  
  811.   even=c420 ? ssispmt ? oeven.ConvertToY().BicubicResize(w, h, b, c, 0, shift, w, Height()).AssumeFrameBased() : oeven.ConvertToY8().BicubicResize(w, h, b, c, 0, shift, w, Height()).AssumeFrameBased() : nop()
  812.   odd=c420 ? ssispmt ? oodd.ConvertToY().BicubicResize(w, h, b, c, 0, -shift, w, Height()).AssumeFrameBased() : oodd.ConvertToY8().BicubicResize(w, h, b, c, 0, -shift, w, Height()).AssumeFrameBased() : nop()
  813.  
  814.   evenChr=c420 ? Interleave(ssispmt ? oeven.ExtractU() : oeven.UToY8(), ssispmt ? oeven.ExtractV() : oeven.VToY8()).BicubicResize(w/2, h/2, b, c, 0, shift, w/2, Height()/2).AssumeFrameBased() : nop()
  815.   oddChr=c420 ? Interleave(ssispmt ? oodd.ExtractU() : oodd.UToY8(), ssispmt ? oodd.ExtractV() :oodd.VToY8()).BicubicResize(w/2, h/2, b, c, 0, -shift, w/2, Height()/2).AssumeFrameBased() : nop()
  816.  
  817.   c420 ? YToUV(Interleave(evenChr.SelectEven(), oddChr.SelectEven()),Interleave(evenChr.SelectOdd(), oddChr.SelectOdd()),Interleave(even, odd)) : cp.Bob( b,c, h )
  818.   GetParity(cp) ? AssumeTFF() : AssumeBFF()
  819. }
  820.  
  821.  
  822. # Interpolate input clip using method given in EdiMode. Use Fallback or Bob as result if mode not in list. If ChromaEdi string if set then interpolate chroma
  823. # separately with that method (only really useful for EEDIx). The function is used as main algorithm starting point and for first two source-match stages
  824. function QTGMC_Interpolate( clip Input, int InputType, string EdiMode, int NNSize, int NNeurons, int EdiQual, int EdiMaxD, int EdiThreads, clip "Fallback", \
  825.                             string "ChromaEdi" )
  826. {
  827.     # >>>> YUY2 is interleaved here
  828.  
  829.     ChromaEdi = default( ChromaEdi, "" )
  830.     CEed = (ChromaEdi == "")
  831.  
  832.     interp = (InputType == 1)            ? Input : \
  833.              (EdiMode == "NNEDI3")       ? Input.NNEDI3( field=-2, nsize=NNSize, nns=NNeurons, qual=EdiQual, threads=EdiThreads, U=CEed,V=CEed ) : \
  834.              (EdiMode == "NNEDI2")       ? Input.NNEDI2( field=-2, nsize=NNeurons, qual=EdiQual, threads=EdiThreads, U=CEed,V=CEed ) : \
  835.              (EdiMode == "NNEDI")        ? Input.NNEDI( field=-2, U=CEed,V=CEed ) : \
  836.              (EdiMode == "EEDI3+NNEDI3") ? Input.EEDI3( field=-2, mdis=EdiMaxD, threads=EdiThreads, U=CEed,V=CEed, \
  837.                                                         sclip=Input.NNEDI3( field=-2, nsize=NNSize, nns=NNeurons, qual=EdiQual, threads=EdiThreads, U=CEed,V=CEed ) ) : \
  838.              (EdiMode == "EEDI3")        ? Input.EEDI3( field=-2, mdis=EdiMaxD, threads=EdiThreads, U=CEed,V=CEed ) : \
  839.              (EdiMode == "EEDI2")        ? Input.SeparateFields().EEDI2( field=-2, maxd=EdiMaxD ) : \
  840.              (EdiMode == "Yadif")        ? isyuy2(Input) ? Input.ConvertToYv16().Yadifmod2( mode=3 ).ConvertToYUY2() : Input.Yadifmod2( mode=3 ) : \
  841.              (EdiMode == "cYadif")       ? Input.Yadif( mode=3 ) : \
  842.              (EdiMode == "TDeint")       ? Input.TDeInt( mode=1 ) : \
  843.              (EdiMode == "RepYadif")     ? isyuy2(Input) ? Repair( Input.ConvertToYv16().Yadifmod2( mode=3 ), default( Fallback, Input.QTGMC_Bob( 0,0.5 ) ).ConvertToYv16(), 2, 0 ).ConvertToYUY2() : \
  844.                                                            Input.Yadifmod2( mode=3 ) : \   
  845.              (EdiMode == "RepcYadif")    ? isyuy2(Input) ? Repair( Input.Yadif( mode=3 ).ConvertToYv16(), default( Fallback, Input.QTGMC_Bob( 0,0.5 ) ).ConvertToYv16(), 2, 0 ).ConvertToYUY2() : \
  846.                                                    Repair( Input.Yadif( mode=3 ), default( Fallback, Input.QTGMC_Bob( 0,0.5 ) ), 2, 0 ) : \
  847.                                            default( Fallback, Input.QTGMC_Bob( 0,0.5 ) )
  848.  
  849.     interpuv = (InputType == 1)        ? NOP() : \
  850.                (ChromaEdi == "NNEDI3") ? Input.NNEDI3( field=-2, nsize=4, nns=0, qual=1, threads=EdiThreads, Y=false ) : \
  851.                (ChromaEdi == "Yadif")  ? isyuy2(Input) ? Input.ConvertToYv16().Yadifmod2( mode=3 ).ConvertToYUY2() : Input.Yadifmod2( mode=3 ) : \
  852.                (ChromaEdi == "cYadif") ? Input.Yadif( mode=3 ) : \
  853.                (ChromaEdi == "Bob")    ? Input.QTGMC_Bob( 0,0.5 ) : \
  854.                                          NOP()
  855.  
  856.     return (!IsClip(interpuv)) ? interp : interp.MergeChroma( interpuv )
  857. }
  858.  
  859.  
  860. # Functions (from original TGMC) used instead of mt_xxflate with similar operation but a somewhat stronger result. Originally added for speed, they are
  861. # no longer faster due to improvements in masktools. Difference (visual and speed) is small so may be reverted in a later version.
  862. function QTGMC_inflate( clip c, int "Y", int "U", int "V" )
  863. {
  864.     # >>>> YUY2 is planar here
  865.     mtY =default( Y, 3 )
  866.     mtU =default( U, 1 )
  867.     mtV =default( V, 1 )
  868.     rgY = (mtY == 3) ? 20 : -1
  869.     rgU = (mtU == 3) ? 20 : -1
  870.     rgV = (mtV == 3) ? 20 : -1
  871.     mt_logic( c, c.RemoveGrain( rgY, rgU, rgV ), "max", Y=mtY,U=mtU,V=mtV )
  872. }
  873.  
  874. function QTGMC_deflate( clip c, int "Y", int "U", int "V" )
  875. {
  876.     # >>>> YUY2 is planar here
  877.     mtY =default( Y, 3 )
  878.     mtU =default( U, 1 )
  879.     mtV =default( V, 1 )
  880.     rgY = (mtY == 3) ? 20 : -1
  881.     rgU = (mtU == 3) ? 20 : -1
  882.     rgV = (mtV == 3) ? 20 : -1
  883.     mt_logic( c, c.RemoveGrain( rgY, rgU, rgV ), "min", Y=mtY,U=mtU,V=mtV )
  884. }
  885.  
  886. # Helper function: Compare processed clip with reference clip: only allow thin, horizontal areas of difference, i.e. bob shimmer fixes
  887. # Rough algorithm: Get difference, deflate vertically by a couple of pixels or so, then inflate again. Thin regions will be removed
  888. #                  by this process. Restore remaining areas of difference back to as they were in reference clip.
  889. function QTGMC_KeepOnlyBobShimmerFixes( clip Input, clip Ref, int Rep, bool Chroma )
  890. {
  891.     # >>>> YUY2 is planar here
  892.  
  893.     # ed is the erosion distance - how much to deflate then reflate to remove thin areas of interest: 0 = minimum to 6 = maximum
  894.     # od is over-dilation level  - extra inflation to ensure areas to restore back are fully caught:  0 = none to 3 = one full pixel
  895.     # If Rep < 10, then ed = Rep and od = 0, otherwise ed = 10s digit and od = 1s digit (nasty method, but kept for compatibility with original TGMC)
  896.     Rep    = default( Rep,    1    )
  897.     Chroma = default( Chroma, true )
  898.     ed = (Rep < 10) ? Rep : Rep / 10
  899.     od = (Rep < 10) ? 0   : Rep % 10
  900.     RCrg  = Chroma ? 3 : 1
  901.     RCrgo = Chroma ? 3 : 2
  902.  
  903.     diff = mt_makediff(Ref, Input, U=3,V=3 )
  904.  
  905.     # Areas of positive difference                                                                # ed = 0 1 2 3 4 5 6 7
  906.     choke1 =                        diff.  mt_inpand( mode="vertical", U=RCrg,V=RCrg )            #      x x x x x x x x    1 pixel   \
  907.     choke1 = (ed > 2)             ? choke1.mt_inpand( mode="vertical", U=RCrg,V=RCrg ) : choke1   #      . . . x x x x x    1 pixel    |  Deflate to remove thin areas
  908.     choke1 = (ed > 5)             ? choke1.mt_inpand( mode="vertical", U=RCrg,V=RCrg ) : choke1   #      . . . . . . x x    1 pixel   /
  909.     choke1 = (ed % 3 != 0)        ? choke1.QTGMC_deflate( U=RCrg,V=RCrg )              : choke1   #      . x x . x x . x    A bit more deflate & some horizonal effect
  910.     choke1 = (ed == 2 || ed == 5) ? choke1.RemoveGrain( 4              )               : choke1   #      . . x . . x . .    Local median
  911.                                                                                                                      
  912.     choke1 =                        choke1.mt_expand( mode="vertical", U=RCrg,V=RCrg )            #      x x x x x x x x    1 pixel  \
  913.     choke1 = (ed > 1)             ? choke1.mt_expand( mode="vertical", U=RCrg,V=RCrg ) : choke1   #      . . x x x x x x    1 pixel   | Reflate again
  914.     choke1 = (ed > 4)             ? choke1.mt_expand( mode="vertical", U=RCrg,V=RCrg ) : choke1   #      . . . . . x x x    1 pixel  /
  915.  
  916.     # Over-dilation - extra reflation up to about 1 pixel
  917.     choke1 = (od == 0)            ? choke1 : \
  918.              (od == 1)            ? choke1.QTGMC_inflate( U=RCrg,V=RCrg ) : \
  919.              (od == 2)            ? choke1.QTGMC_inflate( U=RCrg,V=RCrg ).QTGMC_inflate( U=RCrg,V=RCrg ) : \
  920.                                     choke1.mt_expand ( U=RCrg,V=RCrg )
  921.  
  922.     # Areas of negative difference (similar to above)
  923.     choke2 =                        diff.  mt_expand( mode="vertical", U=RCrg,V=RCrg )        
  924.     choke2 = (ed > 2)             ? choke2.mt_expand( mode="vertical", U=RCrg,V=RCrg ) : choke2
  925.     choke2 = (ed > 5)             ? choke2.mt_expand( mode="vertical", U=RCrg,V=RCrg ) : choke2
  926.     choke2 = (ed % 3 != 0)        ? choke2.QTGMC_inflate( U=RCrg,V=RCrg )              : choke2
  927.     choke2 = (ed == 2 || ed == 5) ? choke2.RemoveGrain( 4              )               : choke2
  928.     choke2 =                        choke2.mt_inpand( mode="vertical", U=RCrg,V=RCrg )
  929.     choke2 = (ed > 1)             ? choke2.mt_inpand( mode="vertical", U=RCrg,V=RCrg ) : choke2
  930.     choke2 = (ed > 4)             ? choke2.mt_inpand( mode="vertical", U=RCrg,V=RCrg ) : choke2
  931.     choke2 = (od == 0)            ? choke2 : \
  932.              (od == 1)            ? choke2.QTGMC_deflate( U=RCrg,V=RCrg )  : \
  933.              (od == 2)            ? choke2.QTGMC_deflate( U=RCrg,V=RCrg ).QTGMC_deflate( U=RCrg,V=RCrg ) : \
  934.                                     choke2.mt_inpand ( U=RCrg,V=RCrg )
  935.  
  936.     # Combine above areas to find those areas of difference to restore
  937.     restore = diff.mt_lutxy( choke1, "x 129 < x y 128 < 128 y ? ?", U=RCrg,V=RCrg ).mt_lutxy( choke2, "x 127 > x y 128 > 128 y ? ?", U=RCrg,V=RCrg )
  938.  
  939.     return Input.mt_adddiff( restore, U=RCrgo,V=RCrgo )
  940. }
  941.  
  942.  
  943. # Given noise extracted from an interlaced source (i.e. the noise is interlaced), generate "progressive" noise with a new "field" of noise injected. The new
  944. # noise is centered on a weighted local average and uses the difference between local min & max as an estimate of local variance
  945. # YUY2 clip input is planar, but must pass interleaved version of clip to setup noise
  946. function QTGMC_Generate2ndFieldNoise( clip Input, clip InterleavedClip, bool "ChromaNoise" )
  947. {
  948.     # >>>> YUY2 is planar here. Noise is generated (AddGrainC) interleaved, but immediately made planar
  949.     ChromaNoise = default( ChromaNoise, false )
  950.     CNmt1 = ChromaNoise ? 3 : 1
  951.     origNoise = Input.SeparateFields()
  952.     noiseMax  = origNoise.mt_expand( mode="square", U=CNmt1,V=CNmt1 ).mt_expand( mode="horizontal", U=CNmt1,V=CNmt1 )
  953.     noiseMin  = origNoise.mt_inpand( mode="square", U=CNmt1,V=CNmt1 ).mt_inpand( mode="horizontal", U=CNmt1,V=CNmt1 )
  954.     random    = BlankClip( InterleavedClip.SeparateFields(), color_yuv=$808080 ).AddGrainC( var=1800, uvar=ChromaNoise ? 1800 : 0 )
  955.     random    = InterleavedClip.IsYUY2() ? random.converttoyv16() : random
  956.     varRandom = mt_makediff( noiseMax, noiseMin, U=CNmt1,V=CNmt1 ).mt_lutxy( random, "x 128 - y * 256 / 128 +", U=CNmt1,V=CNmt1)
  957.     newNoise  = noiseMin.mt_adddiff( varRandom, U=CNmt1,V=CNmt1 )
  958.     return Interleave( origNoise, newNoise ).Weave()
  959. }
  960.  
  961.  
  962. # Insert the source lines into the result to create a true lossless output. However, the other lines in the result have had considerable processing and won't
  963. # exactly match source lines. There will be some slight residual combing. Use vertical medians to clean a little of this away
  964. function QTGMC_MakeLossless( clip Input, clip Source, int InputType )
  965. {
  966.     Assert( InputType != 1, "Lossless modes are incompatible with InputType=1" )
  967.  
  968.     # >>>> YUY2: 'Input' is planar, 'Source' is interleaved (changed to planar here for processing) - returns planar result
  969.  
  970.     # Weave the source fields and the "new" fields that have generated in the input
  971.     srcFields1 = (InputType == 0) ? Source.SeparateFields() : Source.SeparateFields().SelectEvery( 4, 0,3 )
  972.     srcFields  = Source.IsYUY2() ? srcFields1.converttoyv16() : srcFields1
  973.     newFields  = Input.SeparateFields().SelectEvery( 4, 1,2 )
  974.     processed  = Interleave( srcFields, newFields ).SelectEvery(4, 0,1,3,2 ).Weave()
  975.  
  976.     # Clean some of the artefacts caused by the above - creating a second version of the "new" fields
  977.     vertMedian  = processed.VerticalCleaner( mode=1 )
  978.     vertMedDiff = mt_makediff( processed, vertMedian, U=3,V=3 )
  979.     vmNewDiff1  = vertMedDiff.SeparateFields().SelectEvery( 4, 1,2 )
  980.     vmNewDiff2  = vmNewDiff1.VerticalCleaner( mode=1 ).mt_lutxy( vmNewDiff1, "x 128 - y 128 - * 0 < 128 x 128 - abs y 128 - abs < x y ? ?", U=3,V=3 )
  981.     vmNewDiff3  = vmNewDiff2.Repair( vmNewDiff2.RemoveGrain( 2 ), 1 )
  982.  
  983.     # Reweave final result
  984.     return Interleave( srcFields, newFields.mt_makediff( vmNewDiff3, U=3,V=3 )).SelectEvery( 4, 0,1,3,2 ).Weave()
  985. }
  986.  
  987.  
  988. # Source-match, a three stage process that takes the difference between deinterlaced input and the original interlaced source, to shift the input more towards
  989. # the source without introducing shimmer. All other arguments defined in main script
  990. function QTGMC_ApplySourceMatch( clip Deinterlace, int InputType, val Source, val bVec1, val fVec1, val bVec2, val fVec2, \
  991.                                  int SubPel, int SubPelInterp, int hpad, int vpad, int ThSAD1, int ThSCD1, int ThSCD2, int SourceMatch, \
  992.                                  int MatchTR1, string MatchEdi, int MatchNNSize, int MatchNNeurons, int MatchEdiQual, int MatchEdiMaxD,\
  993.                                  int MatchTR2, string MatchEdi2, int MatchNNSize2, int MatchNNeurons2, int MatchEdiQual2, int MatchEdiMaxD2, \
  994.                                  float MatchEnhance, int EdiThreads, bool lsb )
  995. {
  996.     # >>>> YUY2: 'Deinterlace' is planar, 'Source' is interleaved (changed to planar here for all processing except interpolation) - returns planar result
  997.     yuy2 = Source.IsYUY2()
  998.     Source = yuy2 ? Source.converttoyv16() : Source
  999.  
  1000.     # Basic source-match. Find difference between source clip & equivalent fields in interpolated/smoothed clip (called the "error" in formula below). Ideally
  1001.     # there should be no difference, we want the fields in the output to be as close as possible to the source whilst remaining shimmer-free. So adjust the
  1002.     # *source* in such a way that smoothing it will give a result closer to the unadjusted source. Then rerun the interpolation (edi) and binomial smooth with
  1003.     # this new source. Result will still be shimmer-free and closer to the original source.
  1004.     # Formula used for correction is P0' = P0 + (P0-P1)/(k+S(1-k)), where P0 is original image, P1 is the 1st attempt at interpolation/smoothing , P0' is the
  1005.     # revised image to use as new source for interpolation/smoothing, k is the weighting given to the current frame in the smooth, and S is a factor indicating
  1006.     # "temporal similarity" of the error from frame to frame, i.e. S = average over all pixels of [neighbor frame error / current frame error] . Decreasing
  1007.     # S will make the result sharper, sensible range is about -0.25 to 1.0. Empirically, S=0.5 is effective [will do deeper analysis later]
  1008.     errorTemporalSimilarity = 0.5  # S in formula described above
  1009.     errorAdjust1   = Select( MatchTR1, 1.0, 2.0 / (1.0 + errorTemporalSimilarity), 8.0 / (3.0 + 5.0 * errorTemporalSimilarity) )
  1010.     match1Clip     = (SourceMatch < 1 || InputType == 1) ? Deinterlace : Deinterlace.SeparateFields().SelectEvery( 4, 0,3 ).Weave()
  1011.     match1Update   = (SourceMatch < 1 || MatchTR1 == 0) \
  1012.                         ? Source : mt_lutxy( Source, match1Clip, "x " + string(errorAdjust1 + 1) + " * y " + string(errorAdjust1) + " * -", U=3,V=3 )
  1013.     noyv16ma1Edi   = MatchEdi =="NNEDI2" || MatchEdi =="NNEDI" || MatchEdi =="EEDI3+NNEDI3" || MatchEdi =="EEDI3" || MatchEdi =="EEDI2" || MatchEdi =="TDeint" || MatchEdi =="cYadif" || MatchEdi =="RepcYadif"
  1014.     noyv16ma2Edi   = MatchEdi2=="NNEDI2" || MatchEdi2=="NNEDI" || MatchEdi2=="EEDI3+NNEDI3" || MatchEdi2=="EEDI3" || MatchEdi2=="EEDI2" || MatchEdi2=="TDeint" || MatchEdi2=="cYadif" || MatchEdi2=="RepcYadif"
  1015.     match1Edi      = (SourceMatch == 0) ? NOP() : \
  1016.     !noyv16ma1Edi || !yuy2 ? match1Update.QTGMC_Interpolate( InputType, MatchEdi, MatchNNSize, MatchNNeurons, MatchEdiQual, MatchEdiMaxD, EdiThreads ) : \
  1017.                              match1Update.ConvertToYUY2() \
  1018.                                          .QTGMC_Interpolate( InputType, MatchEdi, MatchNNSize, MatchNNeurons, MatchEdiQual, MatchEdiMaxD, EdiThreads ) \
  1019.                                          .ConvertToYv16()
  1020.     match1Super    = (SourceMatch > 0 && MatchTR1 > 0) ? match1Edi.MSuper( pel=SubPel, sharp=SubPelInterp, levels=1, hpad=hpad, vpad=vpad ) : NOP()
  1021.     match1Degrain1 = (SourceMatch > 0 && MatchTR1 > 0) ? match1Edi.MDegrain1( match1Super, bVec1,fVec1, thSAD=ThSAD1, thSCD1=ThSCD1,thSCD2=ThSCD2, lsb=lsb ) : NOP()
  1022.     match1Degrain2 = (SourceMatch > 0 && MatchTR1 > 1) ? match1Edi.MDegrain1( match1Super, bVec2,fVec2, thSAD=ThSAD1, thSCD1=ThSCD1,thSCD2=ThSCD2, lsb=lsb ) : NOP()
  1023.     match1Degrain1 = (SourceMatch > 0 && MatchTR1 > 0) && lsb ? match1Degrain1.ditherpost(mode=6, slice=false) : match1Degrain1
  1024.     match1Degrain2 = (SourceMatch > 0 && MatchTR1 > 1) && lsb ? match1Degrain2.ditherpost(mode=6, slice=false) : match1Degrain2
  1025.     match1         = (SourceMatch < 1) ? Deinterlace : \
  1026.                      (MatchTR1 == 0)   ? match1Edi : \
  1027.                      (MatchTR1 == 1)   ? match1Degrain1.Merge( match1Edi, 0.25 ) : \
  1028.                                          match1Degrain1.Merge( match1Degrain2, 0.2 ).Merge( match1Edi, 0.0625 )
  1029.  
  1030.     # Enhance effect of source-match stages 2 & 3 by sharpening clip prior to refinement (source-match tends to underestimate so this will leave result sharper)
  1031.     match1Shp = (SourceMatch > 1 && MatchEnhance > 0.0) ? match1.mt_lutxy( match1.RemoveGrain( 12 ), "x x y - "+ string(MatchEnhance) + " * +", U=3,V=3 ) : match1
  1032.  
  1033.     # Source-match refinement. Find difference between source clip & equivalent fields in (updated) interpolated/smoothed clip. Interpolate & binomially smooth
  1034.     # this difference then add it back to output. Helps restore differences that the basic match missed. However, as this pass works on a difference rather than
  1035.     # the source image it can be prone to occasional artefacts (difference images are not ideal for interpolation). In fact a lower quality interpolation such
  1036.     # as a simple bob often performs nearly as well as advanced, slower methods (e.g. NNEDI3)
  1037.     match2Clip     = (SourceMatch < 2 || InputType == 1) ? match1Shp : match1Shp.SeparateFields().SelectEvery( 4, 0,3 ).Weave()
  1038.     match2Diff     = (SourceMatch > 1) ? mt_makediff( Source, match2Clip, U=3,V=3 ) : NOP()
  1039.     match2Edi      = (SourceMatch <= 1) ? NOP() : \
  1040.     !noyv16ma2Edi || !yuy2 ? match2Diff.QTGMC_Interpolate( InputType, MatchEdi2, MatchNNSize2, MatchNNeurons2, MatchEdiQual2, MatchEdiMaxD2, EdiThreads ) : \
  1041.                              match2Diff.ConvertToYUY2() \
  1042.                                        .QTGMC_Interpolate( InputType, MatchEdi2, MatchNNSize2, MatchNNeurons2, MatchEdiQual2, MatchEdiMaxD2, EdiThreads ) \
  1043.                                        .ConvertToYv16()
  1044.     match2Super    = (SourceMatch > 1 && MatchTR2 > 0) ? match2Edi.MSuper( pel=SubPel, sharp=SubPelInterp, levels=1, hpad=hpad, vpad=vpad ) : NOP()
  1045.     match2Degrain1 = (SourceMatch > 1 && MatchTR2 > 0) ? match2Edi.MDegrain1( match2Super, bVec1,fVec1, thSAD=ThSAD1, thSCD1=ThSCD1,thSCD2=ThSCD2, lsb=lsb ) : NOP()
  1046.     match2Degrain2 = (SourceMatch > 1 && MatchTR2 > 1) ? match2Edi.MDegrain1( match2Super, bVec2,fVec2, thSAD=ThSAD1, thSCD1=ThSCD1,thSCD2=ThSCD2, lsb=lsb ) : NOP()
  1047.     match2Degrain1 = (SourceMatch > 1 && MatchTR2 > 0) && lsb ? match2Degrain1.ditherpost(mode=6, slice=false) : match2Degrain1
  1048.     match2Degrain2 = (SourceMatch > 1 && MatchTR2 > 1) && lsb ? match2Degrain2.ditherpost(mode=6, slice=false) : match2Degrain2
  1049.     match2         = (SourceMatch < 2) ? match1 : \
  1050.                      (MatchTR2 == 0)   ? match2Edi : \
  1051.                      (MatchTR2 == 1)   ? match2Degrain1.Merge( match2Edi, 0.25 ) : \
  1052.                                          match2Degrain1.Merge( match2Degrain2, 0.2 ).Merge( match2Edi, 0.0625 )
  1053.  
  1054.     # Source-match second refinement - correct error introduced in the refined difference by temporal smoothing. Similar to error correction from basic step
  1055.     errorAdjust2   = Select( MatchTR2, 1.0, 2.0 / (1.0 + errorTemporalSimilarity), 8.0 / (3.0 + 5.0 * errorTemporalSimilarity) )
  1056.     match3Update   = (SourceMatch < 3 || MatchTR2 == 0) \
  1057.                          ? match2Edi : mt_lutxy( match2Edi, match2, "x " + string(errorAdjust2 + 1) + " * y " + string(errorAdjust2) + " * -", U=3,V=3 )
  1058.     match3Super    = (SourceMatch > 2 && MatchTR2 > 0) ? match3Update.MSuper( pel=SubPel, sharp=SubPelInterp, levels=1, hpad=hpad, vpad=vpad ) : NOP()
  1059.     match3Degrain1 = (SourceMatch > 2 && MatchTR2 > 0) ? match3Update.MDegrain1( match3Super, bVec1,fVec1, thSAD=ThSAD1, thSCD1=ThSCD1,thSCD2=ThSCD2, lsb=lsb ) : NOP()
  1060.     match3Degrain2 = (SourceMatch > 2 && MatchTR2 > 1) ? match3Update.MDegrain1( match3Super, bVec2,fVec2, thSAD=ThSAD1, thSCD1=ThSCD1,thSCD2=ThSCD2, lsb=lsb ) : NOP()
  1061.     match3Degrain1 = (SourceMatch > 2 && MatchTR2 > 0) && lsb ? match3Degrain1.ditherpost(mode=6, slice=false) : match3Degrain1
  1062.     match3Degrain2 = (SourceMatch > 2 && MatchTR2 > 1) && lsb ? match3Degrain2.ditherpost(mode=6, slice=false) : match3Degrain2
  1063.     match3         = (SourceMatch < 3) ? match2 : \
  1064.                      (MatchTR2 == 0)   ? match3Update : \
  1065.                      (MatchTR2 == 1)   ? match3Degrain1.Merge( match3Update, 0.25 ) : \
  1066.                                          match3Degrain1.Merge( match3Degrain2, 0.2 ).Merge( match3Update, 0.0625 )
  1067.  
  1068.     # Apply difference calculated in source-match refinement
  1069.     return (SourceMatch < 2) ? match1 : match1Shp.mt_adddiff( match3, U=3,V=3 )
  1070. }
  1071.  
  1072.  
  1073. # Set global variable called "Prefix_Name" to "Value". Throws exception if global already exists unless Replace=true, in which case the global is overwritten
  1074. function QTGMC_SetUserGlobal( string Prefix, string Name, val Value, bool "Replace" )
  1075. {
  1076.     Replace = default( Replace, false )
  1077.     globalName = Prefix + "_" + Name
  1078.  
  1079.     # Tricky logic to check global: enter catch block if Replace=true *or* globalName doesn't exist (i.e. need to set the global), the exception is not rethrown
  1080.     # Not entering catch block means that Replace=false and global exists - so it throws an exception back to AviSynth
  1081.     try { Assert( !Replace && defined(Eval(globalName)) ) }
  1082.     catch (e)
  1083.     {
  1084.         Eval( "global " + globalName + " = Value" )
  1085.         Replace = true
  1086.     }
  1087.     Assert( Replace, """Multiple calls to QTGMC, set PrevGlobals="Replace" or read documentation on 'Multiple QTGMC Calls'""" )
  1088. }
  1089.  
  1090. # Return value of global variable called "Prefix_Name". Returns NOP() if it doesn't exist or Reuse is false
  1091. function QTGMC_GetUserGlobal( string Prefix, string Name, bool "Reuse" )
  1092. {
  1093.     Reuse = default( Reuse, false )
  1094.     globalName = Prefix + "_" + Name
  1095.  
  1096.     try       { ret = Reuse ? Eval( globalName ) : NOP() }
  1097.     catch (e) { ret = NOP() }
  1098.     return ret
  1099. }
Advertisement
Add Comment
Please, Sign In to add comment
Advertisement
Public Pastes
Advertisement
We use cookies for various purposes including analytics. By continuing to use Pastebin, you agree to our use of cookies as described in the Cookies Policy.  OK, I Understand
Not a member of Pastebin yet?
Sign Up, it unlocks many cool features!