zsh.prompt

function precmd {

    local TERMWIDTH
    (( TERMWIDTH = ${COLUMNS} - 1 ))


    ###
    # Truncate the path if it's too long.

    PR_FILLBAR=""
    PR_PWDLEN=""

    local promptsize=${#${(%):------(%n@%m:%l)-------------()---------}}
    local pwdsize=${#${(%):-%~}}

    if [[ "$promptsize + $pwdsize" -gt $TERMWIDTH ]]; then
        ((PR_PWDLEN=$TERMWIDTH - $promptsize))
    else
    PR_FILLBAR="\${(l.(($TERMWIDTH - ($promptsize + $pwdsize)))..${PR_HBAR}.)}"
    fi


    ###
    # Get APM info.

    if which ibam > /dev/null; then
    PR_APM_RESULT=`ibam --percentbattery`
    elif which apm > /dev/null; then
    PR_APM_RESULT=`apm`
    fi
}


setopt extended_glob
preexec () {
    if [[ "$TERM" == "screen" ]]; then
    local CMD=${1[(wr)^(*=*|sudo|-*)]}
    echo -n "\ek$CMD\e\\"
    fi
}


setprompt () {
    ###
    # Need this so the prompt will work.

    setopt prompt_subst


    ###
    # See if we can use colors.

    autoload colors zsh/terminfo
    if [[ "$terminfo[colors]" -ge 8 ]]; then
    colors
    fi
    for color in RED GREEN YELLOW BLUE MAGENTA CYAN WHITE; do
    eval PR_$color='%{$terminfo[bold]$fg[${(L)color}]%}'
    eval PR_LIGHT_$color='%{$fg[${(L)color}]%}'
    (( count = $count + 1 ))
    done
    PR_NO_COLOUR="%{$terminfo[sgr0]%}"
    PR_BGREEN=$'%{\e[0;92m%}'
    PR_DGREEN=$'%{\e[0;32m%}'
    PR_BLUE=$'%{\e[0;94m%}'
    PR_BWHITE='%b%F{white}'
    PR_DWHITE=$'%{\e[0;90m%}'
    PR_CYAN='%b%F{cyan}'


    ###
    # See if we can use extended characters to look nicer.

    typeset -A altchar
    set -A altchar ${(s..)terminfo[acsc]}
    PR_SET_CHARSET="%{$terminfo[enacs]%}"
    PR_SHIFT_IN="%{$terminfo[smacs]%}"
    PR_SHIFT_OUT="%{$terminfo[rmacs]%}"
    PR_HBAR=${altchar[q]:--}
    PR_ULCORNER=${altchar[l]:--}
    PR_LLCORNER=${altchar[m]:--}
    PR_LRCORNER=${altchar[j]:--}
    PR_URCORNER=${altchar[k]:--}


    ###
    # Decide if we need to set titlebar text.

    case $TERM in
    xterm*)
        PR_TITLEBAR=$'%{\e]0;%(!.-=*[ROOT]*=- | .)%n@%m:%~ | ${COLUMNS}x${LINES} | %y\a%}'
        ;;
    screen)
        PR_TITLEBAR=$'%{\e_screen \005 (\005t) | %(!.-=[ROOT]=- | .)%n@%m:%~ | ${COLUMNS}x${LINES} | %y\e\\%}'
        ;;
    *)
        PR_TITLEBAR=''
        ;;
    esac


    ###
    # Decide whether to set a screen title
    if [[ "$TERM" == "screen" ]]; then
    PR_STITLE=$'%{\ekzsh\e\\%}'
    else
    PR_STITLE=''
    fi

    ###
    # Decide whether it is a remote login
    if [[ -n "$SSH_CLIENT" ]]; then
        PR_HOSTNAME_CL=$PR_RED
    else
        PR_HOSTNAME_CL=$PR_DGREEN
    fi
    ###
    # APM detection

    if which ibam > /dev/null; then
    PR_APM='$PR_RED${${PR_APM_RESULT[(f)1]}[(w)-2]}%%(${${PR_APM_RESULT[(f)3]}[(w)-1]})$PR_LIGHT_BLUE:'
    elif which apm > /dev/null; then
    PR_APM='$PR_RED${PR_APM_RESULT[(w)5,(w)6]/\% /%%}$PR_LIGHT_BLUE:'
    else
    PR_APM=''
    fi


    ###
    # Finally, the prompt.
    PR_FADEIN=$PR_DWHITE$PR_HBAR$PR_HBAR$PR_DGREEN$PR_HBAR$PR_BGREEN$PR_HBAR$PR_BWHITE$PR_HBAR$PR_HBAR$PR_BGREEN$PR_HBAR
    PR_FADEOUT=$PR_BWHITE$PR_HBAR$PR_BGREEN$PR_HBAR$PR_DGREEN$PR_HBAR$PR_DWHITE$PR_HBAR

    PROMPT='$PR_SET_CHARSET$PR_STITLE${(e)PR_TITLEBAR}\
$PR_BWHITE$PR_SHIFT_IN$PR_ULCORNER$PR_HBAR$PR_FADEOUT$PR_SHIFT_OUT${PR_BGREEN}[\
$PR_DGREEN%n$PR_BGREEN@$PR_HOSTNAME_CL%m$PR_DGREEN:%l\
${PR_BGREEN}]$PR_SHIFT_IN$PR_FADEIN$PR_DGREEN${(e)PR_FILLBAR}$PR_BGREEN$PR_HBAR$PR_BWHITE$PR_HBAR$PR_FADEOUT$PR_SHIFT_OUT${PR_GREEN}[\
$PR_DGREEN%$PR_PWDLEN<...<%~%<<\
${PR_GREEN}]$PR_SHIFT_IN$PR_FADEIN$PR_DGREEN$PR_URCORNER$PR_SHIFT_OUT\

$PR_BGREEN$PR_SHIFT_IN$PR_LLCORNER$PR_DGREEN$PR_HBAR$PR_SHIFT_OUT\
$PR_SHIFT_IN$PR_DWHITE$PR_HBAR$PR_SHIFT_OUT\
%(!.$PR_RED.$PR_BWHITE) %(!.#.$)$PR_NO_COLOR '

    RPROMPT=' $PR_DGREEN$PR_SHIFT_IN$PR_HBAR$PR_BGREEN$PR_HBAR$PR_SHIFT_OUT\
(%(0?.$PR_DGREEN^_^.$PR_RED>_<)$PR_BGREEN)$PR_SHIFT_IN$PR_HBAR$PR_BGREEN$PR_LRCORNER$PR_SHIFT_OUT$PR_NO_COLOUR'

    PS2='$PR_SHIFT_IN$PR_FADEOUT$PR_HBAR$PR_SHIFT_OUT(\
$PR_BGREEN%_)$PR_SHIFT_IN$PR_FADEOUT$PR_SHIFT_OUT\
$PR_SHIFT_IN$PR_HBAR$PR_SHIFT_OUT>$PR_NO_COLOUR '
}

setprompt