Epic Batch File

@echo off

:main

cls

echo Connecting Point Computer Center
echo System Preperation Utility
echo.
echo 1 = Install SEP for 32-Bit computers.
echo 2 = Install SEP for 64-bit computers.
echo 3 = Open Sysprep Folder
echo 4 = Disable UAC.
echo 5 = Enable UAC.
echo 6 = Open Local Users and Groups MGMT console
echo 7 = Open Internet Options.
echo 8 = Import CPoint Pro power configuration.
echo 9 = Open Power Configuration Page.
echo h = Disable Hibernation permanently. (Desktops Only)
echo i = Install 3rd Party software.
echo a = Open Programs and Features Window.
echo n = Open Network Connections Window.
echo edit = Edit this file. (Password Required)
echo q = Abort SysPrep Utility.
echo e = Abort and Eject Drive.
echo r = Exit, Eject, and Restart Computer

echo.
set /p op=Please Choose an option:

if "%op%"=="1" goto sepx86
if "%op%"=="2" goto sepx64
if "%op%"=="3" start explorer.exe %~d0\CPoint\Sysprep
if "%op%"=="4" goto duac
if "%op%"=="5" goto euac
if "%op%"=="6" goto lusrmgr
if "%op%"=="7" goto inetcpl
if "%op%"=="8" goto pcfgimport
if "%op%"=="9" goto powercfg
if "%op%"=="h" goto hiberoff
if "%op%"=="i" goto thirdpty
if "%op%"=="a" goto appwiz
if "%op%"=="n" goto ncpa
if "%op%"=="edit" goto edit
if "%op%"=="q" goto eof
if "%op%"=="e" goto eject
if "%op%"=="r" goto restart

echo "%op%" is not a valid option or is not implemented yet.
echo Please Try again.
echo.
pause
goto main

:sepx86
cls
echo.
echo Deleting Existing Directory
echo.
RMDIR C:\SEP12 /S /Q
echo.
echo Creating Directory
echo.
MD C:\SEP12
echo Copying File
echo.
copy "\CPoint\Programs\Symantec\SEPx86.exe" "C:\SEP12"

echo Copy Completed
echo.

echo Starting extractor please click "Extract" on the following window.
echo.
start /wait C:\SEP12\SEPx86.exe
echo Extraction Complete
echo.
echo Starting installation.
echo Press any key to return to the Main Menu.
pause
start explorer.exe C:\SEP12
goto main

:sepx64
cls
echo.
echo Deleting Existing Directory
echo.
RMDIR C:\SEP12 /S /Q
echo.
echo Creating Directory
echo.
MD C:\SEP12
echo Copying File
echo.
copy "\CPoint\Programs\Symantec\SEPx64.exe" "C:\SEP12"

echo Copy Completed
echo.

echo Starting extractor please click "Extract" on the following window.
echo.
start /wait C:\SEP12\SEPx64.exe
echo Extraction Complete
echo.
echo Starting installation.
echo press any key to return to the Main menu.
pause
start explorer.exe C:\SEP12
goto main

:duac
cls
echo Disabling User Account Control
start %windir%\System32\reg.exe ADD  HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Policies\System /v  EnableLUA /t REG_DWORD /d 0 /f
echo User Account Control disabled please restart the computer for the changes to take effect.
echo Press any key to return to the Main Menu
pause
goto main

:euac
cls
echo Enabling User Account Control
start %windir%\System32\reg.exe ADD  HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Policies\System /v  EnableLUA /t REG_DWORD /d 1 /f
echo User Account Control enabled please restart the computer for the changes to take effect.
echo Press any key to return to the Main Menu.
pause
goto main

:lusrmgr
cls
echo Starting Local Users and Groups Management Console.
start lusrmgr.msc
echo Press any key to return to the Main Menu.
pause
goto main

:inetcpl
cls
echo Opening Internet Options
start inetcpl.cpl
echo Press any key to return to the Main Menu.
pause
goto main

:pcfgimport
cls
echo Power Configuration Import
echo.
echo Is this a Desktop or a Laptop?
echo.
echo 1 = Desktop
echo 2 = Laptop
echo 3 = Return to the main menu.
echo.
set /p oppwr=Please Choose an Option:

if "%oppwr%"=="1" goto pwrdesktop
if "%oppwr%"=="2" goto pwrlaptop
if "%oppwr%"=="3" goto main

:pwrdesktop
cls
echo Importing Power Plan "CPoint Pro Power Plan" (Desktop)
powercfg -import "%~d0/CPoint/sysprep/power/desktop/Pro.pow" 32f34922-e8d2-480f-838f-2a24463ba5bf
echo.
echo Power plan imported, please open Power Options to switch to this Profile.
echo.
echo Setting power plan as default.
powercfg -setactive 32f34922-e8d2-480f-838f-2a24463ba5bf
pause
goto pcfgimport

:pwrlaptop
cls
echo Importing Power Plan "CPoint Pro Power Plan" (Laptop)
powercfg -import "%~d0/CPoint/sysprep/power/laptop/Pro.pow" 32f34922-e8d2-480f-838f-2a24463ba5bf
echo.
echo Power plan imported, please open Power Options to switch to this Profile.
echo.
echo Setting power plan as default.
powercfg -setactive 32f34922-e8d2-480f-838f-2a24463ba5bf
echo.
pause
goto pcfgimport

:powercfg
cls
echo Opening Power Options Control Panel
start powercfg.cpl
echo Press any Key to return to the Main Menu.
pause
goto main

:hiberoff
cls
echo Disabling Hibernation.
powercfg -h off
echo Hibernation disabled. Press any key to return to the Main Menu.
pause
goto main

:thirdpty
cls
echo Installing 3rd party applications.
echo Please wait for each install to finish before continuing.
echo Press i to Install Adobe Reader or s to Skip.
set /p opth=Enter Choice:
if "%opth%"=="i" echo Installing Adobe Reader... & start /wait %~d0/CPoint/sysprep/AdbeRdr11007_en_US.exe
echo Press i to install Flash Player (IE) or s to Skip.
set /p opth=Enter Choice:
if "%opth%"=="i" echo Installing Adobe Flash Player (IE Installation)... & start /wait %~d0/CPoint/sysprep/install_flash_player_13_active_x.msi /passive
echo Press i to install Flash Player (Plugin) or s to Skip.
set /p opth=Enter Choice:
if "%opth%"=="i" echo Installing Adobe Flash Player (Plugin Installation)... & start /wait %~d0/CPoint/sysprep/install_flash_player_13_plugin.msi /passive
echo Press i to install Google Chrome or s to Skip.
set /p opth=Enter Choice:
if "%opth%"=="i" echo Installing Google Chrome (MultiUser Installation) & start /wait %~d0/CPoint/sysprep/ChromeStandaloneSetup.exe
echo Press i to install Java or s to Skip
set /p opth=Enter Choice:
if "%opth%"=="i" echo Installing Java & start /wait %~d0/CPoint/sysprep/JavaSetup7u55.exe
echo 3rd Party Software installation complete. Note: These Programs may be older versions,
echo please check for updates in the control panel or allow the program to auto-update.
echo Press any key to return to the Main Menu.
pause
goto main

:appwiz
cls
echo Opening Programs and Features window.
start appwiz.cpl
echo Press any key to return to the Main Menu.
pause
goto main

:ncpa
cls
echo Opening Network Connections window.
start ncpa.cpl
echo Press any key to return to the Main Menu
pause
goto main

:edit
cls
echo Please enter Password.
set /p pass=>
if not "%pass%"=="service" goto main
echo Starting Editor.


:restart
cls
echo Restarting Computer please remove the drive when eject notification is displayed.
start shutdown.exe -r -t 30 -f
goto eject

:eject
"%~d0\PortableApps\USBDiskEject\USB_Disk_Eject.exe" /removethis
goto eof

:eof
exit