[Setup]
AppName=My Program
AppVersion=1.5
DefaultDirName={pf}\My Program
OutputDir=userdocs:Inno Setup Examples Output

[Code]
var
  NextDirEdit: TNewEdit;

procedure NextDirButtonClick(Sender: TObject);
var
  Directory: string;
begin
  Directory := NextDirEdit.Text;
  if BrowseForFolder(SetupMessage(msgBrowseDialogLabel),
    Directory, False)
  then
    NextDirEdit.Text := Directory;
end;

procedure InitializeWizard;
var
  NextDirButton: TNewButton;
  NextDirLabel: TNewStaticText;
  BtnVertOffset: Integer;
begin
  NextDirLabel := TNewStaticText.Create(WizardForm);
  NextDirLabel.Parent := WizardForm.SelectDirPage;
  NextDirLabel.Left := WizardForm.SelectDirBrowseLabel.Left;
  NextDirLabel.Top := WizardForm.DirEdit.Top + WizardForm.DirEdit.Height + 10;
  NextDirLabel.Caption := 'Select the next directory';

  NextDirEdit := TNewEdit.Create(WizardForm);
  NextDirEdit.Parent := WizardForm.SelectDirPage;
  NextDirEdit.Left := WizardForm.DirEdit.Left;
  NextDirEdit.Top := NextDirLabel.Top + NextDirLabel.Height + 10;
  NextDirEdit.Width := WizardForm.DirEdit.Width;

  NextDirButton := TNewButton.Create(WizardForm);
  NextDirButton.Parent := WizardForm.SelectDirPage;
  NextDirButton.Left := WizardForm.DirBrowseButton.Left;
  NextDirButton.Top := NextDirEdit.Top - 1;
  NextDirButton.Width := WizardForm.DirBrowseButton.Width;
  NextDirButton.Height := WizardForm.DirBrowseButton.Height;
  NextDirButton.Caption := WizardForm.DirBrowseButton.Caption;
  NextDirButton.OnClick := @NextDirButtonClick;
end;