[Cod5][Release] - Infinite Option Menu Base

#include common_scripts\utility;
#include maps\_utility;
#include maps\_hud_util;

/*
    vRice's Infinite Options Menu Base
    Created in about 1 & 1/2 - 2 hours :)

    self.Menu[0] = Background
    self.Menu[1] = Splitting Line
    self.Menu[2] = Patch Text
    self.Menu[3] = Titles
    self.Menu[4] = Menu Options
*/

Settings()
{
    self.InMenu = 0;

    self thread Infinite();
    self thread MenuOptions();
}

MenuOptions()
{
    for(i = 0; i < 100; i++) self AddOption(0, i, "Main Menu", "Main Menu " + i, ::NewMenu, (i + 1));
    for(i = 0; i < 100; i++) for(ii = 0; ii < 100; ii++) self AddOption( i + 1, ii, "Sub Menu " + i, "Sub Option " + ii, ::Test);

    //self AddOption(MENU.NUMBER, OPTION.NUMBER, TITLE, OPTION, FUNCTION, PARAMETERS);
}

Infinite()
{
    for(;;)
    {
        if(self.InMenu == 0 && self AdsButtonPressed() && self MeleeButtonPressed())
        {
            self.InMenu = 1;

            for(i = 0; i < 7; i++) self.Menu[4][i] = CreateText("", "Default", 1.25, "TOP", "TOP", -70, (i * 15) + 20, 2, .5);

            self.Menu[2] = CreateText("Infinite Menu Base", "Default", 1.35, "TOP", "TOP", 70, 50, 2, 1);
            self.Menu[3] = CreateText("", "Default", 1.35, "TOP", "TOP", 70, 70, 2, 1);

            self.Menu[0] = CreateElement("TOP", "TOP", 0, 15, 275, 115, (0, 0, 0), "WHITE", 1, .3);
            self.Menu[1] = CreateElement("TOP", "TOP", 0, 15, 2, 115, (1, 1, 1), "WHITE", 1, .3);

            self NewMenu(0);
        }

        if(self.InMenu == 1 && self AdsButtonPressed() || self AttackButtonPressed())
        {
            for(i = 0; i < 7; i++) self.Menu["Value"][i] += self AttackButtonPressed();
            for(i = 0; i < 7; i++) self.Menu["Value"][i] -= self AdsButtonPressed();

            self TextUpdate(self.MenuNames[self.SubMenu]);
        }

        if(self.InMenu == 1 && self UseButtonPressed())
        {
            if(!isDefined(self.aInput[self.SubMenu][self.Curs]) && !isDefined(self.bInput[self.SubMenu][self.Curs])) self thread [[self.Function[self.SubMenu][self.Curs]]]();
            else if(isDefined(self.aInput[self.SubMenu][self.Curs]) && !isDefined(self.bInput[self.SubMenu][self.Curs])) self thread [[self.Function[self.SubMenu][self.Curs]]](self.aInput[self.SubMenu][self.Curs]);
            else if(isDefined(self.aInput[self.SubMenu][self.Curs]) && isDefined(self.bInput[self.SubMenu][self.Curs])) self thread [[self.Function[self.SubMenu][self.Curs]]](self.aInput[self.SubMenu][self.Curs],self.bInput[self.SubMenu][self.Curs]);
            wait .1;
        }

        if(self.InMenu == 1 && self MeleeButtonPressed())
        {
            if(self.SubMenu == 0) self CloseMenu();
            else self NewMenu(0);
        }
        wait .1;
    }
}

TextUpdate(Menu)
{
    self.Curs = self.Menu["Value"][3];
    self.Menu[4][3].alpha = 1;

    for(i = 0; i < 7; i++)
    {
        if(self.Menu["Value"][i] > Menu.size - 1) self.Menu["Value"][i] = 0;
        if(self.Menu["Value"][i] < 0) self.Menu["Value"][i] = Menu.size - 1;
    }

    for(i = 0; i < 7; i++) self.Menu[4][i] SetText(Menu[self.Menu["Value"][i]]);
}

CloseMenu()
{
    self.InMenu = 0;

    for(i = 0; i < 7; i++) self.Menu[4][i] destroy();
    for(i = 0; i < 5; i++) self.Menu[i] destroy();
}

NewMenu(Num)
{
    self.SubMenu = Num;
    self.FinalTitle = "";

    for(i = 0; i < 7; i++) self.Menu["Value"][i] = i;
    for(i = 0; i < self.MenuTitle[self.SubMenu].size; i++) {self.FinalTitle += self.MenuTitle[self.SubMenu][i]; self.Menu[3] SetText(self.FinalTitle); wait .075;}

    if(Num == 0) self TextUpdate(self.MenuNames[Num]);
    else self TextUpdate(self.MenuNames[self.SubMenu]);
}

AddOption(M, N, Title, Name, Func, aOpt, bOpt)
{
    self.MenuNames[M][N] = Name;
    self.Function[M][N] = Func;
    self.MenuTitle[M] = Title;

    if(isDefined(aOpt)) self.aInput[M][N] = aOpt;
    if(isDefined(bOpt)) self.bInput[M][N] = bOpt;
}

MoveElement(Time, xPos, yPos)
{
    self MoveOverTime(Time);
    self.x = xPos; self.y = yPos;
}

CreateText(Text, Font, Scale, Align, Relative, x, y, Sort, Alpha)
{
    self endon("death");
    TextElem = createFontString(Font, Scale, self);

    TextElem setPoint(Align, Relative, x, y);
    TextElem SetText(Text);

    TextElem.sort = Sort;
    TextElem.alpha = Alpha;
    TextElem.foreground = true;

    return TextElem;
}

CreateElement(Align, Relative, X, Y, Width, Height, Color, Shader, Sort, Alpha)
{
    self endon("death");
    RectangleElem = newClientHudElem( self );

    RectangleElem.elemType = "bar";
    RectangleElem.width = Width;
    RectangleElem.height = Height;
    RectangleElem.align = Align;
    RectangleElem.relative = Relative;
    RectangleElem.xOffset = 0;
    RectangleElem.yOffset = 0;
    RectangleElem.children = [];
    RectangleElem.sort = Sort;
    RectangleElem.color = Color;
    RectangleElem.alpha = Alpha;
    RectangleElem setParent( level.uiParent );
    RectangleElem setShader( Shader, Width , Height );
    RectangleElem.hidden = false;
    RectangleElem setPoint(Align, Relative, X, Y);

    return RectangleElem;
}

Test()
{
    self iprintln(self.MenuNames[self.SubMenu][self.Curs]);
}