lv2-svn

# Maintainer:  prettyvanilla <prettyvanilla@posteo.at>
# Contributor: SpepS <dreamspepser at yahoo dot it>

pkgname=lv2-svn
pkgver=1.8.1.r911
pkgrel=1
pkgdesc="Successor to the LADSPA audio plug-in standard"
arch=('any')
url="http://lv2plug.in"
license=('LGPL' 'custom')
makedepends=('subversion' 'python')
optdepends=('python: LV2 specification generator')
provides=('lv2' 'lv2core')
conflicts=('lv2' 'lv2core')
replaces=('lv2core')

_svnname=lv2
source=("${_svnname}::svn+http://lv2plug.in/repo/trunk")
md5sums=('SKIP')

pkgver() {
  cd "${srcdir}/${_svnname}"
  local rel=`grep "^VERSION" wscript | cut -d "'" -f 2`
  local ver="$(svnversion)"
  printf "%s.r%s" "${rel}" "${ver//[[:alpha:]]}"
}

build() {
  cd "${srcdir}/${_svnname}"

  python waf configure --prefix=/usr \
                       --no-plugins

  python waf
}

package() {
  cd "${srcdir}/${_svnname}"
  python waf install --destdir="${pkgdir}"

  install -Dm644 COPYING \ "${pkgdir}/usr/share/licenses/${_svnname}/COPYING"
}