# Contributor: graysky <graysky AT archlinux DOT us>
# Contributor: jiribb <[email protected]>
# Contributor: David Spicer <azleifel at googlemail dot com>
# Contributor: Andrew Brouwers
# Maintainer: Stefan Husmann <[email protected]>
# Maintainer: David Spicer <azleifel at googlemail dot com>

pkgbase=handbrake-svn
pkgname=handbrake-svn
true && pkgname=('handbrake-svn' 'handbrake-svn-cli')
pkgver=3654
pkgrel=1
arch=('i686' 'x86_64')
url="http://handbrake.fr/"
license=('GPL')
depends=('bzip2' 'gcc-libs' 'gstreamer0.10-base' 'libnotify' 'hicolor-icon-theme')
makedepends=('intltool' 'python2' 'gettext' 'subversion' 'wget' 'yasm')
conflicts=('handbrake-gtk' 'handbrake')
provides=('handbrake-gtk' 'handbrake')

_svntrunk=svn://svn.handbrake.fr/HandBrake/trunk
_svnmod=hb-trunk

build() {
  cd ${srcdir}

  msg "Connecting to ${_svnmod} SVN server...."
  if [ -d ${_svnmod}/.svn ]; then
    ( cd ${_svnmod} && svn up -r $pkgver )
  else
    svn co ${_svntrunk} --config-dir ./ -r $pkgver ${_svnmod}
  fi
  msg "SVN checkout done or server timeout"
  msg "Starting make..."

  # Create build directory and copy source
  [ -d ${srcdir}/${_svnmod}-build ] && rm -rf ${srcdir}/${_svnmod}-build
  cp -r ${srcdir}/${_svnmod} ${srcdir}/${_svnmod}-build

  # Create build-specific temporary directory
  # (ffmpeg needs a temporary directory that is not set noexec)
  [ -d ${srcdir}/tmp ] && rm -rf ${srcdir}/tmp
  install -d -m755 ${srcdir}/tmp

  #
  # Build
  #

  cd ${srcdir}/${_svnmod}-build

  # Substitutions for python2
  sed -i -e 's|python $(srcdir)|python2 $(srcdir)|' gtk/src/Makefile.am
  sed -i -e '1c#! /usr/bin/python2' gtk/src/makedeps.py
  sed -i -e '1c#! /usr/bin/python2' gtk/src/create_resources.py
  sed -i -e '1c#! /usr/bin/python2' gtk/src/quotestring.py

  LDFLAGS=$(echo $LDFLAGS | sed "s/-Wl,--as-needed//")
  # Use --disable-gtk-update-checks because we don't want to download gui updates
  ./configure --force --verbose --prefix=/usr --disable-gtk-update-checks --launch-jobs=0

  cd ${srcdir}/${_svnmod}-build/build
  TMPDIR=${srcdir}/tmp make
}

package_handbrake-svn() {
  pkgdesc="Multiplatform, multithreaded DVD to MPEG-4/H264/Theora converter (GTK GUI)"
  install=${pkgname}.install

  cd ${srcdir}/${_svnmod}-build/build
  make DESTDIR="${pkgdir}" install

  # Delete icon-theme.cache (is rebuilt on install)
  rm -f ${pkgdir}/usr/share/icons/hicolor/icon-theme.cache
}

package_handbrake-svn-cli() {
  pkgdesc="Multiplatform, multithreaded DVD to MPEG-4/H264/Theora converter (CLI version)"
  depends=('bzip2' 'gcc-libs' 'zlib')

  cd ${srcdir}/${_svnmod}-build/build
  install -D -m755 HandBrakeCLI "${pkgdir}/usr/bin/HandBrakeCLI"

  # Remove build directories
  rm -rf ${srcdir}/tmp
  rm -rf ${srcdir}/${_svnmod}-build
}