Platinum Arts Sandbox - Cutscenes Example

cs_post [
	r_global_set @var_intro 1
	r_loop_ents curmap ent [
		if (= (r_get_type ent) $ENT_CHAR)  [
			if (= (r_get_faction ent) 1) [
				r_destroy ent
			]
		]
	]
]

if (r_global_get @var_intro) [] [
	//initalise
	cs_interp_cos [
		cs_element_solid 0 0 $hud_right $hud_bottom 0 0 1000
	]
	cs_action_movecamera 2 0
	cs_action_viewcamera 2 0

	//transitions and controls
	cs_container_generic [
		cs_action_generic 10500 [
			cs_element_solid 0 0 $hud_right $hud_bottom 0 0 500 [
				cs_action_movecamera 1 0 [cs_action_movecamera 0 21000]
				cs_action_viewcamera 1 0 [cs_action_viewcamera 0 21000]
				cs_interp_dlinear [ cs_element_solid 0 0 $hud_right $hud_bottom 0 0 500 ]
			]
		]
		cs_action_generic 31000 [
			cs_element_solid 0 0 $hud_right $hud_bottom 0 0 1000 [
				cs_interp_one [
					cs_element_solid 0 0 $hud_right $hud_bottom 0 0 3000 [
						cs_interp_dlinear [
							cs_element_solid 0 0 $hud_right $hud_bottom 0 0 1000
						]
					]
				]
			]
			cs_action_generic 1000 [
				cs_action_viewport player 4000
			]
		]
	] 0

	//subtitles
	cs_interp_one [
		cs_container_generic [
			cs_action_generic 1000 [
				cs_element_text (- (div $hud_right 2) 100) (- $hud_bottom 300) 1200 0xFF00FF "Aiee!" 1500 [
					cs_element_text (- (div $hud_right 2) 600) (- $hud_bottom 300) 1200 0xFFFF00 "Hey buddy, are you alright?" 1500 [
						cs_element_text (- (div $hud_right 2) 600) (- $hud_bottom 300) 1200 0x00FFFF "I'm fine but the door's stuck" 2000 [
							cs_element_text (- (div $hud_right 2) 600) (- $hud_bottom 300) 1200 0xFFFF00 "It's indeed stuck, we'll look for another entrance!" 2500 [
								cs_element_text (- (div $hud_right 2) 600) (- $hud_bottom 300) 1200 0xFF0000 "You should look for another way out as well" 1500 [
									cs_element_text (- (div $hud_right 2) 400) (- $hud_bottom 300) 1200 0xFFFF00 "Let's move out!" 1000
								]
							]
						]
					]
				]
			]
			cs_action_generic 13000 [
				cs_element_text (- (div $hud_right 2) 600) (- $hud_bottom 300) 1200 0x007F7F "This place was built in the face of a cliff and has been abandoned for some years." 3000 [
					cs_element_text (- (div $hud_right 2) 600) (- $hud_bottom 300) 1200 0x007F7F "Frankly it looks more like a tomb than a mansion..." 3000 [
						cs_element_text (- (div $hud_right 2) 600) (- $hud_bottom 300) 1200 0x007F7F "Everyone here just disappeared one day and the place deemed cursed by the nearby town."	3000 [
							cs_element_text (- (div $hud_right 2) 600) (- $hud_bottom 300) 1200 0x007F7F "Regardless, I shouldn't stay in this forsaken place longer than required" 3000
						]
					]
				]
			]
			cs_action_generic 32000 [
				cs_container_translate (div $hud_right 2) (div $hud_bottom 2) [
					cs_interp_linear [
						cs_container_scale 2.5 2.5 [
							cs_interp_one [
								cs_element_text -200 -48 400 0x7F7F7F "Hirato Presents" 3000
								cs_element_text -100 48 200 0xFFFFFF "Mystara" 3000
							]
						] 3000
					]
				]
			]
		] 0
	]
]