// Winterfox - Cash Rewards V 1.0
-	script	cash_rewards	-1,{
	OnInit:
		// To add manual mobs besides MVPs.
		.@mobIdListStr$ = "";

		// To filter certain mobs.
		.@mobFilterListStr$ = "";

		// Set the points you get for slaying an mob defined in the rewardMobsIds array.
		.mobRewardPoints = 1;

		// Set the points you get for slaying an opponent in pvp
		.pvpRewardPoints = 1;

		// Explode the mob id list.
		explode(.@mobIdList$, .@mobIdListStr$, ", ");

		// Loop trough the id list.
		for(.@i = 0; .@i < getarraysize(.@mobIdList$); .@i++) {
			// Rebuild add the id to the mob ids.
			.@mobIds[.@i] = atoi(.@mobIdList$[.@i]);
		}

		// Explode the mob filter list
		explode(.@mobFilterList$,.@mobFilterListStr$,", ");

		// Loop trough the filter list.
		for(.@i = 0; .@i < getarraysize(.@mobFilterList$); .@i++) {
			// Rebuild it to another array with id as key.
			.@mobFilter[atoi(.@mobFilterList$[.@i])] = 1;
		}

		// Loop trough the mob ids.
		for(.@i = 0; .@i < getarraysize(.@mobIds); .@i++) {
			// If mob id is not in the filter.
			if(!.@mobFilter[.@mobIds[.@i]]) {
				// Add it to the rewards.
				.rewardMobIds[.@mobIds[.@i]] = 1;
			}
		}

		// Search all MVPs based on if a mob gives MVP Exp.
		.@db = query_sql("SELECT ID  FROM `mob_db` WHERE `MEXP` > 0", .@mvpIds);
		// Loop trough all MVPs
		for(.@i = 0; .@i < getarraysize(.@mvpIds); .@i++) {
			// If the MVP is not in the filter.
			if(!.@mobFilter[.@mvpIds[.@i]]) {
				// Add it to the rewards.
				.rewardMobIds[.@mvpIds[.@i]] = 1;
			}
		}
	end;
	OnNPCKillEvent:
		// If killed mob is a monster that gives a reward.
		if(.rewardMobIds[killedrid]) {
			// Add Cash Point reward.
			#CASHPOINTS += .mobRewardPoints;

			// Show Cash Point gain to the player.
			dispbottom "You now have " + #CASHPOINTS + " Cash Point" + ((#CASHPOINTS > 1) ? "s" : "") + ".";

			// Globally announce the kill.
			announce strcharinfo(PC_NAME) + " killed " + strmobinfo(1, killedrid) + " and earned "+ .mobRewardPoints +" Cash Point" + ((.mobRewardPoints > 1) ? "s" : "") + ".", bc_all;
		}
	end;
	OnPCKillEvent:
			// Add Cash Point reward.
			#CASHPOINTS += .pvpRewardPoints;

			// Show Cash Point gain to the player.
			dispbottom "You now have " + #CASHPOINTS + " Cash Point" + ((#CASHPOINTS > 1)? "s":"") + ".";

			// Announce the kill on the map.
			announce strcharinfo(PC_NAME) + " killed " + rid2name(killedrid) + " and earned " + .pvpRewardPoints +" Cash Point" + ((.pvpRewardPoints > 1)? "s" : "") + ".", bc_map;
	end;
}