Want more features on Pastebin? Sign Up, it's FREE!
Public Pastes

An Optimized Kosinski decompressor for 68k

By: vladikcomper on Nov 4th, 2013  |  syntax: Motorola 68000 HiSoft Dev  |  size: 4.31 KB  |  views: 396  |  expires: Never
download  |  raw  |  embed  |  report abuse  |  print  |  QR code  |  clone
Text below is selected. Please press Ctrl+C to copy to your clipboard. (⌘+C on Mac)
  1. ; ===========================================================================
  2. ; ---------------------------------------------------------------------------
  3. ; Kosinski decompression routine
  4. ;
  5. ; Created by vladikcomper
  6. ; Special thanks to flamewing and MarkeyJester
  7. ; ---------------------------------------------------------------------------
  8.  
  9. _Kos_RunBitStream macro
  10.         dbf     d2,@skip\@
  11.         moveq   #7,d2
  12.         move.b  d1,d0
  13.         swap    d3
  14.         bpl.s   @skip\@
  15.         move.b  (a0)+,d0                        ; get desc. bitfield
  16.         move.b  (a0)+,d1                        ;
  17.         move.b  (a4,d0.w),d0                    ; reload converted desc. bitfield from a LUT
  18.         move.b  (a4,d1.w),d1                    ;
  19. @skip\@
  20.         endm
  21. ; ---------------------------------------------------------------------------
  22.  
  23. KosDec:
  24.         moveq   #7,d7
  25.         moveq   #0,d0
  26.         moveq   #0,d1
  27.         lea     KosDec_ByteMap(pc),a4
  28.         move.b  (a0)+,d0                        ; get desc field low-byte
  29.         move.b  (a0)+,d1                        ; get desc field hi-byte
  30.         move.b  (a4,d0.w),d0                    ; reload converted desc. bitfield from a LUT
  31.         move.b  (a4,d1.w),d1                    ;
  32.         moveq   #7,d2                           ; set repeat count to 8
  33.         moveq   #-1,d3                          ; d3 will be desc field switcher
  34.         clr.w   d3                              ;
  35.         bra.s   KosDec_FetchNewCode
  36.  
  37. KosDec_FetchCodeLoop:
  38.         ; code 1 (Uncompressed byte)
  39.         _Kos_RunBitStream
  40.         move.b  (a0)+,(a1)+
  41.  
  42. KosDec_FetchNewCode:
  43.         add.b   d0,d0                           ; get a bit from the bitstream
  44.         bcs.s   KosDec_FetchCodeLoop            ; if code = 0, branch
  45.  
  46.         ; codes 00 and 01
  47.         _Kos_RunBitStream
  48.         moveq   #0,d4                           ; d4 will contain copy count
  49.         add.b   d0,d0                           ; get a bit from the bitstream
  50.         bcs.s   KosDec_Code_01
  51.  
  52.         ; code 00 (Dictionary ref. short)
  53.         _Kos_RunBitStream
  54.         add.b   d0,d0                           ; get a bit from the bitstream
  55.         addx.w  d4,d4
  56.         _Kos_RunBitStream
  57.         add.b   d0,d0                           ; get a bit from the bitstream
  58.         addx.w  d4,d4
  59.         _Kos_RunBitStream
  60.         moveq   #-1,d5
  61.         move.b  (a0)+,d5                        ; d5 = displacement
  62.  
  63. KosDec_StreamCopy:
  64.         lea     (a1,d5),a3
  65.         move.b  (a3)+,(a1)+                     ; do 1 extra copy (to compensate for +1 to copy counter)
  66.  
  67. KosDec_copy:
  68.         move.b  (a3)+,(a1)+
  69.         dbf     d4,KosDec_copy
  70.         bra.w   KosDec_FetchNewCode
  71. ; ---------------------------------------------------------------------------
  72. KosDec_Code_01:
  73.         ; code 01 (Dictionary ref. long / special)
  74.         _Kos_RunBitStream
  75.         move.b  (a0)+,d6                        ; d6 = %LLLLLLLL
  76.         move.b  (a0)+,d4                        ; d4 = %HHHHHCCC
  77.         moveq   #-1,d5
  78.         move.b  d4,d5                           ; d5 = %11111111 HHHHHCCC
  79.         lsl.w   #5,d5                           ; d5 = %111HHHHH CCC00000
  80.         move.b  d6,d5                           ; d5 = %111HHHHH LLLLLLLL
  81.         and.w   d7,d4                           ; d4 = %00000CCC
  82.         bne.s   KosDec_StreamCopy               ; if CCC=0, branch
  83.  
  84.         ; special mode (extended counter)
  85.         move.b  (a0)+,d4                        ; read cnt
  86.         beq.s   KosDec_Quit                     ; if cnt=0, quit decompression
  87.         subq.b  #1,d4
  88.         beq.w   KosDec_FetchNewCode             ; if cnt=1, fetch a new code
  89.  
  90.         lea     (a1,d5),a3
  91.         move.b  (a3)+,(a1)+                     ; do 1 extra copy (to compensate for +1 to copy counter)
  92.         move.w  d4,d6
  93.         not.w   d6
  94.         and.w   d7,d6
  95.         add.w   d6,d6
  96.         lsr.w   #3,d4
  97.         jmp     KosDec_largecopy(pc,d6.w)
  98.  
  99. KosDec_largecopy:
  100.         rept 8
  101.         move.b  (a3)+,(a1)+
  102.         endr
  103.         dbf     d4,KosDec_largecopy
  104.         bra.w   KosDec_FetchNewCode
  105.  
  106. KosDec_Quit:
  107.         rts
  108.  
  109. ; ---------------------------------------------------------------------------
  110. ; A look-up table to invert bits order in desc. field bytes
  111. ; ---------------------------------------------------------------------------
  112.  
  113. KosDec_ByteMap:
  114.         dc.b    $00,$80,$40,$C0,$20,$A0,$60,$E0,$10,$90,$50,$D0,$30,$B0,$70,$F0
  115.         dc.b    $08,$88,$48,$C8,$28,$A8,$68,$E8,$18,$98,$58,$D8,$38,$B8,$78,$F8
  116.         dc.b    $04,$84,$44,$C4,$24,$A4,$64,$E4,$14,$94,$54,$D4,$34,$B4,$74,$F4
  117.         dc.b    $0C,$8C,$4C,$CC,$2C,$AC,$6C,$EC,$1C,$9C,$5C,$DC,$3C,$BC,$7C,$FC
  118.         dc.b    $02,$82,$42,$C2,$22,$A2,$62,$E2,$12,$92,$52,$D2,$32,$B2,$72,$F2
  119.         dc.b    $0A,$8A,$4A,$CA,$2A,$AA,$6A,$EA,$1A,$9A,$5A,$DA,$3A,$BA,$7A,$FA
  120.         dc.b    $06,$86,$46,$C6,$26,$A6,$66,$E6,$16,$96,$56,$D6,$36,$B6,$76,$F6
  121.         dc.b    $0E,$8E,$4E,$CE,$2E,$AE,$6E,$EE,$1E,$9E,$5E,$DE,$3E,$BE,$7E,$FE
  122.         dc.b    $01,$81,$41,$C1,$21,$A1,$61,$E1,$11,$91,$51,$D1,$31,$B1,$71,$F1
  123.         dc.b    $09,$89,$49,$C9,$29,$A9,$69,$E9,$19,$99,$59,$D9,$39,$B9,$79,$F9
  124.         dc.b    $05,$85,$45,$C5,$25,$A5,$65,$E5,$15,$95,$55,$D5,$35,$B5,$75,$F5
  125.         dc.b    $0D,$8D,$4D,$CD,$2D,$AD,$6D,$ED,$1D,$9D,$5D,$DD,$3D,$BD,$7D,$FD
  126.         dc.b    $03,$83,$43,$C3,$23,$A3,$63,$E3,$13,$93,$53,$D3,$33,$B3,$73,$F3
  127.         dc.b    $0B,$8B,$4B,$CB,$2B,$AB,$6B,$EB,$1B,$9B,$5B,$DB,$3B,$BB,$7B,$FB
  128.         dc.b    $07,$87,$47,$C7,$27,$A7,$67,$E7,$17,$97,$57,$D7,$37,$B7,$77,$F7
  129.         dc.b    $0F,$8F,$4F,$CF,$2F,$AF,$6F,$EF,$1F,$9F,$5F,$DF,$3F,$BF,$7F,$FF
  130.  
  131. ; ===========================================================================
clone this paste RAW Paste Data