#version 120

uniform sampler2D renderedTex;
uniform vec2 screenSize;
varying vec2 v_tex;

//uniform mat3 rgbMat = [3.2404542, -1.5371385, -0.4985314, -0.9692660,  1.8760108,  0.0415560,  0.0556434, -0.2040259,  1.0572252];


void main(void) {

        float FXAA_SPAN_MAX = 8.0;
        float FXAA_REDUCE_MUL = 1.0/8.0;
        float FXAA_REDUCE_MIN = 1.0/128.0;

        vec3 rgbNW=texture2D(renderedTex,v_tex+(vec2(-1.0,-1.0)/screenSize)).xyz;
        vec3 rgbNE=texture2D(renderedTex,v_tex+(vec2(1.0,-1.0)/screenSize)).xyz;
        vec3 rgbSW=texture2D(renderedTex,v_tex+(vec2(-1.0,1.0)/screenSize)).xyz;
        vec3 rgbSE=texture2D(renderedTex,v_tex+(vec2(1.0,1.0)/screenSize)).xyz;
        vec3 rgbM=texture2D(renderedTex,v_tex).xyz;

        vec3 luma=vec3(0.299, 0.587, 0.114);



        float lumaNW = dot(rgbNW, luma);
        float lumaNE = dot(rgbNE, luma);
        float lumaSW = dot(rgbSW, luma);
        float lumaSE = dot(rgbSE, luma);
        float lumaM  = dot(rgbM,  luma);

        float lumaMin = min(lumaM, min(min(lumaNW, lumaNE), min(lumaSW, lumaSE)));
        float lumaMax = max(lumaM, max(max(lumaNW, lumaNE), max(lumaSW, lumaSE)));

        vec2 dir;
        dir.x = -((lumaNW + lumaNE) - (lumaSW + lumaSE));
        dir.y =  ((lumaNW + lumaSW) - (lumaNE + lumaSE));



        float dirReduce = max(
                (lumaNW + lumaNE + lumaSW + lumaSE) * (0.25 * FXAA_REDUCE_MUL),
                FXAA_REDUCE_MIN);

        float rcpDirMin = 1.0/(min(abs(dir.x), abs(dir.y)) + dirReduce);

        dir = min(vec2( FXAA_SPAN_MAX,  FXAA_SPAN_MAX),
                  max(vec2(-FXAA_SPAN_MAX, -FXAA_SPAN_MAX),
                  dir * rcpDirMin)) / screenSize;



        vec3 rgbA = (1.0/2.0) * (
                texture2D(renderedTex, v_tex.xy + dir * (1.0/3.0 - 0.5)).xyz +
                texture2D(renderedTex, v_tex.xy + dir * (2.0/3.0 - 0.5)).xyz);
        vec3 rgbB = rgbA * (1.0/2.0) + (1.0/4.0) * (
                texture2D(renderedTex, v_tex.xy + dir * (0.0/3.0 - 0.5)).xyz +
                texture2D(renderedTex, v_tex.xy + dir * (3.0/3.0 - 0.5)).xyz);
        float lumaB = dot(rgbB, luma);

        //gl_FragColor.xyz = rgbB.xyz;
		//gl_FragColor.a = 1.0;
        //return;


        if((lumaB < lumaMin) || (lumaB > lumaMax)){
                gl_FragColor.xyz=rgbA;
        }else{
                gl_FragColor.xyz=rgbB;
        }
        gl_FragColor.w = 1.0;


}