;IRcap8 551ad36a723469c214def9c7fc623db3


; IMPORTANTE !!! ESTE ARCHIVO TIENE QUE IR CARGADO EN REMOTES, NO EN ALIAS!!!
; PARA QUE FUNCIONE CORRECTAMENTE, DEBE ESTAR PUESTO ARRIBA DE TODOS LOS DEMÁS ARCHIVOS
; (ESTO LO ACOMODAN DESDE EL MENÚ FILE, ORDER..... DESDE AHÍ LO SUBEN DE POSICIÓN PARA QUE QUEDE
; PRIMERO EN LA LISTA DE REMOTES)





; FUNCIONES
;
;               /ban.nick nick   Banear un nick en la sala (puede estar en la sala o no)
;               /ban.id nick      Banear la ID de un nick (puede estar en la sala o no)
;               /ban.ip nick      Banea el la ip (Host) de un usuario (puede estar en la sala o no)
;               /unban nick      Quita todos los banes que estén afectando a un nick (puede estar en la sala o no)





; Otras funciones, SIMILARES a las que están acostumbrados a usar en el bot, pero sin ! ni . adelante
; Tienen que tener el @ puesto para que funcione esto

; BAN nick             (Banea a un usuario)
; KB nick motivo     (Banea y kickea a un usurio)
; KBN nick              (Banea y kickea por nick inapropiado)
; KICK nick motivo  (Kickea a un usuario)

; estas funciones también admiten motivos rápidos, como en el bot. Se los detallo abajo:


; MOTIVOS RAPIDOS
;  a = agresiones / faltas de respeto
;  s = sexo / busquedas sexuales
;  t = tematica inapropiada
; d = datos de contacto
;  l  = lenguaje inapropiado
; b  = busquedas no acordes al canal
; r  = repeticiones

; (SI no ponen ningún motivo, sale el genérico "Comportamiento inadecuado en la sala")



; #           TECLAS RAPIDAS DE FUNCION

; F1  Expulsa por nick inapropiado (Ban al nick)
; F2  Comportamiento inadecuado (Ban al host)
; F4  Ban al host (Sin expulsarlo de la sala)
; F5  Búsquedas sexuales en la sala subidas de tono



; ############################################################################
; ############################################################################
; ############################################################################




on 1:input:#: {

  ; ACA PUEDEN PONER EL COLOR QUE QUIERAN PARA QUE SE APLIQUE A TODOS LOS KICKS
  ; MODIFICANDO LA SIGUIENTE LINEA POR EL CODIGO DE COLOR QUE QUIERAN
  ; EJEMPLO: SI LO QUIEREN EN VERDE SERIA ASI====   set %frm 3

  set %frm 12



  if ($left($1,1) == / ) { return }

  if ($kb($1-) == 1) {  .disable #hablo | halt  }
  else { .enable #hablo | halt  }

}





alias F1 { mode $chan +b $1 $+ !*@* | kick # $1 %frm $+ Cambiate el Nick y volvé.. .Muchas Gracias...  }
alias F2 { mode $chan +b $Address($1,2) | kick # $1 %frm $+ Por favor, replantea tu forma de actuar en el canal  }
alias F4 { mode $chan +b $Address($1,2) }
alias F5 { mode $chan +b $Address($1,2) | kick # $1 %frm $+ Las búsquedas sexuales no son temática de este canal  }
alias F10 {
  .msg chan akick $chan add $1 Actividad no permitida en el canal
  .msg chan akick $chan enforce
  set -u10 %AK.nick $1
  .timer 1 5 msg chan akick $chan del %AK.nick $+ !*@*
}



Alias KB {


  if ( $me !isop $chan) { echo  0,2 PONETE EL @ PARA USAR ESTOS COMANDOS | return 1 }


  var %text $strip($1-)
  if ($regex(%text, /^(ban|kick|kbn?) (\S+)\s?(.+)?/i)) {
    var %nick $regml(2)
    var %IP $address(%nick,2)

    var %motivo $regml(3)
    if (%motivo == a )      { set %motivo No se permiten agresiones ni faltas de respeto }
    if (%motivo == s)       { set %motivo Búsquedas sexuales / Lenguaje sexual explícito }
    if (%motivo == t)       { set %motivo Temática inapropiada para 12 $+ # }
    if (%motivo == b)       { set %motivo Búsquedas no acordes al canal }
    if (%motivo == l)       { set %motivo Lenguaje inapropiado / Comentarios fuera de lugarl }
    if (%motivo == r)       { set %motivo Constantes repeticiones en la sala }
    if (%motivo == d)       { set %motivo No se permite pasar datos de contacto en la sala }



    if ( $regml(1) == kbn ) {
      set %motivo Nick inapropiado para este canal
    mode # +b %nick $+ !*@*   }

    elseif ( $regml(1) == kick ) {
      if ( %motivo == $null ) { set %motivo Por favor, modera tu comportamiento en el canal  }
    }

    else  {  mode # +b %IP
      if (%motivo == $null ) { set %motivo Comportamiento inadecuado en el canal }
    }

    set %motivo %frm %motivo $+ 

    if ($regml(1) != ban ) { kick # %nick %motivo }
    return 1


  }

}



alias Ban_x_Chan {

  if ($me isop $1 ) && ($2 ison $1) {
    var %IP $address($2,2)
    var %Nick $2!*@*
    ; mode $1 +bb %Nick %IP
  }

  .msg chan akick $chan add $2 $+ !*@* $3-
  .timer 1 3 .msg chan akick $1 enforce
  .timer 1 10 .msg chan akick $1 del $2!*@*

  if (  $me isop $1 ) {
    .timer 1 10   kick $1 $2 incumplimiento de normas
  }

}


ON 1:PART:#: { hadd -mu3600 salientes $address($nick,5) $nick }
ON 1:QUIT: {   hadd -mu3600 salientes $address($nick,5) $nick }
ON 1:KICK:#: {  hadd -mu3600 salientes $address($knick,5) $knick }





; ##########   ALIAS   ##############


Alias ban.NICK { Mode $chan +b $1 $+ !*@*  }

Alias ban.IP {
  if ( $1 ison $chan ) { Var %ip $ialchan(* $+ $1 $+ *,$chan,1) }
  Else {   Var %ip $hfind(salientes, $1 $+ !* ,1,w) }
  If ( %Ip ) {   %ip = *!*@ $+ $gettok(%ip, 2, 64) | Mode $chan +b %ip   }
  Else { Echo -a 0,2 No se ha encontrado el nick }
}

Alias ban.ID {
  if ( $1 ison $chan ) { Var %ID $ialchan($1 $+ !*, $chan,1) }
  Else { Var %ID $hfind(salientes, $1 $+ !* ,1,w) }
  noop $regex( %ID, !(.*)@ ) | %ID = $Regml(1)
  If (%ID ) {
    %ID = *! $+ %ID $+ @*
    Mode $chan +b %id
  }
  Else { echo -a No se encontro el nick  }
}



alias Unban {
  if ( $1 ison $chan ) { Var %Mascara $ialchan( $1 $+ !*, $chan,1) }
  Else { Var %Mascara $hfind(salientes, $1 $+ !* ,1,w) }
  If ( %Mascara == $Null ) { Echo -a 0,2 Nick equivocado | Halt }
  Var %i 1, %x 0

  While ( %i <=  $ibl($chan,0))  {
    If ( $ibl($chan,%i) iswm %Mascara   ) {
      inc %x
      set %addr $ibl($chan,%i)
      Var %x $+ %x %addr
    }
    Inc %i
  }
  if (%x) mode $chan - $+ $str(b,%x) %x1 %x2 %x3
  ; Echo -a %x1 %x2 %x3

  unset %addr

}