retroarch-git-imx

# Added stuff for Cubox-i: msalerno
# Maintainer: Mike Swanson <mikeonthecomputer@gmail.com>

pkgname=retroarch-git
_gitname=RetroArch
epoch=1
pkgver=1.2.2.212.gdd7cc40
pkgrel=1
pkgdesc="Simple frontend for the Libretro API"
arch=('armv7h')
url="http://github.com/libretro/RetroArch"
license=('GPL3')
depends=('ffmpeg' 'jack2' 'libusb' 'openal' 'python' 'sdl2')
optdepends=('libretro-super-git: A collection of libretro implementations.')
makedepends=('git')
provides=('retroarch')
conflicts=('retroarch')
source=("git+https://github.com/libretro/$_gitname.git")
sha256sums=('SKIP')

pkgver() {
  cd "$_gitname"
  local version=$(git describe --tags)
  local version=${version/v/}
  local version=${version//-/.}
  echo $version
}

build() {
  cd "$_gitname"

  ./configure --prefix=/usr --enable-neon --enable-sdl2 --enable-udev --enable-vivante_fbdev \
   --disable-x11 --enable-gles --enable-alsa --enable-jack --disable-sdl --disable-kms \
   --enable-floathard --enable-fbo
  make
}

package() {
  cd "$_gitname"

  make install DESTDIR="$pkgdir"
}