PKGBUILD

# Contributor: Praekon <[email protected]>
# Contributor: Arthur <[email protected]>
# Contributor: Jon Wiersma <[email protected]>
# Contributor: monty <linksoft [at] gmx [dot] de>
# Contributor: ed0c <alexandre.piel [at] mailoo [dot] com>
# Maintainer: Tom Moore <t.moore01 [at] gmail [dot] com>

#ALARM: moonman
#	- Using Synology arm package as the base
#	- changed start_pms contents for arm

buildarch=2

pkgname=plex-media-server
pkgver=0.9.11.16.958
pkgrel=1
_subver=80f1748
pkgdesc="Plex Media Server for Linux"
url='http://www.plexapp.com'
arch=('armv7h')
#_pkgarch="armv7"
license=('closed')
depends=('rsync' 'avahi')
replaces=('plexmediaserver')
conflicts=('plexmediaserver' 'plexmediaserver-plexpass')
backup=('etc/conf.d/plexmediaserver')
install='plexmediaserver.install'

source=("http://downloads.plexapp.com/plex-media-server/${pkgver}-${_subver}/PlexMediaServer-${pkgver}-${_subver}-arm7.spk"
        'plexmediaserver.conf.d'
        'plexmediaserver.service'
        "start_pms")

md5sums=('3e4013bc905d8c46de7155d3ae0bd865'
         '32cdd9f9de446f6646616a0077151726'
         '6601ebe6607cfb7dda9f3d77c1d043a9'
         'c4d158ae6f9a186e4553551d062febe3')

build() {
      mkdir ${srcdir}/plex
      cd ${srcdir}/plex
      tar xzf ../package.tgz
}

package() {
       mkdir -p "${pkgdir}"/opt/plexmediaserver
       mkdir -p "${pkgdir}"/usr/lib/systemd/system
       cp -r ${srcdir}/plex/* "${pkgdir}"/opt/plexmediaserver/

       install -Dm755 ${srcdir}/start_pms "${pkgdir}"/opt/plexmediaserver/
       install -Dm644 ${srcdir}/plexmediaserver.conf.d "${pkgdir}"/etc/conf.d/plexmediaserver
       install -Dm644 ${srcdir}/plexmediaserver.service "${pkgdir}"/usr/lib/systemd/system/plexmediaserver.service
}