game.com

$!********************************************
$!*   Keszito neve: Kovacs Marton            *
$!*   Email: tetra@elte.hu                   *
$!*   Elkeszites datuma: 20061201            *
$!*   Feladat sorszama: 4.                   *
$!*   A szkript szabadon terjesztheto,       *
$!*   felhasznalhato es modosmthato,         *
$!*   az eredeti forras es keszito           *
$!*   feltuntetesevel.(GNU???)               *
$!*   Verzio: 0.7                            *
$!*   Fejlesztesekert kerdezd: tetra@elte.hu *
$!********************************************
$
$
$ !inicializalas
$ !parameterek...
$
$ LF[0,8]=10
$ CR[0,8]=13
$ TAB[0,8]=9
$
$ set terminal /insert
$ set terminal /width=80
$
$ if f$ed(P1,"trim,compress,upcase") .eqs. "MAIL"
$ then
$
$    MAIL /subject="VMS BEADANDO 4" 'f$env("procedure")' maulis
$
$ QUESTION_ON_MAIL:
$    read /prompt="Kuldtem levelet. Szeretnel jatszani?(igen/nem) " sys$command temp
$
$    hossz=f$len(temp)
$    if hossz .eq. 0 then goto QUESTION_ON_MAIL
$
$    temp=f$ed(temp,"lowercase")
$
$    if temp .eqs. f$ex(0,hossz,"nem") then exit
$
$    if .not. temp .eqs. f$ex(0,hossz,"igen") then goto QUESTION_ON_MAIL
$
$    p1=p2
$    p2=p3
$    p3=p4
$    p4=p5
$
$ endif
$
$ teszt_e:
$
$ read /prompt="Jatekosok szama(2/4): " sys$command playernum
$
$ if playernum .eqs. "2" .or. playernum .eqs. "4" then goto teszt_v
$
$    say "Nem megfelelo ertek! 2 vagy 4 jatekos lehet!"
$
$    goto teszt_e
$
$ teszt_v:
$
$ dir1="1-2,2-2,2-1,3-1,3-2,3-3,2-3,1-3"
$ dir2="20-29,19-29,19-30,18-30,18-29,18-28,19-28,20-28"
$
$ FelArm=0
$ FelDef=4
$ FelDmg=1
$ FelAtt=2
$ FelHP=2
$ FelMov=4
$ InfArm=2
$ InfDef=7
$ InfDmg=3
$ InfAtt=3
$ InfHP=3
$ InfMov=2
$ ArmArm=3
$ ArmDef=9
$ ArmDmg=4
$ ArmAtt=4
$ ArmHP=5
$ ArmMov=1
$
$ enabled=0
$ aktplayer=1
$
$ if p1 .eqs. ""
$ then
$    jatekos1="1"
$ else
$    jatekos1=f$ex(0,5,p1)
$ endif
$
$ if p2 .eqs. ""
$ then
$    jatekos2="2"
$ else
$    jatekos2=f$ex(0,5,p2)
$ endif
$
$ if p3 .eqs. ""
$ then
$    jatekos3="3"
$ else
$    jatekos3=f$ex(0,5,p3)
$ endif
$
$ if p4 .eqs. ""
$ then
$    jatekos4="4"
$ else
$    jatekos4=f$ex(0,5,p4)
$ endif
$
$ details1=LF + CR
$ details2=LF + CR
$ details3=LF + CR
$
$ baseHP1=20
$ baseHP2=20
$ income0=0
$ income1=2
$ income2=2
$ money1=5
$ money2=3
$ farmlist="|2-9.1.0|2-22.2.0|6-6.1.0|6-25.2.0|7-1.1.0|7-30.2.0|8-13.2.0|8-18.2.0|13-13.2.0|13-18.2.0|14-1.2.0|14-30.1.0|15-6.2.0|15-25.1.0|19-9.2.0|19-22.1.0|1-30.3.0|20-1.3.0"
$
$  bsor1="01B1                                                          "
$  bsor2="02                                                            "
$  bsor3="03                                                            "
$  bsor4="04                                                            "
$  bsor5="05                                                            "
$  bsor6="06                                                            "
$  bsor7="07                                                            "
$  bsor8="08                                                            "
$  bsor9="09                                                            "
$ bsor10="10                                                            "
$ bsor11="11                                                            "
$ bsor12="12                                                            "
$ bsor13="13                                                            "
$ bsor14="14                                                            "
$ bsor15="15                                                            "
$ bsor16="16                                                            "
$ bsor17="17                                                            "
$ bsor18="18                                                            "
$ bsor19="19                                                            "
$ bsor20="20B2                                                          "
$
$
$
$ if playernum .eq. 4
$ then
$
$     bsor1="01B1||  ||  ||  ||  ||  ||  ||  ||  ||  ||  ||  ||  ||  ||  B3"
$    bsor20="20B4++--++--++--++--++--++--++--++--++--++--++--++--++--++--B2"
$
$    income3=2
$    income4=2
$    money3=3
$    money4=3
$    baseHP3=20
$    baseHP4=20
$
$    dir3="1-29,2-29,2-30,3-30,3-29,3-28,2-28,1-28"
$    dir4="20-2,19-2,19-1,18-1,18-2,18-3,19-3,20-3"
$
$    farmlist="|2-9.1.0|2-22.1.0|6-6.1.0|6-25.1.0|7-1.1.0|7-30.1.0|8-13.2.0|8-18.2.0|13-13.2.0|13-18.2.0|14-1.1.0|14-30.1.0|15-6.1.0|15-25.1.0|19-9.1.0|19-22.1.0"
$
$ endif
$
$ esemeny="Ha nem tudsz valamit(a jatekkal kapcsolatban), Help! Jo szorakozast!"
$
$ selected=""
$
$ gosub STATCLEAR
$
$ gosub MAPRESET
$
$ gosub UNITCLEAR
$
$ cls
$
$!++++++++++++++++++++MAIN PROC:++++++++++++++++++++
$
$ oo_ciklus:
$
$    gosub REDRAW
$
$    read /prompt="Parancs: " sys$command order
$
$    gosub translate
$
$ goto oo_ciklus
$
$
$ !Itt a main vege
$
$
$ !++++++++++++++++++++COMMAND-ERTELMEZO PROC++++++++++++++++++++
$ !lehetseges commandok: Select, Doit, Endturn, Buyunit, Getmani, Help, EXit
$
$ translate:
$
$    order=f$edit(order,"compress,trim, lowercase") + " "
$    temp=f$el(0," ",order)
$    hossz=f$length(temp)
$
$    if hossz .eq. 0 then goto endtranssub
$
$    esemeny=""
$
$    if temp .eqs. f$ex(0, hossz, "select") then goto SELECT
$    if temp .eqs. f$ex(0, hossz, "doit") then goto DOIT
$    if temp .eqs. f$ex(0, hossz, "endturn") then goto ENDTURN
$    if temp .eqs. f$ex(0, hossz, "buyunit") then goto BUYUNIT
$    if temp .eqs. f$ex(0, hossz, "getmani") then goto GETMANI
$    if temp .eqs. f$ex(0, hossz, "help") then goto HELP
$    if temp .eqs. f$ex(0, hossz, "exit") then goto EXIT
$    if temp .eqs. f$ex(0, hossz, "more") then goto MORE
$
$    esemeny="Ismeretlen parancs! Probald: Help!"
$
$ goto endtranssub
$
$
$ !+++++SELECT ELJARASA+++++
$
$       SELECT:
$
$!haszn?t v?toz?: tempcol, tempsor: megadott ?t?ek. enabled: tud-e valamit kezdeni a kiv?asztottal a cs??$
$    enabled=0
$    esemeny=""
$
$    temp=f$el(1," ",order)
$    tempsor=f$int(f$el(0,",",temp))
$    tempcol=f$int(f$el(1,",",temp))
$
$    if "INTEGER".eqs.f$ty(tempsor) .and. "INTEGER".eqs.f$ty(tempcol) .and. tempsor.ge.1 .and. tempsor.le.20 .and. tempsor.ge.1 .and. tempsor.le.30
$    then
$
$       gosub STATCLEAR
$
$       col=tempcol*2
$       selected=""
$       enabled=0
$       k=1
$               !ellen?z?iklus: szerepel-e a megadott helyen egys??
$
$       gosub WHOSTHERE
$
$       if i .ne. 0
$       then
$
$          selecteddetails=unit'i''j'
$
$          k=1
$          temp=f$el(2,"|",selecteddetails)
$
$             statusload_eleje:
$
$             if temp .eqs. "|" then goto statusload_vege
$
$                status'k'=temp
$
$                k=k+1
$
$                temp=f$element(k+1,"|",unit'i''j')
$
$             goto statusload_eleje
$
$             statusload_vege:
$
$             k=k+1
$
$             status'k'="Tulajdonos:" + f$str(jatekos'i')
$
$             selected=f$str(tempsor) + "|" + f$str(tempcol)
$
$             esemeny=selected + " egyseg kijelolve"
$
$          if aktplayer .eq. i then enabled=1
$
$       endif
$
$       !farmkijeloles, akar egyseg alatt is
$
$       gosub WHATSTHERE
$
$       if f$ex(0,1,i) .eqs. "F"
$       then
$
$          temp=f$el(f$ex(1,2,i),"|",farmlist)
$          k=k+1
$
$          status'k'="FARM"
$          k=k+1
$          status'k'="Hozama: " + f$str(f$el(1,".",temp))
$          k=k+1
$          status'k'="Tualjdonos: " + f$el(2, ".", temp)
$          esemeny=esemeny + f$str(tempsor) + ":" + f$str(tempcol) + "-s farm kijelolve"
$
$       endif
$               !Baziskijeloles:
$
$       if f$ex(0,1,i) .eqs. "B"
$       then
$
$          temp=f$ex(1,1,i)
$
$          status1="BAZIS"
$          status2="Tulajdonos: " + f$str(temp)
$          status3="Penze: " + f$str(money'temp')
$          status4="Bevetele: " + f$str(income'temp')
$          status5="Eletpont: " + f$str(BaseHP'temp')
$
$       endif
$
$    else
$
$       esemeny="Select hibas parameterezese! Probald: Help!"
$
$    endif
$
$    goto endtranssub
$
$
$
$ !+++++ DOIT +++++++++++++++++++++
$
$    DOIT:
$
$    temp=""
$
$    order=f$ed(f$el(1," ",order),"lowercase")
$
$    if enabled .eq. 0
$    then
$
$       esemeny="Nincs sajat egyseg kijelolve!"
$
$    else
$
$       tempsor=f$el(0,"|",selected)
$       tempcol=f$el(1,"|",selected)
$
$       hossz=f$len(order)
$
$       if hossz.gt.0 .and. (order.eqs.f$ex(0,hossz,"fel") .and. tempsor.gt.1 .or. order.eqs.f$ex(0,hossz,"jobbra") .and. tempcol.lt.30 .or. order.eqs.f$ex(0,hossz,"balra") .and. tempcol.gt.1 .or. order.eqs.f$ex(0,hossz,"le") .and. tempsor.lt.20)
$       then
$
$          order=f$ex(0,1,order)
$
$          destsor=tempsor-(order.eqs."f")+(order.eqs."l")
$          destcol=tempcol-(order.eqs."b")+(order.eqs."j")
$
$          gosub WHOSTHERE
$
$          ki=j
$
$          tempsor=destsor
$          tempcol=destcol
$
$          gosub WHOSTHERE
$
$          if i .eq. 0
$          then
$
$             gosub WHATSTHERE
$
$             if f$ex(0,1,i) .eqs. "B"
$             then
$
$                if f$el(9,"|",unit'aktplayer''ki') .eqs. "Tamadott-e: nem" .and. f$ex(1,1,i) .ne. aktplayer
$                then
$
$                   temp=f$str(aktplayer)+","+f$str(ki)+","+"8"+","+"Lepes:0/"+f$str(f$el(1,"/",f$el(8,"|",unit'aktplayer''ki')))
$
$                   gosub XCHG
$
$                   temp=f$str(aktplayer) + "," + f$str(ki) + ",9,Tamadott-e: igen"
$
$                   gosub XCHG
$
$                   status8="Tamadott-e: igen"
$
$                   temp=f$el(1,":",f$el(6,"|",unit'aktplayer''ki')) + "," + f$str(f$el(1,":",f$el(5,"|",unit'aktplayer''ki'))) + ",8,4"
$
$                   gosub ATTACK
$
$                   if temp .nes. "L"
$                   then
$
$                      esemeny="Az egyseg talalatot ert el a bazissal szemben,"
$
$                      if temp .le. 0
$                      then
$
$                         esemeny=esemeny + " de a talalat lepergett a pancelzatrol..."
$
$                      else
$
$                         i=f$ex(1,1,i)
$
$                         baseHP'i'=baseHP'i' - temp
$
$                         if baseHP'i' .le. 0
$                         then
$
$                            esemeny=esemeny + " A bazis elpusztult. RIP " + f$str(i) + ". jatekos..."
$
$                         else
$
$                            esemeny=esemeny + " A bazis " + f$str(temp) + " veszteseget szenvedett. Maradt " + f$str(baseHP'i')
$
$                         endif
$
$                      endif
$
$                   else
$
$                      esemeny="Az egyseg nem talalta el a bazist!"
$
$                   endif
$
$                else
$
$                   if f$ex(1,1,i) .eq. aktplayer
$                   then
$
$                      esemeny="Sajat bazist tamadsz... megorultel!?"
$
$                   else
$
$                      esemeny="Az egyseg mar tamadott a korben..."
$
$                   endif
$
$                endif
$
$             else
$
$                tvp=f$el(0,"/",f$el(1,":",f$el(8,"|",unit'aktplayer''ki')))
$
$                if tvp .gt. 0
$                then
$
$                   temp=f$el(0,"|",selected) + "|" + f$el(1,"|",selected)
$                   unit'aktplayer''ki'=unit'aktplayer''ki' - temp
$
$                   temp=f$str(tempsor) + "|" + f$str(tempcol)
$                   unit'aktplayer''ki'=temp + unit'aktplayer''ki'
$
$                   esemeny="Az egyseg bemozgott: " + f$str(f$el(0,"|",selected)) + "," + f$str(f$el(1,"|",selected)) + " -> " + f$str(tempsor) + "," + f$str(tempcol)
$
$                   selected=temp
$
$                   if f$ex(0,1,i) .eqs. "F"
$                   then
$
$                      income'aktplayer'=income'aktplayer' + f$el(1,".",f$el(f$ex(1,1,i),"|",farmlist))
$                      temp=f$el(2,".",f$el(f$ex(1,1,i),"|",farmlist))
$
$                      income'temp'=income'temp'-f$el(1,".",f$el(f$ex(1,1,i),"|",farmlist))
$
$                      if temp .ne. aktplayer then esemeny=esemeny + ". A farm elfoglalva!"
$
$                      temp="|" + f$el(f$ex(1,1,i),"|",farmlist)
$
$                      farmlist=farmlist - temp
$
$                      temp=temp-f$el(2,".",temp)
$
$                      farmlist=farmlist + temp + f$str(aktplayer)
$
$                   endif
$
$                   temp=f$str(aktplayer)+","+f$str(ki)+","+"8"+","+"Lepes:"+f$str(tvp-1)+"/"+f$str(f$el(1,"/",f$el(8,"|",unit'aktplayer''ki')))
$
$                   gosub XCHG
$
$                else
$
$                   esemeny="Nincs eleg lepespontja az egysegnek!"
$
$                endif
$
$             endif
$
$          else
$
$             if i .eq. aktplayer
$             then
$
$                esemeny="Sajat egyseget nem tamadhatsz!!!"
$
$             else
$
$                if f$el(9,"|",unit'aktplayer''ki') .eqs. "Tamadott-e: nem"
$                then
$
$                   temp=f$str(aktplayer)+","+f$str(ki)+","+"8"+","+"Lepes:0/"+f$str(f$el(1,"/",f$el(8,"|",unit'aktplayer''ki')))
$
$                   gosub XCHG
$
$                   temp=f$str(aktplayer) + "," + f$str(ki) + ",9,Tamadott-e: igen"
$
$                   gosub XCHG
$
$                   temp=f$str(f$el(1,":",f$el(6,"|",unit'aktplayer''ki'))) + "," + f$str(f$el(1,":",f$el(5,"|",selecteddetails))) + "," + f$str(f$el(1,":",f$el(4,"|",unit'i''j'))) + "," + f$str(f$el(1,":",f$el(3,"|",unit'i''j')))
$
$                   gosub ATTACK
$
$                   if temp .eqs. "L"
$                   then
$
$                      esemeny="Az egysegnek nem sikerult talalatot elernie."
$
$                   else
$
$                      esemeny="Az egyseg talalatot ert el,"
$
$                      if temp .le. 0
$                      then
$
$                         esemeny=esemeny + " de az nem ment at a pancelzaton :P"
$
$                      else
$
$                         HP=f$el(0,"/",f$el(1,":",f$el(7,"|",unit'i''j')))
$
$                         HP=HP - temp
$
$                         if HP .le. 0
$                         then
$
$                            esemeny=esemeny + " es osszezuzta az ellenfelet. Yeah."
$
$!ZZZZZZZZZZZZZZZZZZZZZZZZZZZZZZZZZZZZZZZZZZZZZZZZZZZZZZZZZZZZZZZZZZZZZZZZZZZZZZZZZZZZZZZ
$                            XP=f$el(10,":",unit'aktplayer''ki')
$
$                            Lvl=f$el(1,":",f$el(10,"|",unit'aktplayer''ki')) + 1
$
$                            XP=XP + 2 * f$el(1,":",f$el(10,"|",unit'i''j'))
$
$                            temp=f$str(aktplayer) + "," + f$str(ki) + ",11,XP:" + f$str(XP)
$
$                            gosub XCHG
$
$                            if_lu_b:
$
$                            if XP .lt. Lvl * Lvl then goto if_lu_e
$
$                               temp=f$str(aktplayer) + "," + f$str(ki)
$
$                               gosub LU
$
$                               Lvl=Lvl + 1
$
$                               goto if_lu_b
$
$                               if_lu_e:
$
$                            temp=f$str(aktplayer) + "," + f$str(ki) + ",10,Szint:" + f$str(Lvl-1)
$
$                            gosub XCHG
$!-------------------------------------------------------
$                            unit'i''j'=""
$
$                         else
$
$                            esemeny=esemeny + " az okozott serules " + f$str(temp) + ", maradt " + f$str(HP)
$
$                            temp=f$str(i) + "," + f$str(j) + "," + "7" + "," + "HP:" + f$str(HP) + "/" + f$str(f$el(1,"/",f$el(7,"|",unit'i''j')))
$
$                            gosub XCHG
$
$                         endif
$
$                      endif
$
$                   endif
$
$!$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$$
$                else
$
$                   esemeny="Az egyseg mar tamadott ebben a korben!"
$
$                endif
$
$
$             endif
$
$          endif
$
$!statupload:
$          status2=f$el(3,"|",unit'aktplayer''ki')
$          status3=f$el(4,"|",unit'aktplayer''ki')
$          status4=f$el(5,"|",unit'aktplayer''ki')
$          status5=f$el(6,"|",unit'aktplayer''ki')
$          status6=f$el(7,"|",unit'aktplayer''ki')
$          status7=f$el(8,"|",unit'aktplayer''ki')
$          status8=f$el(9,"|",unit'aktplayer''ki')
$          status9=f$el(10,"|",unit'aktplayer''ki')
$          status10=f$el(11,"|",unit'aktplayer''ki')
$
$       else
$
$          esemeny="Doit hibas paramaterezese, vagy palya szele! Probald: Help"
$
$       endif
$
$    endif
$
$
$    goto endtranssub
$
$
$
$!+++++ ENDTURN ++++++++++++++++++
$
$    ENDTURN:
$
$    gosub STATCLEAR
$
$    last_player=aktplayer
$
$    details1=details2
$    details2=details3
$    details3=LF + CR
$
$    aktplayer=aktplayer+1
$    if aktplayer .gt. playernum then aktplayer=1
$
$    if baseHP'aktplayer' .le. 0 then goto ENDTURN
$
$    if last_player.eq.aktplayer
$    then
$
$       esemeny=f$str(jatekos'aktplayer') + "nyerte a jatekot. grat :)"
$       goto exit
$
$    endif
$
$    selected=""
$    enabled=0
$
$    money'aktplayer'=money'aktplayer'+income'aktplayer'
$
$    esemeny=f$str(jatekos'aktplayer') + " kore kovetkezik."
$    status1="Penz: " + f$str(money'aktplayer')
$    status2="Bevetel: " + f$str(income'aktplayer')
$    status3="Bazis HP: " + f$str(baseHP'aktplayer')
$
$ !////////////////////////////////////FELTOLTES ELEJE
$    i=0
$
$    charge_b:
$
$    if i .gt. 30 then goto charge_e
$
$       if unit'aktplayer''i' .nes. ""
$       then
$
$          maxHP=f$el(7,"|",unit'aktplayer''i')
$
$          HP=f$el(1,":",f$el(0,"/",maxHP))
$
$          maxHP=f$el(1,"/",maxHP)
$
$          maxTVP=f$el(8,"|",unit'aktplayer''i')
$
$          TVP=f$el(0,"/",maxTVP)
$
$          maxTVP=f$el(1,"/",maxTVP)
$
$          if HP .lt. maxHP
$          then
$
$             HP=HP + 1 + maxHP/4
$
$             if HP .gt. maxHP then HP=maxHP
$
$             temp=f$str(aktplayer) + "," + f$str(i) + ",7,HP:" + f$str(HP) + "/" + f$str(maxHP)
$
$             gosub XCHG
$
$          endif
$
$          if TVP .lt. maxTVP
$          then
$
$             TVP=maxTVP
$
$             temp=f$str(aktplayer) + "," + f$str(i) + "," + "8,Lepes:" + f$str(TVP) + "/" + f$str(TVP)
$
$             gosub XCHG
$
$          endif
$
$          if f$el(9,"|",unit'aktplayer''i') .eqs. "Tamadott-e: igen"
$          then
$
$             temp=f$str(aktplayer) + "," + f$str(i) + "," + "9,Tamadott-e: nem"
$
$             gosub XCHG
$
$          endif
$
$       endif
$
$    i=i+1
$
$    goto charge_b
$
$    charge_e:
$ !/////////////////////////////////////FELTOLTES VEGE
$
$    goto endtranssub
$
$
$
$ !+++++BUYUNIT++++++++++++++++++++
$
$    BUYUNIT:
$
$    order=f$el(1," ",order)
$
$    if f$le(order) .eq. 0
$    then
$
$       esemeny="Lehetseges parameterek: Felderito, Gyalogos, Vertes"
$
$    else
$
$       gosub FINDPLACE
$
$       if temp .eqs. ""
$       then
$
$          esemeny="Nincs hely az erkezo egysegnek!"
$
$       else
$
$          gosub FINDSLOT
$
$          if j .eq. 31
$          then
$
$             esemeny="Tul sok egyseged van!!!"
$
$          else
$
$             if order .eqs. f$ex(0,hossz,"felderito")
$             then
$
$                temp=temp + "|Tipus:Felderito|Pancel:''FelArm'|Vedelem:''FelDef'|Sebzes:''FelDmg'|Tamadas:''FelAtt'|HP:''FelHP'/''FelHP'|Lepes:0/''FelMov'|Tamadott-e: igen|Szint:1|XP:1"
$
$                order=3
$
$             else
$
$                if order .eqs. f$ex(0,hossz,"gyalogos")
$                then
$
$                   temp=temp + "|Tipus:Gyalogos|Pancel:''InfArm'|Vedelem:''InfDef'|Sebzes:''InfDmg'|Tamadas:''InfAtt'|HP:''InfHP'/''InfHP'|Lepes:0/''InfMov'|Tamadott-e: igen|Szint:1|XP:1"
$
$                   order=5
$
$                else
$
$                   if order .eqs. f$ex(0,hossz,"vertes")
$                   then
$
$                      temp=temp + "|Tipus:Vertes|Pancel:''ArmArm'|Vedelem:''ArmDef'|Sebzes:''ArmDmg'|Tamadas:''ArmAtt'|HP:''ArmHP'/''ArmHP'|Lepes:0/''ArmMov'|Tamadott-e: igen|Szint:1|XP:1"
$
$                      order=7
$
$                   else
$
$                      esemeny="Lehetseges parameterek: Felderito, Gyalogos, Vertes"
$
$                   endif
$
$                endif
$
$             endif
$
$             if esemeny .eqs. ""
$             then
$
$                if order .gt. money'aktplayer'
$                then
$
$                   esemeny="Nincs eleg penzed... meg " + f$str(order - money'aktplayer') + " kene. Beveteled: " + f$str(income'aktplayer')
$
$                else
$
$                   money'aktplayer'=money'aktplayer'-order
$
$                   details3=details3 + "A " + f$str(aktplayer) + "-s jatekos kikepzett egy " + f$el(1,":",f$el(2,"|",temp)) + "t." + LF + CR
$
$                   unit'aktplayer''j'=temp
$
$                endif
$
$             endif
$
$          endif
$
$       endif
$
$    endif
$
$    goto endtranssub
$
$
$ !+++++GETMANI(MANI) ELJARASA+++++
$
$    GETMANI:
$!ez majd at lesz(lehet) alakitva
$       esemeny="Az aktualis jatekosnak(" + f$str(jatekos'aktplayer') + ") " + f$str(money'aktplayer') + " penze van"
$
$    goto endtranssub
$
$
$!++++++HELP(HELP) ELJARASA+++++++++
$
$    HELP:
$
$    cls
$    temp=f$ed(f$el(1," ",order),"lowercase")
$
$    hossz=f$len(temp)
$
$    if hossz .eq. 0 then goto STANDARD_HELP
$
$    if temp .eqs. f$ex(0, hossz, "select") then goto SELECT_HELP
$    if temp .eqs. f$ex(0, hossz, "doit") then goto DOIT_HELP
$    if temp .eqs. f$ex(0, hossz, "endturn") then goto ENDTURN_HELP
$    if temp .eqs. f$ex(0, hossz, "buyunit") then goto BUYUNIT_HELP
$    if temp .eqs. f$ex(0, hossz, "getmani") then goto GETMANI_HELP
$    if temp .eqs. f$ex(0, hossz, "help") then goto STANDARD_HELP
$    if temp .eqs. f$ex(0, hossz, "exit") then goto EXIT_HELP
$    if temp .eqs. f$ex(0, hossz, "more") then goto MORE_HELP
$    if temp .eqs. f$ex(0, hossz, "szintlepes") then goto LU_HELP
$    if temp .eqs. f$ex(0, hossz, "harc") then goto HARC_HELP
$    if temp .eqs. f$ex(0, hossz, "jelmagyarazat") then goto DISPLAY_HELP
$
$    say "Nem ismertem fel, mint lehetseges opciot..." + LF
$
$    STANDARD_HELP:
$
$    say "HELP" + LF
$    say TAB + "Ez a jetek HELP resze. Rovid leirast kapsz a jatekrol, majd a" + LF + CR + TAB + "reszletesebben kerdezheto topikok felsorolasa kovetkezik." + LF
$    say TAB + TAB + "$ A program egy korokre osztott, parancssoros, karaktergrafikas" + LF + CR + TAB + TAB + "strategiai jatek, kozepkori stilusban." + LF + CR + TAB + TAB + "A cel az ellenfel bazisanak lerombolasa"
$    say TAB + TAB + "$ A program parameterezheto a jatekosok neveivel, 5 karakterre" + LF + CR + TAB + TAB + "csonkitva(a program elvegzi a csonkitast)"
$    say TAB + TAB + "$ Bovebb informacio a kovetekezokrol(a parancsok nagybetuig" + LF + CR + TAB + TAB + "rovidithetoek):" + LF
$    say TAB + "Select" + TAB + "Doit" + TAB + "Endturn" + TAB + "Buyunit" + TAB + "Getmani" + TAB + "Help" + TAB + "EXit" + LF + CR + TAB + "More" + TAB + "HArc" + TAB + "SZintlepes" + TAB + "Jelmagyrazat"
$    say ""
$
$    goto END_HELP
$
$    SELECT_HELP:
$
$    say "SELECT" + LF
$    say TAB + "Ezzel az utasitassal lehet kijelolni a falvakat, egysegeket," + LF + CR + TAB + "bazisokat, akar egymas alatt is."
$    say TAB + "Az adatokrol, amiket szolgaltathat:" + LF + CR + TAB + "Bazis: azt hiszem, evidens, tulajdonosa, annak penze es bevetele" + LF + CR + TAB + "Falu: a tulajdonosrol: ha 0, akkor meg nincs neki(ez konnyen"
$    say TAB + "valtozhat :))" + LF + CR + TAB + "Egysegek: az egyes ertekekrol bovebben a Doit parancsnal," + LF + CR + TAB + "a harc resznel valamint a szintlepesnel." + LF
$
$    goto END_HELP
$
$    DOIT_HELP:
$
$    say "DOIT" + LF
$    say "Szintaxis: Doit Jobbra/Fel/Balra/Le. Nagybetuig roviditheto." + LF
$    say TAB + "A parancs csak sajat egyseg kijelolese utan mukodokepes, ekkor" + CR + LF + TAB + "az adott iranyba vegrehajthato tevekenyseget kiserli meg: tamad," + LF + CR + TAB + "vagy mozog."
$    say TAB + "Mozogni akkor tud, ha a lepeseinek a szama 0 felett van, ilyenkor" + LF + CR + TAB + "csokken eggyel, tamadni ha abban a korban meg nem tamadott(es nem" + LF + CR + TAB + "az elso kore van). Ekkor abban a korben mar nem lephet."
$    say TAB + "A harc szabalyairol tovabbi informaciokat a help Harc reszenel."
$
$    goto END_HELP
$
$    ENDTURN_HELP:
$
$    say "ENDTURN" + LF
$    say "Szintaxis: Endturn. Nagybetuig roviditheto." + LF
$    say TAB + "A parancs a kor befejezesere szolgal."
$    say TAB + "A kor elejen vegrehajtodo tevekenysegek:"
$    say TAB + TAB + "$ A jatekos penzt kap a bevetelei utan"
$    say TAB + TAB + "$ Az egysegek feltoltodnek:"
$    say TAB + TAB + TAB + "a) maximum lepesszamra"
$    say TAB + TAB + TAB + "b) (ujra) tudnak tamadni"
$    say TAB + TAB + TAB + "c) 1/4-nyi HP-t visszatoltenek maximumig" + LF
$
$    goto END_HELP
$
$    BUYUNIT_HELP:
$
$    say "BUYUNIT" + LF
$    say "Szintaktika: Buyunit <Felderito/Gyalogos/Vertes>; nagybetuig roviditheto" + LF
$    say TAB + "A parancs egyseg vasarlasara szolgal, amely harom fajta" + LF + CR + TAB + "lehet: Felderito, Gyalogos es Vertes." + LF + CR + TAB + "Az egysegek a bazisod ketto sugaru kornyezeteben jelennek meg," + LF + CR + TAB + "ha van helyuk." + LF
$    say TAB + "Alapertekek" + LF + CR + TAB + TAB + "Felderito:   Gyalogos:   Vertes:"
$    say TAB + "Ar:" + TAB + TAB + "3           5         7"
$    say TAB + "Pancel:" + TAB + TAB + "''FelArm'           ''InfArm'         ''ArmArm'"
$    say TAB + "Vedelem:" + TAB + "''FelDef'           ''InfDef'         ''ArmDef'"
$    say TAB + "Sebzes:" + TAB + TAB + "''FelDmg'           ''InfDmg'         ''ArmDmg'"
$    say TAB + "Tamadas:" + TAB + "''FelAtt'           ''InfAtt'         ''ArmAtt'"
$    say TAB + "Hp:" + TAB + TAB + "''FelHP'           ''InfHP'         ''ArmHP'"
$    say TAB + "Lepes:" + TAB + TAB + "''FelMov'           ''InfMov'         ''ArmMov'"
$
$    say TAB + "/Megjegyzes: az egysegek nem tamadhatnak az elso korukben./" + LF
$
$    goto END_HELP
$
$    GETMANI_HELP:
$
$    say "GETMANI" + LF
$    say "Szintaktika: Getmani. Nagybetuig roviditheto." + LF
$    say "/Jelenleg csak visszaadja a meglevo penzmag erteket, kesobb fejleszteseket tervezek a paranccsal kapcsolatban/" + LF
$
$    goto END_HELP
$
$    EXIT_HELP:
$
$    say "EXIT" + LF
$    say "Szintaktika: EXit. Nagybetuig roviditheto." + LF
$    say TAB + "Befejezi a program futasat."
$    say TAB + "/Fejlesztesi lehetoseg: mentes opcio/" + LF
$
$    goto END_HELP
$
$    MORE_HELP:
$
$    say "MORE" + LF
$    say "Szintaktika: More. Nagybetuig roviditheto" + LF
$    say "Kiirja tomor es elsore kicsit erthetetlen formaban az elmult 3 kor esemenyeinek reszleteit, ahol szuksegesnek veltem. Segitsetek, hol mit irjon meg!" + LF
$
$    goto END_HELP
$
$    LU_HELP:
$
$    say "LEVEL UP" + LF
$    say TAB + "Szintet akkor lepnek az egysegek, ha az XP mennyiseg elerte" + LF + CR + TAB + "a kovetkezo szint negyzetet(bonyolult? :))"
$    say TAB + "XP-t akkor kapnak az egysegek, ha legyoznek egy masikat, ekkor az" + LF + CR + TAB + "ellen szintjenek ketszereset kapja meg tapasztalatkent."
$    say TAB + "Szintlepeskor a kovetkezo ertekek adodnak az eddigiekhez(tortresz" + LF + CR + TAB + "csak paros szinteken!):"
$    say TAB + TAB + ">> Felderito:  2/0,5/  2/  1/  2/0,5"
$    say TAB + TAB + ">> Gyalogos:   3/1,5/  3/  2/  1/1,5"
$    say TAB + TAB + ">> Vertes:   3,5/  2/  4/  3/0,5/  2"
$    say TAB + TAB + "Magyarazat:  Def/Dmg/Att/ HP/Mov/Arm" + LF
$
$    goto END_HELP
$
$    HARC_HELP:
$
$    say "HARC" + LF
$    say "Ez a kis leiras a harcrendszerrol keszult. Hogy te is ertsed miert halmeg az egyik, mikor a masik eletben marad. Az elet kegyetlen... :)" + LF
$    say TAB + "Tamadaskor a talalat a att+att*x >= def esetben kovetkezik be."
$    say TAB + "//A kepletben az att a tamado Tamadas erteke, a def a vedekezo fel" + LF + CR + TAB + "Vedelem erteke, x pedig egy 0,01 es 1 kozotti szam//"
$    say TAB + "A HP veszteseg egyszeruen a sebzes es a pancelzat kulonbsegenek a pozitiv resze." + LF
$
$    goto END_HELP
$
$    DISPLAY_HELP:
$
$    say "MEGJELENITES" + LF
$    say "Maga a tabla egy 20x30-s matrix, dolgozom meg a jobb atlathatosagon..."
$    say "Jelenleg(v0.7) egy 2-s bontasu raccsal probalom a koordinatakat lathatova tenni... minden otletre vevo vagyok! :)"
$    say "Mivel ket karakteren kell megjelenitenem minden informaciot, nem biztos, hogy" + LF + CR + "egyertelmuek a jeloleseim. Akkor kovetkezzek egy kis magyarazat..." + LF
$    say TAB + "@n:" + TAB + "Falu, n-l jelolve az altala szolgaltatott bevetelt."
$    say TAB + "Bn:" + TAB + "Bazis, n-l a tulajdonosat jelolve."
$    say TAB + "F/G/Vn:" + TAB + "Egyseg, n itt is a tulajt jeloli(gondoltam meg a szintre, de ket karakter...)" + LF
$
$    goto END_HELP
$
$    END_HELP:
$    read /prompt="Nyomj enter a folytatashoz..." sys$command order
$
$    order="h " + f$str(order)
$
$    if f$len(order) .ne. 2 then goto HELP
$
$    goto endtranssub
$
$
$!+++++EXIT(EXIT) ELJARASA+++++
$
$!//////Ide majd a ment? kell
$
$    EXIT:
$
$    say "Kosz, hogy engem valasztottal!!!"
$    say "********************************************************************************"
$    say "*------------------------------------------------------------------------------*"
$    say "*--++++++------------+++++-------+++++----------+++++++++++------------++++----*"
$    say "*--+++++++------------+++++-----+++++-----------+++++++++++------------++++----*"
$    say "*--+++--+++------------+++++---+++++------------++++-------------------++++----*"
$    say "*--+++--+++-------------+++++-+++++-------------++++-------------------++++----*"
$    say "*--+++-+++---------------+++++++++--------------+++++++++--------------++++----*"
$    say "*--++++--------------------+++++----------------+++++++++--------------++++----*"
$    say "*--++++++------------------+++++----------------++++-------------------++++----*"
$    say "*--+++--+++----------------+++++----------------++++---------------------------*"
$    say "*--+++---+++---------------+++++----------------++++--------------------++-----*"
$    say "*--+++---+++---------------+++++----------------+++++++++++------------++++----*"
$    say "*--++++++++----------------+++++----------------+++++++++++-------------++-----*"
$    say "*------------------------------------------------------------------------------*"
$    say "********************************************************************************"
$
$    exit
$
$
$    endtranssub:
$
$    return
$
$!+++++++++++++++++++MORE+++++++++++++++++++
$
$    MORE:
$
$    say "1: ",details1,"2: ",details2,"3: ",details3
$    read /prompt="Nyomj entert a folyatatashoz!" sys$command temp
$
$    return
$
$ !++++++++++++++++++++?RARAJZOL? PROC++++++++++++++++++++
$
$
$ REDRAW:
$
$ gosub MAPRESET
$
$!farmberajzolo
$    i=f$el(1,"|",farmlist)
$    temp=1
$
$    farmdraw_b:
$
$    if i .eqs. "|" then goto farmdraw_e
$
$       sor'f$el(0,"-",i)'=f$ex(0,(f$el(1,"-",f$el(0,".",i)))*2,sor'f$el(0,"-",i)') + "@" + f$el(1,".",i) + f$ex(2+(f$el(1,"-",f$el(0,".",i)))*2,60,sor'f$el(0,"-",i)')
$
$    temp=temp+1
$    i=f$el(temp,"|",farmlist)
$
$    goto farmdraw_b
$
$    farmdraw_e:
$!egysegberajzolo
$    i=1
$
$    drc_outer_b:
$
$    if i .gt. playernum then goto drc_outer_e
$
$    j=0
$
$       drc_inner_b:
$
$       if j .gt. 30 then goto drc_inner_e
$
$          if unit'i''j' .nes. ""
$          then
$
$             tempsor=f$el(0,"|",unit'i''j')
$             tempcol=f$el(1,"|",unit'i''j')
$             sor'tempsor'=f$ex(0,tempcol*2,sor'tempsor') + f$ex(6,1,f$el(2,"|",unit'i''j')) + f$str(i) + f$ex(2+tempcol*2,60,sor'tempsor')
$
$          endif
$
$          j=j+1
$
$          goto drc_inner_b
$
$       drc_inner_e:
$
$    i=i+1
$
$    goto drc_outer_b
$
$    drc_outer_e:
$
$    cls
$    i=1
$    say "    1 2 3 4 5 6 7 8 910 1 2 3 4 5 6 7 8 920 1 2 3 4 5 6 7 8 930"
$    say "  +------------------------------------------------------------"
$
$
$    drc_eleje:
$
$       if i .gt. 20 then goto drc_vege
$
$       temp=f$ex(0,2,sor'i') + "|" + f$ex(2,60,sor'i') + " " + status'i'
$
$       say temp
$
$       i=i+1
$
$       goto drc_eleje
$
$    drc_vege:
$
$    say esemeny
$
$ return
$
$
$ !++++++++++++++++++++++++++++++++
$ !+++ Kitorli a statusmezoket ++++
$ !++++++++++++++++++++++++++++++++
$
$ STATCLEAR:
$
$    z=1
$    statclear_b:
$
$    if z .gt. 20 then goto statclear_e
$
$       status'z'=""
$
$       z=z+1
$
$       goto statclear_b
$
$    statclear_e:
$
$ del/sy z
$
$ return
$
$
$ !+++++++++++++++++++++++++++++++++
$ !+++ reseteli a mozgo sorokat ++++
$ !+++++++++++++++++++++++++++++++++
$
$ MAPRESET:
$
$    z=1
$    mapreset_b:
$
$    if z .gt. 20 then goto mapreset_e
$
$       sor'z'=bsor'z'
$
$       z=z+1
$
$       goto mapreset_b
$
$    mapreset_e:
$
$ del/sy z
$
$ return
$
$
$
$ !++++++++++++++++++++++++++++++
$ !+++ kitorli a unitmezoket ++++
$ !++++++++++++++++++++++++++++++
$
$ UNITCLEAR:
$
$ z=1
$
$ uclear_out_b:
$
$ if z .gt. playernum then goto uclear_out_e
$
$       z1=0
$
$       uclear_inner_b:
$
$       if z1 .gt. 30 then goto uclear_inner_e
$
$          unit'z''z1'=""
$
$          z1=z1+1
$
$          goto uclear_inner_b
$
$       uclear_inner_e:
$
$    z=z+1
$
$    goto uclear_out_b
$
$ uclear_out_e:
$
$ del/sy z
$ del/sy z1
$
$ return
$
$
$ !++++++++++++++++++++++++++++++++++++++++++++++++++++
$ !+++                                           ++++++
$ !+++ temp=jatekos,egysegszam,hanyadikslot,mire ++++++
$ !+++ Kicsereli unit tomb egy elemet(nem koord  ++++++
$ !+++                                           ++++++
$ !++++++++++++++++++++++++++++++++++++++++++++++++++++
$
$
$ XCHG:
$
$ tmpi=f$el(0,",",temp)
$ tmpj=f$el(1,",",temp)
$ tmpk=f$el(2,",",temp)
$ tmpstr=f$el(3,",",temp)
$ tmpc=1
$ temp2=""
$
$    temp=f$el(1,"|",unit'tmpi''tmpj')
$
$    temp2=f$el(0,"|",unit'tmpi''tmpj')
$
$    xchg_b:
$
$    if temp .eqs. "|" then goto xchg_e
$
$       if tmpk .eq. tmpc
$       then
$
$          temp2=temp2 + "|" + f$str(tmpstr)
$
$       else
$
$          temp2=temp2 + "|" + f$str(temp)
$
$       endif
$
$    tmpc=tmpc+1
$
$    temp=f$el(tmpc,"|",unit'tmpi''tmpj')
$
$    goto xchg_b
$
$    xchg_e:
$
$    unit'tmpi''tmpj'=temp2
$
$ del/sy temp2
$ del/sy tmpc
$ del/sy tmpi
$ del/sy tmpj
$ del/sy tmpk
$ del/sy tmpstr
$
$ return
$
$
$
$ !+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
$ !++++                                              +++++++++++
$ !++++ ELJARAS, AMI MEGHATAROZZA, HA EGYSEG VAN OTT +++++++++++
$ !++++ parameter: tempcol, tempsor                      +++++++
$ !++++ visszaad: i, j(unit'i''j' ha van, i=0 egyebkent) +++++++
$ !++++                                                  +++++++
$ !+++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
$ WHOSTHERE:
$
$    i=1
$    van=0
$
$    testcouter_eleje:
$
$    if i .gt. playernum then goto testcouter_vege
$
$    j=0
$
$       testcinner_eleje:
$
$       if j .gt. 30 then goto testcinner_vege
$
$          if f$int(f$el(0,"|",unit'i''j')) .eq. tempsor .and. f$int(f$el(1,"|",unit'i''j')) .eq. tempcol then van=1
$
$          if van .ne. 0 then goto testcouter_vege
$
$       j=j+1
$
$       goto testcinner_eleje
$
$       testcinner_vege:
$
$    i=i+1
$
$    goto testcouter_eleje
$
$    testcouter_vege:
$
$    if van .eq. 0
$    then
$
$       i=0
$
$    endif
$
$ return
$
$
$
$
$ !++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
$ !++++                                               +++++++++++++
$ !++++ ELJARAS, AMI MEGHATAROZZA, HA EPULET VAN OTT  +++++++++++++
$ !++++ parameter: tempcol, tempsor                              ++
$ !++++ visszaad: F+farm szama ha farm,B+jatekos szama, ha bazis ++
$ !++++                                                          ++
$ !++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++++
$ WHATSTHERE:
$
$    i=""
$
$    if tempsor .eq. 1 .and. tempcol .eq. 1 then i="B1"
$    if tempsor .eq. 20 .and. tempcol .eq. 30 then i="B2"
$
$    if playernum .gt. 2
$    then
$
$       if tempsor .eq. 1 .and. tempcol .eq. 30 then i="B3"
$       if tempsor .eq. 20 .and. tempcol .eq. 1 then i="B4"
$
$    endif
$
$    if i .eqs. ""
$    then
$
$       j=1
$       temp=f$element(1,"|",farmlist)
$
$       farmtest_eleje:
$
$       if temp .eqs. "|" .or. i .nes. "" then goto farmtest_vege
$
$          if tempsor .eq. f$el(0,"-",temp) .and. tempcol .eq. f$el(0,".",f$el(1,"-",temp)) then i="F"+f$str(j)
$
$          j=j+1
$
$          temp=f$element(j,"|",farmlist)
$
$       goto farmtest_eleje
$
$       farmtest_vege:
$
$    endif
$
$ return
$
$ !+++++++++++++++++++++++++++
$ !+++ Ures slotot talal +++++
$ !+++ az uj egysegnek   +++++
$ !+++++++++++++++++++++++++++
$
$ FINDSLOT:
$
$ j=0
$
$ findslot_b:
$
$ if j .gt. 30 .or. unit'aktplayer''j' .eqs. "" then goto findslot_e
$
$    j=j + 1
$
$ goto findslot_b
$
$ findslot_e:
$
$ return
$
$ !+++++++++++++++++++++++++
$ !+++ Ures helyet talal +++
$ !+++ a bazis kornyeken +++
$ !+++++++++++++++++++++++++
$
$ FINDPLACE:
$
$    temp=dir'aktplayer'
$
$    h=0
$    ures=0
$
$    findplace_b:
$
$       tempsor=f$el(0,"-",f$el(h,",",temp))
$
$       tempcol=f$el(1,"-",f$el(h,",",temp))
$!say "tempsor:" + f$str(tempsor) + LF + CR + "tempcol:" + f$str(tempcol) + LF + CR + f$str(h)
$       if tempsor .eqs. "," .or. ures .eq. 1 then goto findplace_e
$!ezt meg at kell majd irni...
$
$!       tempsor=f$el(0,"-",f$el(j,",",temp))
$
$!       tempcol=f$el(1,"-",f$el(j,",",temp))
$
$       gosub WHOSTHERE
$
$          if i .eq. 0
$          then
$
$             temp=f$str(tempsor) + "|" + f$str(tempcol)
$             ures=1
$
$          endif
$
$       h=h+1
$
$    goto findplace_b
$
$    findplace_e:
$
$ if ures .eq. 0 then temp=""
$
$ return
$
$
$ !++++++++++++++++++++++++++++++++++++++++++++++++++++
$ !+++                                    +++++++++++++
$ !+++ temp=tamadas,sebzes,vedelem,pancel +++++++++++++
$ !+++ Levezenyli a tamadast              +++++++++++++
$ !+++                       ++++++++++++++++++++++++++
$ !++++++++++++++++++++++++++++++++++++++++++++++++++++
$
$ ATTACK:
$
$ att=f$el(0,",",temp)
$ def=f$el(2,",",temp)
$ dmg=f$el(1,",",temp)
$ arm=f$el(3,",",temp)
$
$    temp=f$el(1,".",f$ti()) + 1
$
$    details3=details3 + "A tamado dobas erteke " + f$str(temp)
$
$    temp=temp*att/100+att-def
$
$    details3=details3 + ", ezzel a tamadas erteke " + f$str(temp)
$
$    if temp .gt. 0
$    then
$
$       temp=f$int(dmg) - f$int(arm)
$
$       details3=details3 + ". A sebzes " + f$str(dmg) + "-" + f$str(arm) + ": " + f$str(temp) + LF + CR
$
$    else
$
$       details3=details3 + ", igy nem talalt..." + LF + CR
$
$       temp="L"
$
$    endif
$
$ del/sy att
$ del/sy def
$ del/sy dmg
$ del/sy arm
$
$ return
$
$
$ !+++++++++++++++++++
$ !+++ Szintlepes ++++
$ !+++++++++++++++++++
$
$ LU:
$
$ li=f$el(0,",",temp)
$ lj=f$el(1,",",temp)
$
$    temp=unit'li''lj'
$    type=f$el(0,"|",f$el(1,":",temp))
$    att=f$el(1,":",f$el(6,"|",temp))
$    def=f$el(1,":",f$el(4,"|",temp))
$    dmg=f$el(1,":",f$el(5,"|",temp))
$    arm=f$el(1,":",f$el(3,"|",temp))
$    HP=f$el(0,"/",f$el(1,":",f$el(7,"|",temp)))
$    mHP=f$el(1,"/",f$el(7,"|",temp))
$    TVP=f$el(0,"/",f$el(1,":",f$el(8,"|",temp)))
$    mTVP=f$el(1,"/",f$el(8,"|",temp))
$    ifatt=f$el(9,"|",temp)
$    temp=f$el(0,":",temp) + ":" + type + "|Pancel:"
$
$    if type .eqs. "Felderito"
$    then
$
$       patt=2
$       pdef=2
$       pdmg=0
$       if Lvl then dmg=dmg + 1
$       parm=0
$       if Lvl then arm=arm + 1
$       pHP=1
$       pTVP=2
$
$    else
$
$       if type .eqs. "Gyalogos"
$       then
$
$          patt=3
$          pdef=3
$          pdmg=1
$          if Lvl then dmg=dmg + 1
$          parm=1
$          if Lvl then arm=arm + 1
$          pHP=2
$          pTVP=1
$
$       else
$
$          patt=4
$          pdef=3
$          if Lvl then def=def + 1
$          pdmg=2
$          parm=2
$          pHP=3
$          pTVP=0
$          if Lvl
$          then
$             mTVP=mTVP + 1
$             TVP=TVP + 1
$          endif
$
$       endif
$
$    endif
$
$    att=att + patt
$    def=def + pdef
$    dmg=dmg + pdmg
$    arm=arm + parm
$    HP=HP + pHP
$    mHP=mHP + pHP
$    TVP=TVP + pTVP
$    mTVP=mTVP + pTVP
$
$    unit'li''lj'=temp + f$str(arm) + "|Vedelem:" + f$str(def) + "|Sebzes:" + f$str(dmg) + "|Tamadas:" + f$st(att) + "|HP:" + f$st(HP) + "/" + f$st(mHP) + "|Lepes:" + f$st(TVP) + "/" + f$st(mTVP) + "|" + ifatt + "|Szint:" + f$st(Lvl)+"|XP:"+f$st(XP)
$
$ del/sy li
$ del/sy lj
$
$ return
$
$