drizzle PKGBUILD

# Maintainer: Emil Renner Berthing <esmil@mailme.dk>

pkgname=drizzle
eval "pkgname=('drizzle' 'libdrizzle')" # hack to fool AUR
pkgbase=drizzle
pkgver=7.1.33
pkgrel=1
arch=('i686' 'x86_64')
url="http://drizzle.org/"
license=('GPL')
makedepends=('protobuf' 'boost' 'gperf')
source=(https://launchpad.net/drizzle/7.1/$pkgver/+download/drizzle-$pkgver-stable.tar.gz)
sha1sums=('5ca3349e8bc14ac73a94ed7ddf1fd234c47f5110')

build() {
  cd "$srcdir/drizzle-$pkgver-stable"

  msg "Changing references to python binary in config scripts"
  sed -i 's/python/python2/g' ./config/pre_hook.sh
  sed -i 's/python/python2/g' ./config/pandora-plugin

  msg "Starting make..."
  ./config/autorun.sh
  PYTHON=python2 ./configure --prefix=/usr || return 1

  msg "Changing references to python binary in Makefile"
  sed -ie 's/python /python2 /g' Makefile

  # Disable adding group and user by the install rule in the makefile
  sed -i 's/^GROUPADD/#GROUPADD/' Makefile
  sed -i 's/^USERADD/#USERADD/' Makefile
  make || return 1
}

package_drizzle() {
  pkgdesc="A lightweight SQL database for Cloud and Web"
  depends=('protobuf' 'boost' 'libdrizzle')

  cd "$srcdir/drizzle-$pkgver-stable"
  make DESTDIR="$pkgdir/" install

  cd "$pkgdir"
  mkdir -p ../tmp/{include,lib/pkgconfig}

  mv usr/include/libdrizzle ../tmp/include
  mv usr/lib/libdrizzle.* ../tmp/lib
  mv usr/lib/pkgconfig/libdrizzle.pc ../tmp/lib/pkgconfig
}

package_libdrizzle() {
  eval "pkgdesc='A C library to query Drizzle and other MySQL-related databases'" # hack to fool AUR
  depends=('glibc')

  cd "$pkgdir"
  mv ../tmp usr
}