EO+ Heroes Call War Games

Main
{
	questname	"Heroes Call (Group)"
	version	1.0
}
State Begin
{
	action	ShowHint("Only a Group Leader over level 20 can start the Heroes Call War Games!");
	if	IsLeader() goto CheckLeader1
	elseif	InParty() goto GetLeader1
	else goto GetParty1
}
State GetLeader1
{
	action	ShowHint("You will need to get your Group Leader to talk to me.");
	action	Reset();
}
State GetParty1
{
	action	ShowHint("You need to be in a group for the Heroes Call War Games.");
	action	Reset();
}
State GetLevel1
{
	action	ShowHint("The Group Leader becomes your teams General and must be over level 20.");
	action	Reset();
}
State CheckLeader1
{
	if	IsLevel(20) goto Begin1
	else goto GetLevel1
}
State NoFunds1
{
	action	ShowHint("Insufficient funds.");
	action	Reset();
}
State Begin1
{
	desc	"Heroes Call (Group)"

	action	AddNpcText(#,"Welcome to the Heroes Call War Games!");
	action	AddNpcText(#,"When you and your group are ready, I can start the Heroes Call!");
	action	AddNpcText(#,"Each attempt will cost 2000 Coins, though the rewards you can acquire inside are considerable!");
	action	AddNpcText(#,"If your fail and are unable to complete it, you must speak to the Reset NPC at the entrance to start it again.");
	action	AddNpcText(#,"It is important that you brief your group on what to do, you will be your teams General!");
	action	AddNpcText(#,"Once we begin, your whole team will be summoned to the battleground, to win, you must defeat 5 of the opposing teams Captains, then defeat the opposing teams General.");
	action	AddNpcText(#,"Your team will have to fight its way through the opposing teams forces to complete the objectives, working as a team is a good idea!");
	action	AddNpcText(#,"If you are new to the Heroes Call War Games, take this time now to explain the rules to your team members...");

	action	AddNpcInput(#,1,"We are ready.");
	action	AddNpcInput(#,2,"We are not ready.");

	rule	InputNpc(1) goto ReadyCheck
	rule	InputNpc(2) goto Reset
}
State Reset
{
	action	Reset();
}
State ReadyCheck
{
	desc	"HC - Kill Captains"
	action	AddNpcText(#,"Everything is ready to go! You will now be charged 2000 Coins and your team will be mobilized for battle.");

	action	AddNpcInput(#,1,"Begin.");
	rule	InputNpc(1) goto PayFee1
}
State PayFee1
{
	if	GotItems(1,2000) goto PayFee2
	else	SetState("NoFunds1");
}
State PayFee2
{
	action	RemoveItem(1,2000);
	action	PlaySound(5);
	action	ShowHint("Heroes Call War Games has begun!");
	action	SetState("KillCaptains1");
}
State KillCaptains1
{
	action	SetCoord(48,17,79);
	action	SpawnNpc(294,2);
	action	SetCoord(48,13,73);
	action	SpawnNpc(295,5);
	action	SetCoord(48,28,86);
	action	SpawnNpc(295,5);
	action	SetState("KillCaptains2");
}
State KillCaptains2
{
	action	SetCoord(48,79,18);
	action	SpawnNpc(294,2);
	action	SetCoord(48,69,12);
	action	SpawnNpc(295,5);
	action	SetCoord(48,87,28);
	action	SpawnNpc(295,5);
	action	SetState("KillCaptains3");
}
State KillCaptains3
{
	action	SetCoord(48,71,73);
	action	SpawnNpc(294,2);
	action	SetCoord(48,63,78);
	action	SpawnNpc(295,3);
	action	SetCoord(48,77,63);
	action	SpawnNpc(295,3);
	action	SetState("KillCaptains4");
}
State KillCaptains4
{
	action	SetCoord(48,42,42);
	action	SpawnNpc(295,5);
	action	SetCoord(48,32,45);
	action	SpawnNpc(293,5);
	action	SetCoord(48,47,32);
	action	SpawnNpc(293,5);
	action	SetState("SummonTeam1");
}
State SummonTeam1
{
	action	SetCoord(48,15,15);
	action	SetState("SummonTeam2");
}
State SummonTeam2
{
	action	PartyWarp(48,15,15);
	action	SetState("KillCaptains5");
}
State KillCaptains5
{
	desc	"HC - Kill Captains"
	action	ShowHint("Heroes Call War Game has begun!");
	rule	KilledNpcs(294,5) goto SummonTeam3
}
State SummonTeam3
{
	action	SetCoord(48,15,15);
	action	SetState("SummonTeam4");
}
State SummonTeam4
{
	action	PartyWarp(48,15,15);
	action	SetState("KillGeneral1");
}
State KillGeneral1
{
	action	SetCoord(48,44,44);
	action	SpawnNpc(296,1);
	action	SetCoord(48,15,15);
	action	SetState("KillGeneral2");
}
State KillGeneral2
{
	desc	"HC - Kill General"
	action	ShowHint("The enemy General has come on to the battlefield!");
	action	ShowHint("Kill the enemy General!");
	rule	KilledNpcs(296,1) goto Win1
}
State Win1
{
	action	ShowHint("Your team has defeated the opposing team!");
	action	ShowHint("Rewarding all party members now, well done!");
	action	GivePartyItem(1,2000);
	action	SetState("Reset");
}