Custom Quits mIRC

menu * {
  Custom Quits
  .Quit: quit
  .-
  .Quit List: quitlist
}
alias quitlist { dialog -m quits quits }
alias quit {
  if ($isfile(quits.txt) && ($lines(quits.txt) >= 1)) {
    var %total $lines(quits.txt)
    !quit Random Quit: $read(quits.txt,$rand(1,%total))
  }
  else { !quit $me is using "Random Quit" by Savage_CL! }
}
dialog quits {
  title "Custom Quits"
  size -1 -1 210 116
  option dbu
  text "Custom Quits by Savage_CL!",        1, 3 5 209 8, center
  list                    34, 61 17 145 95, size
  button "Add",           35, 10 20 45 12
  button "Edit",          36, 10 35 45 12
  button "Delete",        37, 10 50 45 12
  button "Up",            38, 10 65 21 12
  button "Down",          39, 34 65 21 12
  button "Notepad",       46, 10 80 45 12
}
on 1:dialog:quits:init:0:{
  $iif($isfile(quits.txt),loadbuf -o quits 34 quits.txt)
}
;add button (tab 2)
on 1:dialog:quits:sclick:35: {
  write quits.txt $input(New Quit Message?,eo,Custom Quits)
  did -r quits 34
  loadbuf -o quits 34 quits.txt
}

;edit button (tab 2)
on 1:dialog:quits:sclick:36: {
  if ($did(quits,34).sel != 0) {
    write -l $+ $didwm(quits,34,$did(quits,34).seltext) quits.txt $input(Edit:,eo,Custom Quits,$did(quits,34).seltext)
    did -r quits 34
    loadbuf -o quits 34 quits.txt
  }
}
;delete button (tab 2)
on 1:dialog:quits:sclick:37: {
  var %tempselline $did(quits,34).sel
  if (%tempselline != 0) {
    write -dl $+ $did(quits,34).sel quits.txt
    did -r quits 34
    loadbuf -o quits 34 quits.txt
    did -c quits 34 %tempselline
  }
}

;up/down buttons
on 1:dialog:quits:sclick:38,39: {
  var %mSel = $did(quits, 34).sel, %mText = $did(quits, 34).seltext, %op = $iif($did == 38, -, +), %nSel = $calc(%mSel %op 1)
  var %sText = $did(quits, 34, %nSel).text
  if (%nSel > 0 && %nSel < $calc(1+$did(quits, 34).lines)) {
    did -oc quits 34 %nSel %mText
    did -o quits 34 %mSel %sText
  }
  savebuf -o quits 34 quits.txt
}

;notepad button (tab 2)
on 1:dialog:quits:sclick:46: {
  did -r quits 34
  run quits.txt
  $iif($input(Please click ok when you are done editing!,o,Custom Quits),loadbuf -o quits 34 quits.txt)
}