payon,162,231,5 	script	NPC Linker	100,{

	set .@deny, 10; // 10 seconds cooldown
	if ( @healer_deny + .@deny >= gettimetick(2) ) end;
	set @healer_deny, gettimetick(2);

	set .@time, 300000; // the buff last 5 minutes

	sc_end sc_stone;
	sc_end sc_freeze;
	sc_end sc_sleep;
	sc_end sc_curse;
	sc_end sc_silence;
	sc_end sc_confusion;
	sc_end sc_blind;
	sc_end sc_bleeding;
	sc_end sc_decreaseagi;
	sc_end sc_poison;
	sc_end sc_hallucination;
	sc_end sc_stripweapon;
	sc_end sc_striparmor;
	sc_end sc_striphelm;
	sc_end sc_stripshield;
	sc_end sc_changeundead;
	sc_end sc_orcish;
	sc_end sc_berserk;
	sc_end sc_ske;
	sc_end sc_swoo;
	sc_end sc_ska;

	sc_start SC_CONCENTRATE, .@time, 10;
	sc_start SC_BLESSING, .@time, 10;
	sc_start SC_INCREASEAGI, .@time, 10;
	sc_start SC_IMPOSITIO, .@time, 5;
	sc_start SC_SUFFRAGIUM, .@time, 3;
	sc_start SC_KYRIE, .@time, 10;
	sc_start SC_MAGNIFICAT, .@time, 5;
	sc_start SC_GLORIA, .@time, 5;
	sc_start SC_WINDWALK, .@time, 5;
	//sc_start SC_ANGELUS, .@time, 10;

	switch ( basejob ) {
		case Job_Alchemist:				set .@spirit, 445; break;
		case Job_Monk:					set .@spirit, 447; break;
		case Job_Star_Gladiator:		set .@spirit, 448; break;
		case Job_Sage:					set .@spirit, 449; break;
		case Job_Crusader:				set .@spirit, 450; break;
		//case Job_SuperNovice:			set .@spirit, 451; break;
		case Job_Knight:				set .@spirit, 452; break;
		case Job_Wizard:				set .@spirit, 453; break;
		case Job_Priest:				set .@spirit, 454; break;
		case Job_Bard: case Job_Dancer:	set .@spirit, 455; break;
		case Job_Rogue:					set .@spirit, 456; break;
		//case Job_Assassin:				set .@spirit, 457; break;
		case Job_Blacksmith:			set .@spirit, 458; break;
		case Job_Hunter:				set .@spirit, 460; break;
		case Job_Soul_Linker:			set .@spirit, 461; break;
		default:
			if ( upper == 1 && baselevel < 70 )
				set .@spirit, 494;
	}
	if ( .@spirit ) {
		sc_start4 sc_spirit, .@time, 5, .@spirit,0,0;
		skilleffect .@spirit, 5;
	}

	set .@ori, countitem(756);
	if ( .@ori >= 5 ) {
		getitem 984, .@ori / 5;
		delitem 756, .@ori / 5 * 5;
		message strcharinfo(0), "Refined "+ ( .@ori / 5 * 5 ) +" Oridecon Stones, got "+ ( .@ori / 5 ) +" Oridecons.";
	}
	set .@elu, countitem(757);
	if ( .@elu >= 5 ) {
		getitem 985, .@elu / 5;
		delitem 757, .@elu / 5 * 5;
		message strcharinfo(0), "Refined "+ ( .@elu / 5 * 5 ) +" Elunium Stones, got "+ ( .@elu / 5 ) +" Eluniums.";
	}

	while ( getbrokenid(1) && zeny >= 5000 ) {
		set .@rcount, .@rcount +1 ;
		set zeny, zeny - 5000;
		repair 1;
	}
	if ( .@rcount )
		message strcharinfo(0), "Repaired "+ .@rcount +" Items.";

	getinventorylist;
	for( set .@i,0; .@i < @inventorylist_count; set .@i, .@i + 1 ) {
		if ( @inventorylist_identify[.@i] == 1 )
			continue;
		else if ( getskilllv(40) == 1 && sp >= 10 )
			heal 0,0; // lol... this is supposed to reduce their SP by 10, whatever
		else if ( countitem(611) )
			delitem 611,1;
		else if ( getskilllv(224) && zeny >= ( 100 - ( 5 + 4 * getskilllv(224) ) )* 2/5 )
			set zeny, zeny - ( 100 - ( 5 + 4 * getskilllv(224) ) )* 2/5;
		else if ( getskilllv(37) && zeny >= ( 100 - ( 5 + 2 * getskilllv(37) ) )* 2/5 )
			set zeny, zeny - ( 100 - ( 5 + 2 * getskilllv(37) ) )* 2/5;
		else if ( zeny >= 40 )
			set zeny, zeny - 40;
		else
			break;
		delitem2 @inventorylist_id[.@i],1,0,0,0,0,0,0,0;
		getitem @inventorylist_id[.@i],1;
		set .@icount, .@icount +1 ;
	}
	if ( .@icount )
		message strcharinfo(0), "Identified "+ .@icount +" Items.";

	if ( isequippedcnt(4128) >= 1 ) // if your server needs 2 GTB to immune, set to 2 instead of 1
		dispbottom "[Healer] Please unequip your Golden Thief Bug card to get full buff.";

	percentheal 100,100;
	skilleffect 28, maxhp;
	skilleffect 9, maxsp;

	end;
}