FCM#93 - Chicken Coop

//Celsius to Fahrenheit conversion
double Fahrenheit(double celsius)
{
    return 1.8 * celsius + 32;
}

// fast integer version with rounding
//int Celcius2Fahrenheit(int celcius)
//{
//  return (celsius * 18 + 5)/10 + 32;
//}


//Celsius to Kelvin conversion
double Kelvin(double celsius)
{
    return celsius + 273.15;
}

// dewPoint function NOAA
// reference (1) : http://wahiduddin.net/calc/density_algorithms.htm
// reference (2) : http://www.colorado.edu/geography/weather_station/Geog_site/about.htm
//
double dewPoint(double celsius, double humidity)
{
    // (1) Saturation Vapor Pressure = ESGG(T)
    double RATIO = 373.15 / (273.15 + celsius);
    double RHS = -7.90298 * (RATIO - 1);
    RHS += 5.02808 * log10(RATIO);
    RHS += -1.3816e-7 * (pow(10, (11.344 * (1 - 1/RATIO ))) - 1) ;
    RHS += 8.1328e-3 * (pow(10, (-3.49149 * (RATIO - 1))) - 1) ;
    RHS += log10(1013.246);

        // factor -3 is to adjust units - Vapor Pressure SVP * humidity
    double VP = pow(10, RHS - 3) * humidity;

        // (2) DEWPOINT = F(Vapor Pressure)
    double T = log(VP/0.61078);   // temp var
    return (241.88 * T) / (17.558 - T);
}

// delta max = 0.6544 wrt dewPoint()
// 6.9 x faster than dewPoint()
// reference: http://en.wikipedia.org/wiki/Dew_point
double dewPointFast(double celsius, double humidity)
{
    double a = 17.271;
    double b = 237.7;
    double temp = (a * celsius) / (b + celsius) + log(humidity*0.01);
    double Td = (b * temp) / (a - temp);
    return Td;
}

// include the servo library
#include <Servo.h>
#include <LiquidCrystal.h>
#include <dht11.h>

Servo myServo;      // create a servo object

LiquidCrystal lcd(12, 11, 5, 4, 3, 2);

dht11 DHT11;
#define DHT11PIN 6

int light;          // LDR value - how light/dark is it

int sunUp=790;      // LDR setting for daytime
int sunDown=400;    // LDR setting for night time

int reverse=0;      // only used in the map funtion to close door
int coopOpen=0;     // only really used in door opening command
int openDoor=1;     // open coop
int closeTime=3000; // 2secs to close door

int coopDanger=8;   // Red LED pin - signifies coop open
int coopSafe=7;     // Green LED pin - signifies coop closed

//  ----

void setup() {
  myServo.attach(9); // attaches the servo on pin 9 to the servo object

  pinMode(coopDanger,OUTPUT);  // Red LED pin is an output
  pinMode(coopSafe,OUTPUT);    // Green LED pin is an output

  digitalWrite(coopDanger, HIGH);  // Set Red LED off on start
  digitalWrite(coopSafe, LOW);     // Set Green LED on at start (coop is closed on start)

  lcd.begin(16, 2);

  Serial.begin(9600);              // open a serial connection to your computer
}

void loop() {
  light=analogRead(A1);           // read LDR

  int chk = DHT11.read(DHT11PIN);

//  CLOSE COOP
  if (light < sunDown && coopOpen==1){  // sun is down and coop is open then:
      myServo.attach(9);                // attach servo
      myServo.write(openDoor);          // close coop
      digitalWrite(coopDanger, LOW);    // red LED off
      digitalWrite(coopSafe, HIGH);     // light green LED
      delay(closeTime);                 // delay while moving servo
      myServo.detach();                 // turn off servo
      coopOpen=0;                       // set open to false
  }

//  OPEN COOP
  if (light > sunUp && coopOpen==0){        // sun is up and coop is closed then:
      myServo.attach(9);                    // attach servo
      reverse=map(openDoor,0,1023,180,0);   // map 180-1 to reverse servo
      myServo.write(reverse);               // close coop
      digitalWrite(coopDanger, HIGH);       // red LED off
      digitalWrite(coopSafe, LOW);          // light green LED
      delay(closeTime);                     // delay while moving servo
      myServo.detach();                     // stop servo
      coopOpen=1;                           // set open to true
  }

  Serial.print("Read sensor: ");
  switch (chk)
  {
    case DHTLIB_OK:
        Serial.println("OK");
        break;
    case DHTLIB_ERROR_CHECKSUM:
        Serial.println("Checksum error");
        break;
    case DHTLIB_ERROR_TIMEOUT:
        Serial.println("Time out error");
        break;
    default:
        Serial.println("Unknown error");
        break;
  }

  Serial.print("Humidity (%): ");
  Serial.println((float)DHT11.humidity, 2);

  Serial.print("Temperature (°C): ");
  Serial.println((float)DHT11.temperature, 2);

  Serial.print("Temperature (°F): ");
  Serial.println(Fahrenheit(DHT11.temperature), 2);

  Serial.print("Temperature (°K): ");
  Serial.println(Kelvin(DHT11.temperature), 2);

  Serial.print("Dew Point (°C): ");
  Serial.println(dewPoint(DHT11.temperature, DHT11.humidity));

  Serial.print("Dew PointFast (°C): ");
  Serial.println(dewPointFast(DHT11.temperature, DHT11.humidity));

  // set the cursor to column 0, line 0
  lcd.setCursor(0, 0);
  lcd.print("Humidity (%): ");
  lcd.print(DHT11.humidity);
  // set the cursor to column 0, line 1
  // (note: line 1 is the second row, since counting begins with 0):
  lcd.setCursor(0, 1);
  lcd.print("Temp. ('C): ");
  lcd.print(DHT11.temperature);


// print light level
  Serial.print(", light: ");
  Serial.println(light);

  delay(3000);

}