AE2 Meteors Suck Minetweaker Script

//aliases
val iron = <minecraft:iron_ingot>;
val gold = <minecraft:gold_ingot>;
val redstone = <minecraft:redstone>;
val nether_quartz = <minecraft:quartz>;
val diamond = <minecraft:diamond>;

val silicon = <ore:itemSilicon>;

val certus_quartz = <appliedenergistics2:item.ItemMultiMaterial:0>;
val charged_quartz = <appliedenergistics2:item.ItemMultiMaterial:1>;
val fluix_crystal = <appliedenergistics2:item.ItemMultiMaterial:7>;

val circuit_quartz = <appliedenergistics2:item.ItemMultiMaterial:16>;
val circuit_diamond = <appliedenergistics2:item.ItemMultiMaterial:17>;
val circuit_gold = <appliedenergistics2:item.ItemMultiMaterial:18>;

val proc_gold = <appliedenergistics2:item.ItemMultiMaterial:22>;
val proc_quartz = <appliedenergistics2:item.ItemMultiMaterial:23>;
val proc_diamond = <appliedenergistics2:item.ItemMultiMaterial:24>;


//circuit recipes
recipes.addShaped(circuit_gold,
   [[redstone, silicon, redstone],
        [  iron,    gold,     iron      ],
        [redstone, silicon, redstone]]);


recipes.addShaped(circuit_diamond,
   [[redstone, silicon, redstone],
        [  iron,   diamond,   iron      ],
        [redstone, silicon, redstone]]);


recipes.addShaped(circuit_quartz,
   [[redstone, silicon, redstone],
        [ iron, charged_quartz, iron],
        [redstone, silicon, redstone]]);


//circuit to processor smelting recipes
furnace.addRecipe(proc_gold, circuit_gold);
furnace.addRecipe(proc_quartz, circuit_quartz);
furnace.addRecipe(proc_diamond, circuit_diamond);


//fluix crystal
recipes.addShapeless(fluix_crystal, [certus_quartz, nether_quartz, redstone]);