EXAMPLE - CHAKRA BAR

/*
EXAMPLE - CHAKRA BAR
for
HUD - Full Burst by J16D
*/

{$CLEO}
0000:

while true
if
  Player.Defined($PLAYER_CHAR)
then
    if
    0ADC:   test_cheat "actors"
    then
        wait 0

        const
            dir_fullburst = "cleo\hud_settings\hud_fullburst.ini"
        end
        /// read the chakra in the *.ini
        0AF2: 25@ = get_float_from_ini_file dir_fullburst section "CHAKRA" key "VALUE"
        if
        25@ > 200.0  // check if you have enough chakra
        then
            // quantity of chakra that you want to remove
            000B: 25@ += -200.0
            /// write the chakra in the *.ini
            0AF3: write_float 25@ to_ini_file dir_fullburst section "CHAKRA" key "VALUE"
        else
            0ACC: show_text_lowpriority "not enough chakra" time 1500
            jump @end_script
        end

        0ACA: show_text_box "on"

        04C4: store_coords_to 1@ 2@ 3@ from_actor $PLAYER_ACTOR with_offset -1.0 -2.5 0.0

        var
        10@: Array 2 of Integer
        end
        for 30@ = 0 to 1 // step 1
            009A: 10@[30@] = create_actor_pedtype 4 model #MALE01 at 1@ 2@ 3@
            1@ += 2.0
        end // for
        32@ = 0

        const
        counter_dead_actors = 5@
        end
        counter_dead_actors = 0

        while 10000 > 32@   /// 10 seconds
            for 30@ = 0 to 1 // step 1
                if
                056D:   actor 10@[30@] defined
                then
                    if
                    0118:   actor 10@[30@] dead
                    then
                        counter_dead_actors += 1
                        01C2: remove_references_to_actor 10@[30@] // Like turning an actor into a random pedestrian
                    end
                end
            end
            if
            counter_dead_actors > 1
            then
                break
            end

         wait 0
        end

        /// --- safe part, in case, actors alive
        for 30@ = 0 to 1 // step 1
            if
            056D:   actor 10@[30@] defined
            then
                01C2: remove_references_to_actor 10@[30@] // Like turning an actor into a random pedestrian
            end
        end

        0ACA: show_text_box "off"

        :end_script
        wait 500
    end
end
 wait 0
end