google-cloud-sdk PKGBUILD

pkgname='google-cloud-sdk'
pkgver=0.9.26
pkgrel=1
pkgdesc='Tools and libraries to easily create and manage resources on Google Cloud Platform'
arch=('i686' 'x86_64')
url='https://developers.google.com/cloud/sdk/'
depends=('python2')
makedepends=('python2')
optdepends=('go: for Go version of App Engine'
            'java-environment: for Java version of App Engine'
            'php: for PHP version of App Engine')
license=('APACHE')
source=("$pkgname-$pkgver.tar.gz::https://dl.google.com/dl/cloudsdk/release/google-cloud-sdk.tar.gz"
        "profile.sh")
md5sums=('328e974b4fe584f91c04557a0e1d86ea'
         'd7c7ccb7d32a871d67288228f5b4cd94')
noextract=("$pkgname-$pkgver.tar.gz")
options=('!strip' 'staticlibs')

build() {
  true
}

package() {
  mkdir "$pkgdir/opt"
  cd "$pkgdir/opt"
  tar -xzf "$srcdir"/$pkgname-$pkgver.tar.gz
  cd google-cloud-sdk
  python2 -S "$pkgdir"/opt/google-cloud-sdk/bin/bootstrapping/install.py \
    --usage-reporting false --disable-installation-options \
    --path-update false --bash-completion false --rc-path "$srcdir"/fake.bashrc \
    --additional-components pkg-go pkg-python pkg-java
  sed -i -e "s|#![ ]*/usr/bin/env python$|#!/usr/bin/env python2|" $(find "${pkgdir}" -name '*.py')
  install -Dm755 completion.bash.inc "$pkgdir"/etc/bash_completion.d/google-cloud-sdk
  install -Dm755 "$srcdir"/profile.sh "$pkgdir"/etc/profile.d/google-cloud-sdk
}