Overwatch - respawn while keeping position

variables {
	global:
		7: Texts
		15: Seeking_Phase
		26: Settings_General

	player:
		21: isReady
		34: HeroChangePress
		38: PlayerPositions
}

subroutines {
	8: ResetCharacterPressOverTime
}

rule("Change Hero system - Seeker") {
	event {
		Ongoing - Each Player;
		Team 2;
		All;
	}

	conditions {
		Is Alive(Event Player) == True;
		Is Button Held(Event Player, Button(Reload)) == True;
	}

	actions {
		"isReady is used to check if it need respawn or not so we set it back to 0 each press. (fail check)"
		Event Player.isReady = 0;

		"HeroChangePress is variable to tell the number of press a player did."
		Event Player.HeroChangePress += 1;

		"Hero we check if our Press count is lower than setting \"Number of press require to change hero.\""
		If(Round To Integer(Event Player.HeroChangePress, Up) < Global.Settings_General[6]);

			"Since that lower we print a tiny message on player screen to tell the count left before being force to change hero."
			Small Message(Event Player, Custom String("{2} {0} {1}", Global.Texts[44], Global.Texts[36],

				"Now we temporary edit what the Settings will return for the next if."
				Global.Settings_General[6] - Round To Integer(Event Player.HeroChangePress, Up)));

			"This subroutine is the pretty self explaining with name, it reset HeroChangePress back to 0 over time."
			Call Subroutine(ResetCharacterPressOverTime);
		End;

		"Now we check if our number of press is same or higher that the settings \"Number of press require to change hero.\""
		If(Round To Integer(Event Player.HeroChangePress, Up) >= Global.Settings_General[6]);

			"Now we save current positon of the Hero before puting him in spawn (that how the game does it.)"
			Event Player.PlayerPositions[0] = Position Of(Event Player);

			"Now we save current eye positon of the Hero before puting him in spawn (that how the game does it, it will be used in the futur to reset back the camera where it was.)"
			Event Player.PlayerPositions[1] = Eye Position(Event Player);

			"We forbid the currently selected hero so the game force the player to change hero."
			Set Player Allowed Heroes(Event Player, Remove From Array(Allowed Heroes(Event Player), Hero Of(Event Player)));

			"Now we reset available hero following Rules, meaning allowing back our previously forbidden hero."
			Reset Player Hero Availability(Event Player);

			"Now we wait for the player to select an hero and actually spawn."
			Wait Until(Has Spawned(Event Player), 99999);

			"A little Delay for user with low end pc or switch to actually load fine."
			Wait(0.500, Ignore Condition);

			"We reset our number of press."
			Event Player.HeroChangePress = 0;

			"Settings_General[5] is the workshop settings "retain hero position on hero change feature (not spawn press H one !)"
			If(Global.Settings_General[5] == True);

				"now we set ready as 7 to be eligible to another rule"
				Event Player.isReady = 7;

			End;
		End;
		Wait(0.250, Ignore Condition);
	}
}

rule("Change Hero system - Hider") {
	event {
		Ongoing - Each Player;
		Team 1;
		All;
	}

	conditions {
		Is Alive(Event Player) == True;
		Is Button Held(Event Player, Button(Primary Fire)) == True;
		Global.Seeking_Phase == False;
	}

	actions {
		"For variable comments check Seeker system, here only the method of press is different something different will be done in the futur to merge them."
		Event Player.HeroChangePress += 1;
		Event Player.isReady = 1;
		If(Round To Integer(Event Player.HeroChangePress, Up) < Global.Settings_General[6]);
			Small Message(Event Player, Custom String("{2} {0} {1}", Global.Texts[44], Global.Texts[36],
				Global.Settings_General[6] - Round To Integer(Event Player.HeroChangePress, Up)));
			Call Subroutine(ResetCharacterPressOverTime);
		End;
		If(Round To Integer(Event Player.HeroChangePress, Up) >= Global.Settings_General[6]);
			Event Player.PlayerPositions[0] = Position Of(Event Player);
			Event Player.PlayerPositions[1] = Eye Position(Event Player);
			Set Player Allowed Heroes(Event Player, Remove From Array(Allowed Heroes(Event Player), Hero Of(Event Player)));
			Reset Player Hero Availability(Event Player);
			Wait(Has Spawned(Event Player), Ignore Condition);
			Wait(0.500, Ignore Condition);
			If(Global.Settings_General[5] == True);
				Event Player.isReady = 7;
			End;
			Event Player.HeroChangePress = 0;
		End;
		Wait(0.250, Ignore Condition);
	}
}

rule("Change Hero system - Teleport Player back") {
	event
	{
		Ongoing - Each Player;
		All;
		All;
	}

	conditions {
		Is Alive(Event Player) == True;
		Has Spawned(Event Player) == True;
		"Here you variable that is set to 7 once we reach proper press count and feature turned On"
		Event Player.isReady == 7;
	}

	actions {
		"Here we set back the number of time player press to 0 to reset the system"
		Event Player.HeroChangePress = 0;
		"We teleport back our player to previously saved position"
		Teleport(Event Player, Event Player.PlayerPositions[0]);
		"Team 1 = Hider"
		If(Team Of(Event Player) == Team 1);
			"We remove Knocked down status for Hider that fake-death"
			Clear Status(Event Player, Knocked Down);
			"We now remove 3rd person camera from Hider"
			Stop Camera(Event Player);
		End;
		Event Player.isReady = 1;
	}
}