Trocador de Moedas por Yggs/Vice-Versa ~ Wenden [PEDIDO]

/*
      ___           ___           ___                         ___           ___
     /\  \         /\__\         /\  \         _____         /\__\         /\  \
    _\:\  \       /:/ _/_        \:\  \       /::\  \       /:/ _/_        \:\  \
   /\ \:\  \     /:/ /\__\        \:\  \     /:/\:\  \     /:/ /\__\        \:\  \
  _\:\ \:\  \   /:/ /:/ _/_   _____\:\  \   /:/  \:\__\   /:/ /:/ _/_   _____\:\  \
 /\ \:\ \:\__\ /:/_/:/ /\__\ /::::::::\__\ /:/__/ \:|__| /:/_/:/ /\__\ /::::::::\__\
 \:\ \:\/:/  / \:\/:/ /:/  / \:\~~\~~\/__/ \:\  \ /:/  / \:\/:/ /:/  / \:\~~\~~\/__/
  \:\ \::/  /   \::/_/:/  /   \:\  \        \:\  /:/  /   \::/_/:/  /   \:\  \
   \:\/:/  /     \:\/:/  /     \:\  \        \:\/:/  /     \:\/:/  /     \:\  \
    \::/  /       \::/  /       \:\__\        \::/  /       \::/  /       \:\__\
     \/__/         \/__/         \/__/         \/__/         \/__/         \/__/

*/
// Porfavor não retire os créditos.

prontera,147,166,5	script	Trocador de Yggs	47,{

setarray @id[0],674,675; // Id das moedas [Padrão: 674 = Moeda de Mythril / 675 = Moeda de Prata]
set @w,1; // Quantas moedas irá receber por cada troca [Padrão: 1]
setarray @p[0],607,608; // Ids dos itens que será cobrado para trocar pelas moedas [607 = Fruto de Yggdrasil / 608 = Semente de Yggdrasil]
setarray @a[0],250,250; // Quantas Yggs/Seed serão cobradas por 1 moeda [Padrão: 250 Frutos de Yggdrasil / 250 Semenetes de Yggdrasil]

	Mes "["+strnpcinfo(1)+"]";
	Mes "Como posso ajudá-lo?";
	next;
	switch(select("Trocar Yggs por Moeda:Trocar Moedas por Yggs:Sair")){
		Case 3: Close;
		Case 1:
		Mes "["+strnpcinfo(1)+"]";
		Mes "Me diga qual tipo de yggdrasil";
		Mes "deseja trocar.";
		next;
			set @menu$,"";
			for(set @i,0; @i < getarraysize(@p); set @i,@i+1)
			set @menu$,@menu$+""+getitemname(@p[@i])+":";
			set @menu$,@menu$+"Cancelar";
			set @sel,select(@menu$)-1;
			if(@sel == getarraysize(@p)) Close;

			Mes "["+strnpcinfo(1)+"]";
			Mes "Muito bem, a troca vai ser assim:";
			Mes "por ^FF0000"+@a[@sel]+"^000000x "+getitemname(@p[@sel]);
			Mes "Eu vou lhe dar ^FF0000"+@w+"^000000x "+getitemname(@id[@sel]);
			Mes "Estamos de acordo?";
			next;
				if(select("Sim:Não") == 2) Close;
				if(countitem(@p[@sel]) < @a[@sel]){
				Mes "["+strnpcinfo(1)+"]";
				Mes "Você não tem "+getitemname(@p[@sel]);
				Mes "suficientes para concluir com a";
				Mes "operação.";
				Close;
				}

				Mes "["+strnpcinfo(1)+"]";
				Mes "Está feito, a troca foi";
				Mes "realizada com sucesso!";
				Close2;
				delitem @p[@sel],@a[@sel];
				getitem @id[@sel],@w;
				end;
		Case 2:
		Mes "["+strnpcinfo(1)+"]";
		Mes "Me diga qual tipo de Moeda";
		Mes "deseja trocar.";
		next;
			set @menu$,"";
			for(set @i,0; @i < getarraysize(@id); set @i,@i+1)
			set @menu$,@menu$+""+getitemname(@id[@i])+":";
			set @menu$,@menu$+"Cancelar";
			set @sel,select(@menu$)-1;
			if(@sel == getarraysize(@id)) Close;

			Mes "["+strnpcinfo(1)+"]";
			Mes "Muito bem, a troca vai ser assim:";
			Mes "por ^FF0000"+@w+"^000000x "+getitemname(@id[@sel]);
			Mes "Eu vou lhe dar ^FF0000"+@a[@sel]+"^000000x "+getitemname(@p[@sel]);
			Mes "Estamos de acordo?";
			next;
				if(select("Sim:Não") == 2) Close;
				if(countitem(@id[@sel]) < @w){
				Mes "["+strnpcinfo(1)+"]";
				Mes "Você não tem "+getitemname(@id[@sel]);
				Mes "suficientes para concluir com a";
				Mes "operação.";
				Close;
				}

				Mes "["+strnpcinfo(1)+"]";
				Mes "Está feito, a troca foi";
				Mes "realizada com sucesso!";
				Close2;
				delitem @id[@sel],@w;
				getitem @p[@sel],@a[@sel];
				end;
		}
}