Antelle's AutoHotKey file

; Antelle's AutoHotKey file
; Adds Mac shortcuts to Windows :p

; #InstallKeybdHook     ; keys testing
#SingleInstance, Force
#MaxHotkeysPerInterval 100500

; === mouse ===
WheelUp::
Send {WheelDown}
Return

WheelDown::
Send {WheelUp}
Return

WheelRight::
Send {WheelLeft}
Return

WheelLeft::
Send {WheelRight}
Return

LWin & LButton::
Send ^{LButton}
Return

; === general ===
#c::send ^{sc02e}     ; copy
#v::send ^{sc02f}     ; paste
#x::send ^{sc02d}     ; cut
#a::send ^{sc01e}     ; select all
#s::send ^{sc01f}     ; save
#z::send ^{sc02c}     ; undo
#o::send ^{sc018}     ; open
#n::send ^{sc031}     ; new
#+z::send ^{sc015}    ; redo
#w::send ^{f4}        ; close
#q::send !{f4}        ; quit
#t::send ^{sc014}     ; new tab
#f::send ^{sc021}     ; find
#+f::send ^+{sc021}   ; find
#g::send ^{sc022}     ; next find
#+g::send ^+{sc022}   ; prev find
#r::send ^{sc013}     ; reload
#+d::send ^+{sc020}   ; duplicate
#i::send !{Enter}     ; properties (get info)
#m::send #{Down}      ; minimize
!#m::send #d          ; minimize all
#h::send #{Down}      ; minimize (hide)
LWin & NumpadAdd::send ^{NumpadAdd} ; +
LWin & NumpadSub::send ^- ; -
LWin & -::send ^-         ; -
LWin & Tab::AltTab                  ; alt-tab
+Delete::send {Delete}              ; disable shift-del
#d::return                          ; disable win-d
NumLock::return                     ; disable numlock
Alt & Backspace::send ^+{Left}{Delete}      ; delete word to left
Alt & Delete::send ^+{Right}{Delete}        ; delete word to right
#Backspace::send +{Home}{Delete}    ; delete to home
#Delete::send +{End}{Delete}        ; delete to end
*f13::send {Blind}{PrintScreen}     ; F13 -> print screen
*f15::send {Blind}{Break}           ; F15 -> break
#[::send {Browser_Back}             ; back
#]::send {Browser_Forward}          ; forward

; === layout ===
CapsLock::
    send, {Alt Down}{Shift Down}{Shift Up}{Alt Up}
    ; run c:\Projects\CapsLedFromLayout\Release\CapsLedFromLayout.exe
return

; === file navigation ===
#Up::send ^{Home}           ; file home
+#Up::send +^{Home}         ; select to file home
#Down::send ^{End}          ; file end
+#Down::send +^{End}        ; select to file end
#Left::send {home}          ; home
+#Left::send +{home}{esc}   ; select to home
#Right::send {end}          ; end
+#Right::send +{end}{esc}   ; select to end
!Left::send ^{left}         ; alt-left
!+Left::send ^+{left}       ; alt-shift-left
!Right::send ^{right}       ; alt-right
!+Right::send ^+{right}     ; alt-shift-right

; === total commander ===
#+e::send {f4}              ; edit

; === sublime text ===
#b::send ^{sc030}           ; build
#+p::send ^+{sc019}         ; commands list

; === extra ===
; sleep computer
#f19::
    DllCall("PowrProf\SetSuspendState", "int", 0, "int", 0, "int", 0)
return

; lock computer
f16::
    Run rundll32.exe user32.dll`,LockWorkStation
return

; options
#,::send ^!+o               ; options remapping

; disable start key
LWin::return
RWin::return

; cmd+space (spotlight search)
RWin & Space::send ^{esc}
LWin & Space::send ^{esc}

; resharper navigation
#\::send !\                 ; Search Member in File
#+t::send !+{sc014}         ; Open symbol

; === apps ===
#!^b::
    SetTitleMatchMode 2
    IfWinExist `Google Chrome`
    {
        WinActivate
    }
    else
    {
        run %userprofile%\AppData\Local\Google\Chrome\Application\chrome.exe
        WinWait `Google Chrome`
        WinActivate
    }
return

#!^e::
    run `c:\Soft\SublimeText\sublime_text.exe`
return

#!^l::
    SetTitleMatchMode 2
    IfWinExist `Total Commander`
    {
        WinActivate
    }
    else
    {
        run `c:\Soft\Total Commander\TotalCmd.exe`
        WinWait `Total Commander`
        WinActivate
    }
return

#!^k::
    SetTitleMatchMode 2
    IfWinExist `1Password`
    {
        WinActivate
    }
    else
    {
        run `c:\Program Files (x86)\1Password\1Password.exe`
        WinWait `1Password`
        WinActivate
    }
return

#!^t::
    run C:\Experiments\Console2\Console.exe
return

#!^f::
    send #e
return

#!^,::
    run control
return