Android build.gradle

import groovy.io.FileType
buildscript {
    repositories {
        mavenCentral()
    }
    dependencies {
        classpath 'com.android.tools.build:gradle:0.5.+'
        classpath 'com.squareup.gradle:gradle-android-test-plugin:0.9.+'
    }
}
apply plugin: 'android'
apply plugin: 'android-test'

repositories {
    mavenCentral()
}

android {
    compileSdkVersion 18
    buildToolsVersion "18.0.0"

    defaultConfig {
        minSdkVersion 14
        targetSdkVersion 16
    }
    sourceSets {
        test {
            java {
                include "/src/test/java"
            }
        }
    }
}

ext.androidAnnotationsVersion = '2.7.1'
ext.daggerVersion = '1.1.0'
configurations {
    apt
}

dependencies {
    apt "com.googlecode.androidannotations:androidannotations:${androidAnnotationsVersion}"
    apt "com.squareup.dagger:dagger-compiler:${daggerVersion}"
    compile 'com.android.support:support-v4:13.0.+'
    compile 'org.codehaus.jackson:jackson-mapper-asl:1.9.+'
    compile "com.googlecode.androidannotations:androidannotations-api:${androidAnnotationsVersion}"
    compile "com.squareup.dagger:dagger:${daggerVersion}"
    testCompile 'junit:junit:4.10'
    testCompile 'org.robolectric:robolectric:2.1.+'
    testCompile 'com.squareup:fest-android:1.0.+'
}

def aptOutput
afterEvaluate { project ->
    android.applicationVariants.each { variant ->
        aptOutput = file("${project.buildDir}/source/r/${variant.dirName}")
        println "****************************"
        println "variant: ${variant.name}"
        println "manifest:  ${variant.processResources.manifestFile}"
        println "aptOutput:  ${aptOutput}"
        println "****************************"

        variant.javaCompile.doFirst {
            println "*** compile doFirst ${variant.name}"
            aptOutput.mkdirs()

            aptOutput.eachFileRecurse FileType.FILES, {
                if (it.name.equals('R.java')) {
                    return
                }
                it.delete()
            }

            variant.javaCompile.options.compilerArgs += [
                    '-processorpath', configurations.apt.getAsPath(),
                    '-AandroidManifestFile=' + variant.processResources.manifestFile,
                    '-s', aptOutput
            ]
        }
    }
}