DDComb

### ONLY FOR PROGRESSIVE VIDEO or Field Based
### Based on Didée's script
### 2016.11.18 mod
Function DDComb(clip c, float "band", bool "static", bool "strong")
{
  band     = default(band,0)
  static   = default(static,false)
  strong   = default(strong,false)
  c
  borders = bicubicresize(width()/2,height()/2).bicubicresize(width()+8,height())
  stackhorizontal(borders.crop(0,0,4,0),last,borders.crop(width()+4,0,0,0))

  o=last ox=o.width() oy=o.height()

  clean1  = c.IsFieldBased() ? o.vinverse2() : o.separatefields().vinverse2().weave()

  D1      = mt_makediff(o,clean1)
  D8      = D1.bicubicresize(ox/2-72,oy).blur(1,0).bicubicresize(ox,oy,1,0)
  D9      = mt_lutxy(D1,D8,"x 128 - y 128 - * 0 < 128 x 128 - abs y 128 - abs < x y ? ?")
  clean1a = clean1.mt_adddiff(D9,U=2,V=2)
  clean1b = clean1a.frfun7(1.01,8,1)
  clean1b = c.IsFieldBased() && !(clean1b.IsFieldBased()) ? c.getparity() ? clean1b.AssumeBFF().AssumeFieldBased().AssumeTFF() : clean1b.AssumeTFF().AssumeFieldBased().AssumeBFF() : clean1b

  allD    = mt_makediff(o,clean1b,u=128,v=128)
  shrpD   = mt_makediff(clean1b,clean1b.removegrain(20))
  DD      = shrpD.repair(allD,13,0).mt_lutxy(shrpD,"x 128 - y 128 - * 0 < 128 x 128 - abs y 128 - abs < x y ? ?")
  clean1b = strong ? sBlackerPixel(o=clean1b, filtered=clean1a.Blur(1,0).Blur(1,c.IsFieldBased() ? 0 : 1)) : clean1b
  clean1c = clean1b.mt_lutxy(clean1a,"x 3 + y < x 2 + x y < x 1 + x 3 - y > x 2 - x y > x 1 - x ? ? ? ?",U=2,V=2)
                \.mt_adddiff(c.IsFieldBased() ? DD.sbrV() : DD.sbr(),U=2,V=2)

  clean1c = clean1c.crop(4,0,-4,0,true)
  clean2c = static ? clean1c.IsFieldBased() ? clean1c.weave() : clean1c : nop()
  clean1d = static ? clean2c.tcomb(mode=0).checkmate(tthr2=0) : nop()
  clean1d = static ? clean1c.IsFieldBased() ? clean1d.separatefields() : clean1d : nop()
  clean1m = static ? mt_lutxy(clean1d,clean1c,"x y - 2 - 0 > 255 y x - 2 - 0 > 255 0 ? ?") : nop()
  clean1c = static ? mt_merge(clean1c,clean1d,clean1m,U=2,V=2) : clean1c
  output  = band != 0 ? clean1c.gradfun3(thr=band,smode=2) : clean1c
  return output
  #--- end of script ---#
}
#######################################################

#--- Helper functions below ---#

function Vinverse2(clip clp, float "sstr", int "amnt", int "uv")
{
  uv   = default(uv,3)
  sstr = default(sstr,2.7)
  amnt = default(amnt,255)
  uv2  = (uv==2) ? 1 : uv
  STR  = string(sstr)
  AMN  = string(amnt)
  vblur  = clp.sbrV()
  vblurD = mt_MakeDiff(clp,vblur,U=uv2,V=uv2)
  Vshrp  = mt_LutXY(vblur,vblur.mt_convolution("1","1 2 1"),expr="x x y - "+STR+" * +",U=uv2,V=uv2)
  VshrpD = mt_MakeDiff(Vshrp,vblur,U=uv2,V=uv2)
  VlimD  = mt_LutXY(VshrpD,VblurD,expr="x 128 - y 128 - * 0 < x 128 - abs y 128 - abs < x y ? 128 - 0.25 * 128 + x 128 - abs y 128 - abs < x y ? ?",U=uv2,V=uv2)
  mt_AddDiff(Vblur,VlimD,U=uv,V=uv)
  (amnt>254) ? last : (amnt==0) ? clp : mt_LutXY(clp,last,expr="x "+AMN+" + y < x "+AMN+" + x "+AMN+" - y > x "+AMN+" - y ? ?",U=uv,V=uv)
  return(last)
}

function sbrV(clip o)
{
  rg11=o.mt_convolution("1","1 2 1")
  rg11D=mt_makediff(o,rg11)
  rg11DD=mt_makediff(rg11D,rg11D.mt_convolution("1","1 2 1")).mt_lutxy(rg11D,"x 128 - y 128 - * 0 < 128 x 128 - abs y 128 - abs < x y ? ?")
  o.mt_makediff(rg11DD,U=2,V=2)
}


# sBlackerPixel by A.SONY, for repairing DeCrawled and dehaloed clip

function sBlackerPixel(clip "o", clip "filtered", int "maxdiff", int "thr", bool "linflate")
{
maxdiff = default(maxdiff,   32)
thr     = default(thr,       40)
linflate= default(linflate,true)
maxdiff2=maxdiff*3/2

linflate ? Mt_Merge(o,filtered,o.mt_lutxy(filtered,"y "+string(thr)+" > x y > & x y - "+string(maxdiff)+" < 255 x y - "+string(maxdiff2)+" < ? 255 255 "+string(maxdiff2)+" / x y - * - 0 ? 0 ?").mt_inflate(155,155),U=2,V=2) : \
           o.mt_lutxy(filtered,"x y > y "+string(thr)+" > & x y - "+string(maxdiff)+" < & y x ?",U=2,V=2)
}