mapper.msdp.bylins.set

#var MapOutputWindow 0

#action {/^#Connection established\./}
    {
        #var MapperWorldName $HOSTNAME;
        #wclear $MapOutputWindow;
        #wname $MapOutputWindow {MSDP Automap - $MapperWorldName};
        #message mapper off;
        #var PrevVNum 0;
        #var CurrentVNum 0;
        #var AutoRun 0;
        #read maps/$MapperWorldName.msdp.map
    }
    {automap}
#action {/^#Connection lost\./} {#mapper write maps/$MapperWorldName.msdp.map} {5} {automap}
#action {/^#Connection closed by user\./} {#mapper write maps/$MapperWorldName.msdp.map} {5} {automap}

#mapper clear

#mapper add direction {вниз,вн,down,d} -1 -1 0 {вверх,вв,up,u}
#mapper add direction {восток,в,east,e} 1 0 0 {запад,з,west,w}
#mapper add direction {север,с,north,n} 0 1 0 {юг,ю,south,s}

#mapper add flag {forest} {"} {green}
#mapper add flag {city} {"} {white}
#mapper add flag {inside} {"} {grey}
#mapper add flag {swim water} {~} {blue}
#mapper add flag {no swim water} {~} {light blue}
#mapper add flag {field} {"} {yellow}
#mapper add flag {hills} {^} {brown}
#mapper add flag {mountain} {^} {white}
#mapper add flag {road} {:} {white}
#mapper add flag {stone road} {:} {grey}
#mapper add flag {wild road} {:} {charcoal}
#mapper add flag {flying} {^} {red}

#mapper add flag {продавец} {$} {light green}
#mapper add flag {квестер} {@} {yellow}
#mapper add flag {кузнец} {%} {brown}
#mapper add flag {опасно} {!} {light red}
#mapper add flag {учитель} {*} {green}
#mapper add flag {жопа} {Ж} {light red}
#mapper add flag {неисследовано} {?} {brown}

#alias redrawMap
    {
        #wclear $MapOutputWindow;
        #mapper print normal header flags exits comment w$MapOutputWindow $MapVNum
    }
    {automap}
#alias onRoom
    {
        #mapper add room $MsdpRoomVnum {$MsdpRoomName} {} {$MsdpRoomArea} {} {$MsdpRoomTerrain};
        #mapper reset flag $MsdpRoomVnum неисследовано;
        #if {$MsdpRoomExitsLength > 0}
            {
                #loop {1, $MsdpRoomExitsLength}
                    {
                        #mapper get id {$MsdpRoomExitsValue%0} ExitVNum;
                        #if {$ExitVNum == 0}
                            {
                                #mapper add room {$MsdpRoomExitsValue%0} {?} {} {} {} {неисследовано}
                            };
                        #mapper add exit $MsdpRoomVnum {$MsdpRoomExitsKey%0} {$MsdpRoomExitsValue%0}
                    }
            };
        #var PrevVNum {$CurrentVNum};
        #var CurrentVNum {$MsdpRoomVnum};
        #var MapVNum {$CurrentVNum};
        redrawMap;
        #if {$AutoRun == 1} {stepAutoRun}
    }
    {automap}

#action TEXT {/^#oob MSDP ROOM/} {onRoom; #drop} {5} {automap}

#alias запвых {#mapper add exit $PrevVNum {$COMMAND} $CurrentVNum {};redrawMap} {automap}
#alias здесь
    {
        #mapper set flag $MapVNum %1;
        #strcmp %1 опасно {#mapper set avoidance $MapVNum 100};
        #strcmp %1 жопа {#mapper set avoidance $MapVNum 0};
        redrawMap
    }
    {automap}
#alias здесьне {#mapper reset flag $MapVNum %1;redrawMap} {automap}
#alias коммент {#mapper set comment $MapVNum {%%0};redrawMap} {automap}
#alias {/^проход (\w+) (.*)/} {#mapper set pass $MapVNum {%%0} {%%1};redrawMap} {automap}
#alias путьсюда {#mapper path $CurrentVNum $MapVNum} {automap}

#alias кближнему
    {
        #mapper search near $MapVNum flag %1 TargetVNum;
        #strcmp {$TargetVNum} 0 {}
            {
                #var AutoRun 1;
                stepAutoRun
            }
    }
    {automap}

#alias stepAutoRun
    {
        #strcmp $CurrentVNum $TargetVNum {#var AutoRun 0};
        #if {$AutoRun == 1}
            {
                #mapper path $CurrentVNum $TargetVNum AutoRunStep;
                #strcmp {$AutoRunStep} {}
                    {
                        #var AutoRun {0}
                    }
                    {
                        $AutoRunStep
                    }
            }
    }
    {automap}
#alias бежсюда
    {
        #var TargetVNum $MapVNum;
        #var AutoRun 1;
        stepAutoRun
    }
    {automap}
#alias стопбеж {#var AutoRun 0} {automap}

#alias покарте
    {
        #mapper get exit %1 $MapVNum NextMapVNum;
        #if {$NextMapVNum != 0}
            {
                #var MapVNum $NextMapVNum;
                redrawMap
            }
    }
    {automap}

#hot {Alt+UP} {покарте север} {automap}
#hot {Alt+LEFT} {покарте запад} {automap}
#hot {Alt+RIGHT} {покарте восток} {automap}
#hot {Alt+DOWN} {покарте юг} {automap}
#hot {Alt+0} {#var MapVNum $CurrentVNum;redrawMap} {automap}

#telnet MSDP on
#oob MSDP add ROOM
#message oob ON

#group enable automap