Nyan Cat / Nyancodemon

//=======================================================
//=======================================================
// Created by DBThanatos ([email protected])
// Feel free to use it, but give the proper credits
//=======================================================
//=======================================================
Actor Nyancodemon : Cacodemon
{
	+NOPAIN
	-SOLID
	+THRUACTORS
	+NOTARGET
	+FLOATBOB
	states
	{
	Spawn:
		HEAD A 10 A_Look
		loop
	See:
		HEAD A 1 A_Wander
		TNT1 A 0 A_SpawnItemEx("RainbowTrail",-10,0,28,0,0,0,0,32)
		HEAD A 1
		TNT1 A 0 A_SpawnItemEx("RainbowTrail",-10,0,28,0,0,0,0,32)
		loop
	Pain:
		HEAD E 3
		HEAD E 3 A_Pain
		HEAD F 6
		goto See
	Death:
		HEAD G 8
		HEAD H 8 A_Scream
		HEAD IJ 8
		HEAD K 8 A_NoBlocking
		HEAD L -1 A_SetFloorClip
		stop
	Raise:
		HEAD L 8 A_UnSetFloorClip
		HEAD KJIHG 8
		goto See
  }
}


Actor RainbowTrail
{
	+NOINTERACTION
	States
	{
	Spawn:
		TNT1 A 0
		TNT1 A 0 A_SpawnItemEx("NyanRTRed",0,0,24,0,0,0,0,32)
		TNT1 A 0 A_SpawnItemEx("NyanRTOrange",0,0,16,0,0,0,0,32)
		TNT1 A 0 A_SpawnItemEx("NyanRTYellow",0,0,8,0,0,0,0,32)
		TNT1 A 0 A_SpawnItemEx("NyanRTGreen",0,0,0,0,0,0,0,32)
		TNT1 A 0 A_SpawnItemEx("NyanRTBlue",0,0,-8,0,0,0,0,32)
		TNT1 A 0 A_SpawnItemEx("NyanRTPurple",0,0,-16,0,0,0,0,32)
		TNT1 A 2
		Stop
	}
}

Actor NyanRTRed
{
	Renderstyle Add
	+NOINTERACTION
	Scale 0.8
	Translation "0:255=%[0,0,0]:[1,0,0]"
	States
	{
	Spawn:
		BAL1 AB 2 Bright A_FadeOut(0.03)
		Loop
	}
}

Actor NyanRTOrange : NyanRTRed
{	Translation "0:255=%[0,0,0]:[1,0.5,0.15]"	}
Actor NyanRTYellow : NyanRTRed
{	Translation "0:255=%[0,0,0]:[1,0.94,0]"	}
Actor NyanRTGreen : NyanRTRed
{	Translation "0:255=%[0,0,0]:[0.13,0.69,0.29]"	}
Actor NyanRTBlue : NyanRTRed
{	Translation "0:255=%[0,0,0]:[0,0.63,0.9]"	}
Actor NyanRTPurple : NyanRTRed
{	Translation "0:255=%[0,0,0]:[0.57,0.25,0.57]"	}