AoC NoPatcher/NoVideo by Glyph

@ECHO on

ECHO AoC NoPatcher/NoVideo by Glyph
ECHO "aoc -patch" to start the patcher
ECHO "aoc -restore" to restore the config file
ECHO.
ECHO "aoc -fps" to try and improve your fps using timeBeginPeriod / timeEndPeriod
ECHO "aoc -priority" to launch the game with priority above normal
ECHO "aoc -clearcache" to clear the shader cache before starting the game
ECHO.
ECHO "aoc <user> <pass>" to save you from typing them ingame
ECHO.
ECHO Can be combined. Exmaple: "aoc -fps -clearcache John topsecret"
ECHO.
ECHO -------------------------------------------
ECHO.

:params
IF "%1" == "-patch" GOTO patch
IF "%1" == "-restore" GOTO restore
IF "%1" == "-fps" GOTO fps
IF "%1" == "-priority" GOTO priority
IF "%1" == "-clearcache" GOTO clearcache
GOTO backup

:fps
SET fps=true
SHIFT
GOTO params

:priority
SET priority=true
SHIFT
GOTO params

:clearcache
ECHO Deleting cache...
DEL shader.cache.local
SHIFT
GOTO params

:backup
IF EXIST LocalConfig.xml.bak GOTO bypass
ECHO Creating backup...
COPY LocalConfig.xml LocalConfig.xml.bak

:bypass
ECHO Bypassing patcher...
TYPE LocalConfig.xml | FIND /V "<HttpPatchFolder>" > LocalConfig.xml.tmp
MOVE LocalConfig.xml.tmp LocalConfig.xml

IF "%fps%" == "true" ECHO Changing FPS booster setting...
IF "%fps%" == "true" rundll32 winmm.dll timeBeginPeriod 1

ECHO Starting client...
ECHO.
ECHO Please do NOT close this window, it will revert the changes when game closes.
IF "%priority%" == "true" ECHO Using priority above normal
IF "%priority%" == "true" START /WAIT /ABOVENORMAL AgeOfConan.exe -novideo -noconsole -username %1 -password %2
IF NOT "%priority%" == "true" AgeOfConan.exe -novideo -noconsole -username %1 -password %2

IF "%fps%" == "true" ECHO Restoring FPS booster setting to default...
IF "%fps%" == "true" rundll32 winmm.dll timeEndPeriod 1

GOTO restore

:restore
ECHO Restoring backup...
MOVE LocalConfig.xml.bak LocalConfig.xml
GOTO eof

:patch
ECHO Restoring backup...
MOVE LocalConfig.xml.bak LocalConfig.xml
ECHO Starting patcher...
start ConanPatcher.exe
GOTO eof

:eof