// Author: Kraz
// Description: Simple Mining
if not listexists 'Runebooks'
  createlist 'Runebooks'
endif
if not listexists 'Runes'
  createlist 'Runes'
endif
if list 'Runes' == 0
  pushlist 'Runes' 5
  pushlist 'Runes' 11
  pushlist 'Runes' 17
  pushlist 'Runes' 23
  pushlist 'Runes' 29
  pushlist 'Runes' 35
  pushlist 'Runes' 41
  pushlist 'Runes' 47
  pushlist 'Runes' 53
  pushlist 'Runes' 59
  pushlist 'Runes' 65
  pushlist 'Runes' 71
  pushlist 'Runes' 77
  pushlist 'Runes' 83
  pushlist 'Runes' 89
  pushlist 'Runes' 95
  // All runes have been mined, go to the next runebook
  poplist 'Runebooks' 'front'
endif
// Add all your mine runebooks serial to that list
if list 'Runebooks' == 0
  pushlist 'Runebooks' 0x400b9c26 //EDIT THIS USING OBJECT INSPECTOR AND SELECT A RUNEBOOK
  pushlist 'Runebooks' 0x400c0a68 //EDIT THIS USING OBJECT INSPECTOR AND SELECT A RUNEBOOK
  pushlist 'Runebooks' 0x41aa7665 //EDIT THIS USING OBJECT INSPECTOR AND SELECT A RUNEBOOK
endif
if not listexists 'Ores'
  createlist 'Ores'
  pushlist 'Ores' 0x19b7
  pushlist 'Ores' 0x19b8
  pushlist 'Ores' 0x19ba
  pushlist 'Ores' 0x19b9
endif
if not listexists 'Stones'
  createlist 'Stones'
  // Citrine
  pushlist 'Stones' 0xf15
  // Amber
  pushlist 'Stones' 0xf25
  // Emerald
  pushlist 'Stones' 0x3195
  // Star Sapphire
  pushlist 'Stones' 0xf21
  // Amethyst
  pushlist 'Stones' 0xf16
  // Ruby
  pushlist 'Stones' 0xf13
  // Diamond
  pushlist 'Stones' 0xf26
  // Sapphire
  pushlist 'Stones' 0xf19
  // Tourmaline
  pushlist 'Stones' 0xf2d
endif
if not @findalias 'Stock'
  promptalias 'Stock'
endif
if not @findobject 'Home Runebook'
  promptalias 'Home Runebook'
endif
if weight >= 390 or not @findtype 0xf39 0 'backpack'
  cast 'strength'
  pause 2000
  target! 'self'
  pause 3000
  cast 'recall'
  pause 3000
  target! 'Home Runebook'
  headmsg 'Check Shovels!'
  pause 1000
  if @injournal 'Insufficient mana' 'system'
    useskill 'Meditation'
    while mana != maxmana
      pause 500
    endwhile
  endif
  @clearjournal
  if @injournal 'More reagents' 'system' or @injournal 'Insufficient mana' 'system'
    clearjournal
    replay
    stop
  endif
  useobject! 'Stock'
  pause 1000
  for 0 to 'Stones'
    while @movetype Stones[] 'backpack' 'Stock'
      pause 1000
    endwhile
  endfor
  for 0 to 'Ores'
    while @findtype Ores[] 'any' 'backpack'
      useobject! 'found'
      waitfortarget 1000
      // Small forge 0xfb1
      // Elven forge 0x2dd8
      // Large forge 0x19a2
      targetground 0xfb1 'any' 2
      pause 200
      if @injournal 'not enough metal' 'system'
        moveitem 'found' 'Stock'
        pause 1000
        clearjournal
      endif
    endwhile
  endfor
  while @findtype 0x1bf2 'any' 'backpack'
    moveitem 'found' 'Stock'
    pause 1000
  endwhile
  if @counttype 0xf39 0x0 'backpack' < 2
    movetype 0xf39 'stock' 'backpack' 0 0 0 0x0 1
    pause 1000
  endif
  if @counttype 0xf7b 0x0 'backpack' < 10
    movetype 0xf7b 'stock' 'backpack' 0 0 0 0x0 15
    pause 1000
  endif
  if @counttype 0xf88 0x0 'backpack' < 10
    movetype 0xf88 'stock' 'backpack' 0 0 0 0x0 15
    pause 1000
  endif
  if @counttype 0xf7a 0x0 'backpack' < 10
    movetype 0xf7a 'stock' 'backpack' 0 0 0 0x0 15
    pause 1000
  endif
  if @counttype 0xf86 0x0 'backpack' < 10
    movetype 0xf86 'stock' 'backpack' 0 0 0 0x0 15
    pause 1000
  endif
else
  for 0 to 'Runes'
    useobject! Runebooks[0]
    waitforgump 0x554b87f3 15000
    replygump 0x554b87f3 Runes[]
    pause 3000
    if @injournal 'More reagents' 'system' or @injournal 'Insufficient mana' 'system'
      clearjournal
      continue
    endif
    poplist 'Runes' 'front'
    if @injournal 'location is blocked' 'system'
      clearjournal
      continue
    endif
    useskill 'hiding'
    if @findtype 0xf39 0 'backpack' and weight <= 389
      for 15
        if not usetype! 0xf39 or weight >= 390
          replay
          stop
        endif
        waitfortarget 1000
        targettileoffset -1 0 0
        pause 1000
        if @injournal 'there is no metal' 'system'
          clearjournal
          replay
          stop
        endif
      endfor
    else
      break
    endif
    pause 3000
  endfor
endif