NMS

#property indicator_separate_window
#property indicator_buffers 2
#property indicator_color1 Magenta
#property indicator_color2 Silver
#property indicator_level1 0
#property indicator_levelcolor Gray
#property indicator_levelstyle 2

extern int     NMS_period  = 40;
extern bool    Show_SD     = true;
extern int     SD_len      = 30;
extern double  SD_up       = 2;
extern double  SD_dn       = 2;

double NMS[];
double SD[];

int init()
{
  string nmsname = "NMS(" + NMS_period + ")";
  string sdname = "NMS_SD(" + SD_len + ")";
  IndicatorShortName(nmsname);
  IndicatorBuffers(2);
  SetIndexBuffer(0, NMS);
  SetIndexLabel(0, nmsname);
  SetIndexBuffer(1, SD);
  SetIndexLabel(1, sdname);
  return(0);
}

int start()
{
  int limit, i, ii, counted_bars = IndicatorCounted();

  if(Bars <= NMS_period) return(0);
  if(counted_bars < 0) counted_bars = 0;
  if(counted_bars > NMS_period) limit = Bars - counted_bars;
  else                          limit = Bars - NMS_period - 1;

  for(i = limit; i >= 0; i--)
    {
    double nms2 = 0;
    for(ii = 1; ii <= NMS_period; ii++)
      {
      double oLRSlope = 0, SumXY = 0, SumY = 0, SumX, SumXSqr, Divisor;
      if(ii > 1)
        {
        SumX = ii * (ii - 1) * 0.5;
        SumXSqr = ii * (ii - 1) * (2 * ii - 1) * 1/6;
        Divisor = (SumX * SumX) - ii * SumXSqr;
        for(int iii = 0; iii < ii; iii++)
          {
          SumXY += iii * MathLog(Close[i+iii]);
          SumY += MathLog(Close[i+iii]);
          }
        oLRSlope = (ii * SumXY - SumX * SumY) / Divisor;
        }
      nms2 += oLRSlope * MathSqrt(ii);
      }
    NMS[i] = nms2 * 100;
    }

  if(Show_SD)
    for(i = limit; i >= 0; i--)
      if(i < Bars - NMS_period - 1 - SD_len)
        {
        if(NMS[i] == 0)     SD[i] = 0;
        else if(NMS[i] > 0) SD[i] = iBandsOnArray(NMS, 0, SD_len, SD_up, 0, MODE_UPPER, i);
        else if(NMS[i] < 0) SD[i] = iBandsOnArray(NMS, 0, SD_len, SD_dn, 0, MODE_LOWER, i);
        }

  return(0);
}