CursorBlink

.nolist
#include    "ti83plus.inc"
#define    ProgStart    $9D95
.list
.org    ProgStart - 2
    .db t2ByteTok, tAsmCmp
    b_call(_getKey)
    b_call(_ClrLCDFull)
    LD HL, 0
    LD (CurRow), HL
    SET CurOn, (IY + CurFlags)
    LD A, 0
    LD (CurTime), A
    DI
    LD HL, CurTime
    EXX
    IM 2
    LD A, %00000010
    OUT (3), A
    LD A, $98               ;AppBackupScreen is at $9872
    LD I, A
    LD HL, $9900            ;Load Vector Table, $9900 - $99FF
    LD (HL), $98
    LD D, H
    LD E, 1
    LD BC, 255
    LDIR
    LD HL, InputISREnd
    LD DE, $9898
    LD BC, 3
    LDIR
    EI                  ;Enable the interrupts again.
InputKey:
    BIT CurOn, (IY + CurFlags)
    JR NZ, InputCursorOn
    LD A, " "
    JR InputKeyCont
InputCursorOn:
    LD A, $E0               ;$E0 = Cursor
InputKeyCont:
    b_call(_PutMap)
    LD A, $FD
    OUT (1), A
    NOP
    NOP
    IN A, (1)
    CP $FE
    JR NZ, InputKey
    IM 1
    RET
InputISR:
    DI
    EX AF, AF'
    EXX
    LD HL, CurTime
    INC (HL)
    LD A, 32
    CP (HL)
    JR NZ, InputNoblink
    LD (HL), 0
    LD A, (IY + CurFlags)
    XOR %00001000
    LD (IY + CurFlags), A
InputNoblink:
    EXX
    EX AF, AF'
    EI
    RET
InputISREnd:
    JP InputISR
;Keyport (1):
;                  +-------------------------------------------------------------------------------------------------------------------------------+
;                  ¦                                                             Read:                                                             ¦
;                  +-------------------------------------------------------------------------------------------------------------------------------¦
;                  ¦$FE = %11111110¦$FD = %11111101¦$FB = %11111011¦$F7 = %11110111¦$EF = %11101111¦$DF = %11011111¦$BF = %10111111¦$7F = %01111111¦
;+-----------------+---------------+---------------+---------------+---------------+---------------+---------------+---------------+---------------¦
;¦ ¦$BF = %10111111¦    [GRAPH]    ¦    [TRACE]    ¦    [ZOOM]     ¦   [WINDOW]    ¦     [Y=]      ¦     [2nd]     ¦    [MODE]     ¦     [DEL]     ¦
;¦W¦$DF = %11011111¦               ¦     [STO]     ¦     [LN]      ¦     [LOG]     ¦     [X²]      ¦     [X-1]     ¦    [MATH]     ¦    [ALPHA]    ¦
;¦R¦$EF = %11101111¦      [0]      ¦      [1]      ¦      [4]      ¦      [7]      ¦      [,]      ¦     [SIN]     ¦    [APPS]     ¦   [X,T,Q,n]   ¦
;¦I¦$F7 = %11110111¦      [.]      ¦      [2]      ¦      [5]      ¦      [8]      ¦      [)]      ¦     [COS]     ¦    [PRGM]     ¦    [STAT]     ¦
;¦T¦$FB = %11111011¦     [(-)]     ¦      [3]      ¦      [6]      ¦      [9]      ¦      [(]      ¦     [TAN]     ¦    [VARS]     ¦               ¦
;¦E¦$FD = %11111101¦    [ENTER]    ¦      [+]      ¦      [-]      ¦      [X]      ¦      [/]      ¦      [^]      ¦    [CLEAR]    ¦               ¦
;¦ ¦$FE = %11111110¦    [DOWN]     ¦    [LEFT]     ¦    [RIGHT]    ¦     [UP]      ¦               ¦               ¦               ¦               ¦
;+-------------------------------------------------------------------------------------------------------------------------------------------------+
.end
.end