API tools faq
paste
Advertisement
Guest User

Untitled

a guest
Jan 9th, 2014
112
0
Never
Add comment
Not a member of Pastebin yet? Sign Up, it unlocks many cool features!
text 27.17 KB | None | 0 0
raw download clone embed print report
  1. //===== eAthena Script =======================================================
  2. //= PVP ladder script with dota announcement ( SQL only )
  3. //===== By: ==================================================================
  4. //= ~AnnieRuru~
  5. //===== Current Version: =====================================================
  6. //= 2.9
  7. //===== Compatible With: =====================================================
  8. //= eAthena SQL 14279, with MySQL 5.1
  9. //===== Description: =========================================================
  10. //= PVP ladder store in SQL table
  11. //= plus anti-sit-killer feature
  12. //===== Topic ================================================================
  13. //= http://www.eathena.ws/board/index.php?showtopic=177918
  14. //===== Additional Comments: =================================================
  15. //= still don't have modify value option, will be done ... in next year ...
  16. //============================================================================
  17.  
  18. // add all the maps that you want this script to trigger ... all pvp and event maps perhaps ?
  19. // but if you already enable "all" maps, then can comment all these
  20. cell_game mapflag loadevent
  21.  
  22.  
  23. - script DOTAPVP -1,{
  24. OnInit:
  25. // Config
  26. set .sound, 1; // soundeffect : 0 - disable, 1 - play soundeffect to all players on map, 2 - play soundeffect to an area around the killer, 3 - play soundeffect to killer only
  27. set .announce, 0; // announce to : 0 - global, 1 - map
  28. set .announcemap, 1; // announce the map name in the announcement ? : 0 - off, 1 - on
  29.  
  30. set .announcekill, 0; // announce who pawn who's head : 0 - off, 1 - on
  31. set .msg_die, 1; // show message who kill you when die : 0 - off, 1 - on
  32. set .msg_kill, 0; // show message you kill who when killed someone : 0 - off, 1 - on
  33.  
  34. set .gmnokill, 0; // GMs are not suppose to kill players. A GM with <this number> level or higher will do nothing. IF set to 60, GM60 and above kill any player will not get anything : 0 - off
  35.  
  36. set .killingspree, 3;
  37. set .dominating, 4;
  38. set .megakill, 5;
  39. set .unstoppable, 6;
  40. set .wickedsick, 7;
  41. set .monsterkill, 8;
  42. set .godlike, 9;
  43. set .holyshit, 10;
  44. set .continue, 1; // after beyond-godlike, every <this number> kills will make announcement again
  45.  
  46. set .owned, 5; // how many times the party/guild has to kill to announce ownage
  47. set .owncontinue, 1; // after ownage, every <this number> party/guild cumulative kills will make ownage announce again
  48.  
  49. set .min_gm_menu, 99; // minimum level of GM can use the GM menu on ladder npc
  50.  
  51. set .showtotal, 20; // show the length of ladder. Note : Maximum value = 128
  52. set .showpage, 10; // set the views per page. Note : Maximum value = 128
  53. set .loweststreak, 3; // mininum streak count allow to show in highest streak ladder. Default 3 means must at least have killing spree streak to display in ladder
  54. set .lowestownage, 5; // mininum ownage count allow to show in longest ownage ladder. Default 5 means must at least have 5 ownage counts to display in ladder
  55.  
  56. setarray .maptrigger$, // only these maps will trigger this script
  57. // "all", // uncomment this to allow load all maps
  58. "prtg_cas01",
  59. "payg_cas04",
  60. "gefg_cas02",
  61. "prtg_cas02",
  62. "aldeg_cas02",
  63. "guild_vs1",
  64. "cell_game";
  65.  
  66. // anti-sit-killer system
  67. // a player must kill another player with this minimum <this number> base level to get the announcement and in the ladder.
  68. // Otherwise only have streak ended announcement and killed player's streak reset.
  69. // Its possible for a level 1 novice to kill a level 99 player and he/she will still get in the ladder
  70. // but a level 99 kill a level 1 player will get nothing
  71. // 0 - off this system ( default is 55, pk setting )
  72. set .lvltokill, 0;
  73.  
  74. // when a player kill another same player <this number> times in a row, the player is warp back to save point.
  75. // and the player's streak, kills, and ownage count will deduct accordingly
  76. // 0 - off this system
  77. set .counttopunish, 6;
  78.  
  79. // minimum level range to kill another player
  80. // eg. when set to 20, player level 99 needs to kill another player with minimum level of 79 to get announcement and increase the kill rank.
  81. // but a player with base level 50 kills a level 99 will also get the announcement
  82. // higher base level cannot kill lower level, but lower level can kill higher level
  83. // 0 - off this system
  84. set .minlvlrange, 0;
  85.  
  86.  
  87. // Config ends ------------------------------------------------------------------------------------------
  88.  
  89. // to prevent bug happen
  90. if ( .announce < 0 || .announce > 1 ) set .announce, 0;
  91. if ( .continue < 1 ) set .continue, 1;
  92. if ( .owncontinue < 1 ) set .owncontinue, 1;
  93. if ( .gmnokill <= 0 ) set .gmnokill, 100;
  94. if ( .lvltokill <= 1 ) set .lvltokill, 0;
  95. if ( .counttopunish <= 1 ) set .counttopunish, 0;
  96. set .maptriggersize, getarraysize(.maptrigger$);
  97. end;
  98.  
  99. // script start.
  100. OnPCKillEvent:
  101. if ( getgmlevel() >= .gmnokill ) end;
  102. getmapxy .@map$, .@x, .@y, 0;
  103. if ( .maptrigger$ != "all" ) {
  104. for ( set .@i, 0; .@i < .maptriggersize; set .@i, .@i +1 ) {
  105. if ( .@map$ == .maptrigger$[.@i] ) break;
  106. }
  107. if ( .@i == .maptriggersize ) end;
  108. }
  109. attachrid killedrid;
  110. if ( killerrid != getcharid(3) && ( .msg_die || .msg_kill ) ) {
  111. if ( .msg_die ) message strcharinfo(0),"You have been killed by "+ rid2name(killerrid);
  112. if ( .msg_kill ) message rid2name(killerrid),"You just killed "+ strcharinfo(0);
  113. }
  114. if ( @PlayersKilledStreak >= .holyshit )
  115. set .@streakname$,"Beyond Godlike";
  116. else if ( @PlayersKilledStreak >= .godlike )
  117. set .@streakname$,"Godlike";
  118. else if ( @PlayersKilledStreak >= .monsterkill )
  119. set .@streakname$,"Monster Kill";
  120. else if ( @PlayersKilledStreak >= .wickedsick )
  121. set .@streakname$,"Wicked Sick";
  122. else if ( @PlayersKilledStreak >= .unstoppable )
  123. set .@streakname$,"Unstoppable";
  124. else if ( @PlayersKilledStreak >= .megakill )
  125. set .@streakname$,"Mega-kill";
  126. else if ( @PlayersKilledStreak >= .dominating )
  127. set .@streakname$,"Dominating";
  128. else if ( @PlayersKilledStreak >= .killingspree )
  129. set .@streakname$,"Killing Spree";
  130. if ( @PlayersKilledStreak >= .killingspree && killerrid == getcharid(3) )
  131. announce strcharinfo(0) +" has ended "+( (sex)?"him":"her" )+" own "+ .@streakname$ +"["+ @PlayersKilledStreak +"] streak "+( (.announcemap)?("at "+ .@map$):""),16|.announce;
  132. else if ( @PlayersKilledStreak >= .killingspree )
  133. announce rid2name(killerrid) +" has ended "+ strcharinfo(0) +"'s "+ .@streakname$ +"["+ @PlayersKilledStreak +"] streak "+( (.announcemap)?("at "+ .@map$):""),16|.announce;
  134. else if ( .announcekill && killerrid != getcharid(3) )
  135. announce rid2name(killerrid) +" has pawned "+ strcharinfo(0) +"'s head "+( (.announcemap)?("at "+ .@map$):""),16|.announce;
  136. set @PlayersKilledStreak,0;
  137. set @dota_sql_deaths, @dota_sql_deaths +1;
  138. set @dota_multikills,0;
  139. query_sql "replace into pvpladder values ( "+ getcharid(0) +", '"+ escape_sql(strcharinfo(0)) +"', "+ @dota_sql_streaks +", "+ @dota_sql_kills +", "+ @dota_sql_deaths +", from_unixtime("+ @dota_sql_streaktime +") )";
  140. set .@killed_gid, getcharid(2);
  141. if ( .@killed_gid ) {
  142. setd ".dota_sql_"+ .@killed_gid +"_c", 0;
  143. if ( getd(".dota_sql_"+ .@killed_gid +"_h") )
  144. query_sql "replace into ownladder values ( "+ .@killed_gid +", '"+ escape_sql(getguildname(.@killed_gid)) +"', "+ getd(".dota_sql_"+ .@killed_gid +"_c") +", "+ getd(".dota_sql_"+ .@killed_gid +"_h") +", from_unixtime("+ getd(".dota_sql_"+ .@killed_gid +"_t") +") )";
  145. }
  146. if ( killerrid == getcharid(3) || baselevel < .lvltokill ) end;
  147. if ( .minlvlrange ) set .@killedlvl, baselevel;
  148. attachrid killerrid;
  149. if ( .minlvlrange && .@killedlvl + .minlvlrange < baselevel ) end;
  150. if ( .counttopunish ) {
  151. if ( @sitkillminute != gettime(2) ) {
  152. deletearray @sitkillid, 128;
  153. deletearray @sitkilltimes, 128;
  154. set @sitkillminute, gettime(2);
  155. }
  156. set .@sitkillsize, getarraysize(@sitkillid);
  157. for ( set .@i,0; .@i < .@sitkillsize; set .@i, .@i +1 ) {
  158. if ( @sitkillid[.@i] != killedrid ) continue;
  159. else {
  160. set @sitkilltimes[.@i], @sitkilltimes[.@i] +1 ;
  161. if ( @sitkilltimes[.@i] >= .counttopunish ) {
  162. warp "SavePoint",0,0;
  163. announce strcharinfo(0) +" , Stop killing "+ rid2name(killedrid) + " !!!",0;
  164. debugmes strcharinfo(0) +" is sit-killing "+ rid2name(killedrid) +" for "+ @sitkilltimes[.@i] + " times";
  165. logmes "is sit-killing "+ rid2name(killedrid) +" for "+ @sitkilltimes[.@i] +" times";
  166. if ( @PlayersKilledStreak == @dota_sql_streaks ) {
  167. set @dota_sql_streaks, @dota_sql_streaks +1 - .counttopunish;
  168. set @dota_sql_streaktime, gettimetick(2);
  169. }
  170. set @PlayersKilledStreak, @PlayersKilledStreak +1 - .counttopunish;
  171. set @dota_sql_kills, @dota_sql_kills +1 - .counttopunish;
  172. query_sql "replace into pvpladder values ( "+ getcharid(0) +", '"+ escape_sql(strcharinfo(0)) +"', "+ @dota_sql_streaks +", "+ @dota_sql_kills +", "+ @dota_sql_deaths +", from_unixtime("+ @dota_sql_streaktime +") )";
  173. set .@killer_gid, getcharid(2);
  174. if ( .@killer_gid ) {
  175. if ( getd(".dota_sql_"+ .@killer_gid +"_c") == getd(".dota_sql_"+ .@killer_gid +"_h") ) {
  176. setd ".dota_sql_"+ .@killer_gid +"_h", getd(".dota_sql_"+ .@killer_gid +"_h") +1 - .counttopunish;
  177. setd ".dota_sql_"+ .@killer_gid +"_t", gettimetick(2);
  178. }
  179. setd (".dota_sql_"+ .@killer_gid +"_c"), getd(".dota_sql_"+ .@killer_gid +"_c") +1 - .counttopunish;
  180. query_sql "replace into ownladder values ( "+ .@killer_gid +", '"+ escape_sql(getguildname(.@killer_gid)) +"', "+ getd(".dota_sql_"+ .@killer_gid +"_c") +", "+ getd(".dota_sql_"+ .@killer_gid +"_h") +", from_unixtime("+ getd(".dota_sql_"+ .@killer_gid +"_t") +") )";
  181. }
  182. end;
  183. }
  184. break;
  185. }
  186. }
  187. if ( .@i == .@sitkillsize ) {
  188. set @sitkillid[.@i], killedrid;
  189. set @sitkilltimes[.@i], 1;
  190. }
  191. }
  192. set @PlayersKilledStreak, @PlayersKilledStreak +1 ;
  193. set @dota_sql_kills, @dota_sql_kills +1 ;
  194. if ( @PlayersKilledStreak > @dota_sql_streaks ) {
  195. set @dota_sql_streaks, @PlayersKilledStreak;
  196. set @dota_sql_streaktime, gettimetick(2);
  197. }
  198. query_sql "replace into pvpladder values ( "+ getcharid(0) +", '"+ escape_sql(strcharinfo(0)) +"', "+ @dota_sql_streaks +", "+ @dota_sql_kills +", "+ @dota_sql_deaths +", from_unixtime("+ @dota_sql_streaktime +") )";
  199. if ( @PlayersKilledStreak == .killingspree )
  200. setarray .@streakname$,"killingspree.wav","is on a KILLING SPREE","!";
  201. else if ( @PlayersKilledStreak == .dominating )
  202. setarray .@streakname$,"dominating.wav","is DOMINATING","!";
  203. else if ( @PlayersKilledStreak == .megakill )
  204. setarray .@streakname$,"megakill.wav","has a MEGA KILL","!";
  205. else if ( @PlayersKilledStreak == .unstoppable )
  206. setarray .@streakname$,"unstoppable.wav","is UNSTOPPABLE","!!";
  207. else if ( @PlayersKilledStreak == .wickedsick )
  208. setarray .@streakname$,"wickedsick.wav","is WICKED SICK","!!";
  209. else if ( @PlayersKilledStreak == .monsterkill )
  210. setarray .@streakname$,"monsterkill.wav","has a MONSTER KILL","!!";
  211. else if ( @PlayersKilledStreak == .godlike )
  212. setarray .@streakname$,"godlike.wav","is GODLIKE","!!!";
  213. else if ( @PlayersKilledStreak >= .holyshit && ( (@PlayersKilledStreak - .holyshit) % .continue == 0 ) )
  214. setarray .@streakname$,"holyshit.wav","is BEYOND GODLIKE",". Someone KILL "+( (sex)?"HIM":"HER" ) +"!!!!!!";
  215. if ( .@streakname$[1] != "" ) {
  216. announce strcharinfo(0) +" "+ .@streakname$[1] +"["+ @PlayersKilledStreak +"] "+( (.announcemap)?("at "+ .@map$):"") + .@streakname$[2],16|.announce;
  217. if ( .sound == 1 ) soundeffectall .@streakname$[0],0,.@map$;
  218. else if ( .sound == 2 ) soundeffectall .@streakname$[0],0;
  219. else if ( .sound == 3 ) soundeffect .@streakname$[0],0;
  220. }
  221. set @dota_multikills, @dota_multikills + 1;
  222. deltimer "DOTAPVP::OnStreakReset";
  223. addtimer 18000,"DOTAPVP::OnStreakReset";
  224. set .@killer_gid, getcharid(2);
  225. if ( .@killer_gid && .@killer_gid != .@killed_gid ) {
  226. setd ".dota_sql_"+ .@killer_gid +"_c", getd(".dota_sql_"+ .@killer_gid +"_c") +1 ;
  227. if ( getd(".dota_sql_"+ .@killer_gid +"_c") > getd(".dota_sql_"+ .@killer_gid +"_h") ) {
  228. setd ".dota_sql_"+ .@killer_gid +"_h", getd(".dota_sql_"+ .@killer_gid +"_c");
  229. setd ".dota_sql_"+ .@killer_gid +"_t", gettimetick(2);
  230. }
  231. query_sql "replace into ownladder values ( "+ .@killer_gid +", '"+ escape_sql(getguildname(.@killer_gid)) +"', "+ getd(".dota_sql_"+ .@killer_gid +"_c") +", "+ getd(".dota_sql_"+ .@killer_gid +"_h") +", from_unixtime("+ getd(".dota_sql_"+ .@killer_gid +"_t") +") )";
  232. }
  233. set .@dota_multikills, @dota_multikills;
  234. set .@origin, getcharid(3);
  235. sleep 1500;
  236. if ( .@killer_gid && .@killer_gid != .@killed_gid && getd(".dota_sql_"+ .@killer_gid +"_c") >= .owned && ( ( getd(".dota_sql_"+ .@killer_gid +"_c") - .owned ) % .owncontinue == 0 ) ) {
  237. if ( .announce ) mapannounce .@map$, "The guild ["+ getguildname(.@killer_gid) +"] is OWNING["+ getd(".dota_sql_"+ .@killer_gid +"_c") +"] !!!",16;
  238. else announce "The guild ["+ getguildname(.@killer_gid) +"] is OWNING["+ getd(".dota_sql_"+ .@killer_gid +"_c") +"] !!!",16;
  239. if ( .sound == 1 ) soundeffectall "ownage.wav",0,.@map$;
  240. else if ( .sound == 2 ) soundeffectall "ownage.wav",0;
  241. else if ( .sound == 3 && attachrid(.@origin) ) soundeffect "ownage.wav",0;
  242. }
  243. sleep 1250;
  244. if ( !attachrid(.@origin) ) end;
  245. if ( .@dota_multikills == 2 ) {
  246. if ( .announce ) mapannounce .@map$, strcharinfo(0) +" just got a Double Kill !",16;
  247. else announce strcharinfo(0) +" just got a Double Kill !",16;
  248. if ( .sound == 1 ) soundeffectall "doublekill.wav",0,.@map$;
  249. else if ( .sound == 2 ) soundeffectall "doublekill.wav",0;
  250. else if ( .sound == 3 ) soundeffect "doublekill.wav",0;
  251. }
  252. else if ( .@dota_multikills == 3 ) {
  253. if ( .announce ) mapannounce .@map$, strcharinfo(0) +" just got a Triple Kill !!!",16;
  254. else announce strcharinfo(0) +" just got a Triple Kill !!!",16;
  255. if ( .sound == 1 ) soundeffectall "triplekill.wav",0,.@map$;
  256. else if ( .sound == 2 ) soundeffectall "triplekill.wav",0;
  257. else if ( .sound == 3 ) soundeffect "triplekill.wav",0;
  258. }
  259. else if ( .@dota_multikills == 4 ) {
  260. if ( .announce ) mapannounce .@map$, strcharinfo(0) +" just got a Ultra Kill !!!",16;
  261. else announce strcharinfo(0) +" just got a Ultra Kill !!!",16;
  262. if ( .sound == 1 ) soundeffectall "ultrakill.wav",0,.@map$;
  263. else if ( .sound == 2 ) soundeffectall "ultrakill.wav",0;
  264. else if ( .sound == 3 ) soundeffect "ultrakill.wav",0;
  265. }
  266. else if ( .@dota_multikills >= 5 ) {
  267. if ( .announce ) mapannounce .@map$, strcharinfo(0) +" is on a Rampage !!!",16;
  268. else announce strcharinfo(0) +" is on a Rampage !!!",16;
  269. if ( .sound == 1 ) soundeffectall "rampage.wav",0,.@map$;
  270. else if ( .sound == 2 ) soundeffectall "rampage.wav",0;
  271. else if ( .sound == 3 ) soundeffect "rampage.wav",0;
  272. }
  273. end;
  274. OnStreakReset:
  275. set @dota_multikills, 0;
  276. end;
  277. OnWhisperGlobal:
  278. if ( @spam_dotapvp + 3 >= gettimetick(2) ) // 3 seconds interval so player don spam this command
  279. end;
  280. set @spam_dotapvp, gettimetick(2);
  281. if ( @dota_sql_kills == 0 && @dota_sql_deaths == 0 )
  282. query_sql "select kills, deaths, streaks, unix_timestamp(streaktime) from pvpladder where char_id = "+ getcharid(0), @dota_sql_kills, @dota_sql_deaths, @dota_sql_streaks, @dota_sql_streaktime;
  283. if ( @dota_sql_kills || @dota_sql_deaths ) {
  284. dispbottom "Your current Streak : "+ @PlayersKilledStreak;
  285. dispbottom "Your total Kills : "+ @dota_sql_kills;
  286. dispbottom "Your total Deaths : "+ @dota_sql_deaths;
  287. dispbottom "Your highest Streak : "+ @dota_sql_streaks;
  288. query_sql "select date_format( from_unixtime("+ @dota_sql_streaktime +"),'%a %e/%c/%y %r')", .@time1$;
  289. dispbottom "Your highest Streak on : "+ .@time1$;
  290. }
  291. else
  292. dispbottom "You are not in the pvp ladder yet.";
  293. if ( getcharid(2) ) {
  294. if ( getd(".dota_sql_"+ getcharid(2) +"_h") == 0 ) {
  295. query_sql "select currentown, highestown, unix_timestamp(owntime) from ownladder where guild_id = "+ getcharid(2), .@c, .@h, .@t;
  296. setd ".dota_sql_"+ getcharid(2) +"_c", .@c;
  297. setd ".dota_sql_"+ getcharid(2) +"_h", .@h;
  298. setd ".dota_sql_"+ getcharid(2) +"_t", .@t;
  299. }
  300. if ( getd(".dota_sql_"+ getcharid(2) +"_h") ) {
  301. dispbottom "Your guild current Own : "+ getd(".dota_sql_"+ getcharid(2) +"_c");
  302. dispbottom "Your guild highest Own : "+ getd(".dota_sql_"+ getcharid(2) +"_h");
  303. query_sql "select date_format( from_unixtime("+ getvariableofnpc( getd(".dota_sql_"+ getcharid(2) +"_t"), "DOTAPVP" ) +"),'%a %e/%c/%y %r')", .@time2$;
  304. dispbottom "Your guild highest Own on : "+ .@time2$;
  305. }
  306. else
  307. dispbottom "Your guild is not in the ladder yet.";
  308. }
  309. end;
  310. OnPCLoginEvent:
  311. if ( .maptrigger$ != "all" ) end;
  312. OnPCLoadMapEvent:
  313. if ( @dota_sql_kills == 0 && @dota_sql_deaths == 0 ) {
  314. if ( .maptrigger$ != "all" ) {
  315. getmapxy .@map$, .@x, .@y, 0;
  316. for ( set .@i, 0; .@i < .maptriggersize; set .@i, .@i +1 ) {
  317. if ( .@map$ == .maptrigger$[.@i] ) break;
  318. }
  319. if ( .@i == .maptriggersize ) end;
  320. }
  321. query_sql "select kills, deaths, streaks, unix_timestamp(streaktime) from pvpladder where char_id = "+ getcharid(0), @dota_sql_kills, @dota_sql_deaths, @dota_sql_streaks, @dota_sql_streaktime;
  322. }
  323. if ( getcharid(2) && getd(".dota_sql_"+ getcharid(2) +"_h") == 0 ) {
  324. query_sql "select currentown, highestown, unix_timestamp(owntime) from ownladder where guild_id = "+ getcharid(2), .@c, .@h, .@t;
  325. setd ".dota_sql_"+ getcharid(2) +"_c", .@c;
  326. setd ".dota_sql_"+ getcharid(2) +"_h", .@h;
  327. setd ".dota_sql_"+ getcharid(2) +"_t", .@t;
  328. }
  329. end;
  330. }
  331.  
  332. izlude,133,155,3 script PvP-StatsViewer 57,{
  333. set .@npcname$, strnpcinfo(0);
  334. while (1) {
  335. mes "["+ .@npcname$ +"]";
  336. mes "Hello "+ strcharinfo(0) +"...";
  337. mes "If you want to I can show you your PVP stats.";
  338. next;
  339. switch ( select ( "Most Kills","Highest Streak","Longest Ownage","Own Information","Explanation" ) ) {
  340. case 1:
  341. set .@nb, query_sql("select name, kills, deaths from pvpladder order by kills desc limit "+ getvariableofnpc(.showtotal,"DOTAPVP"), .@name$, .@kills, .@deaths);
  342. if ( .@nb == 0 ) {
  343. mes "["+ .@npcname$ +"]";
  344. mes "The ladder currently is empty.";
  345. next;
  346. }
  347. for ( set .@j,0; .@j < .@nb; set .@j, .@j + getvariableofnpc(.showpage,"DOTAPVP") ) {
  348. mes "["+ .@npcname$ +"]";
  349. for ( set .@i, .@j; .@i < (getvariableofnpc(.showpage,"DOTAPVP") + .@j) && .@i < .@nb; set .@i, .@i + 1 ) {
  350. mes "^996600"+ (.@i+1) +": ^006699"+ .@name$[.@i] +" ^00AA00["+ .@kills[.@i] +"] ^FF0000<"+ .@deaths[.@i] +">^000000";
  351. }
  352. next;
  353. }
  354. break;
  355. case 2:
  356. set .@nb, query_sql("select name, streaks, date_format(streaktime,'%a %e/%c/%y %r') from pvpladder where streaks >= "+ getvariableofnpc(.loweststreak,"DOTAPVP") +" order by streaks desc limit "+ getvariableofnpc(.showtotal,"DOTAPVP"), .@name$, .@streak, .@time$);
  357. if ( .@nb == 0 ) {
  358. mes "["+ .@npcname$ +"]";
  359. mes "The ladder currently is empty.";
  360. next;
  361. }
  362. for ( set .@j,0; .@j < .@nb; set .@j, .@j + getvariableofnpc(.showpage,"DOTAPVP") ) {
  363. mes "["+ .@npcname$ +"]";
  364. for ( set .@i, .@j; .@i < (getvariableofnpc(.showpage,"DOTAPVP") + .@j) && .@i < .@nb; set .@i, .@i + 1 ) {
  365. mes "^996600"+ (.@i+1) +": ^006699"+ .@name$[.@i] +" ^70AC11{"+ .@streak[.@i] +"} ^000000on :";
  366. mes " ^EE8800"+ .@time$[.@i] +"^000000";
  367. }
  368. next;
  369. }
  370. break;
  371. case 3:
  372. set .@nb, query_sql("select name, highestown, date_format(owntime,'%a %e/%c/%y %r') from ownladder where highestown >= "+ getvariableofnpc(.lowestownage,"DOTAPVP") +" order by highestown desc limit "+ getvariableofnpc(.showtotal,"DOTAPVP"), .@name$, .@owned, .@time$);
  373. if ( .@nb == 0 ) {
  374. mes "["+ .@npcname$ +"]";
  375. mes "The ladder currently is empty.";
  376. next;
  377. }
  378. for ( set .@j,0; .@j < .@nb; set .@j, .@j + getvariableofnpc(.showpage,"DOTAPVP") ) {
  379. mes "["+ .@npcname$ +"]";
  380. for ( set .@i, .@j; .@i < (getvariableofnpc(.showpage,"DOTAPVP") + .@j) && .@i < .@nb; set .@i, .@i + 1 ) {
  381. mes "^996600"+ (.@i+1) +": ^006699"+ .@name$[.@i] +" ^00AAAA("+ .@owned[.@i] +") ^000000on :";
  382. mes " ^EE8800"+ .@time$[.@i] +"^000000";
  383. }
  384. next;
  385. }
  386. break;
  387. case 4:
  388. if ( @dota_sql_kills == 0 && @dota_sql_deaths == 0 )
  389. query_sql "select kills, deaths, streaks, unix_timestamp(streaktime), date_format(streaktime,'%a %e/%c/%y %r') from pvpladder where char_id = "+ getcharid(0), @dota_sql_kills, @dota_sql_deaths, @dota_sql_streaks, @dota_sql_streaktime, .@time1$;
  390. mes "["+ .@npcname$ +"]";
  391. if ( @dota_sql_kills == 0 && @dota_sql_deaths == 0 )
  392. mes "You not yet kill any player.";
  393. else {
  394. mes "Your Current Streak : ^70AC11{"+ @PlayersKilledStreak +"}^000000";
  395. mes "Your Total Kills : ^00AA00["+ @dota_sql_kills +"]^000000";
  396. mes "Your Death Counts : ^FF0000<"+ @dota_sql_deaths +">^000000";
  397. if ( @dota_sql_kills || @dota_sql_streaks ) {
  398. mes "Highest Streak was ^70AC11{"+ @dota_sql_streaks +"}^000000 on :";
  399. query_sql "select date_format( from_unixtime("+ @dota_sql_streaktime +"),'%a %e/%c/%y %r')", .@time1$;
  400. mes " ^EE8800"+ .@time1$ +"^000000";
  401. }
  402. }
  403. next;
  404. if ( getcharid(2) ) {
  405. if ( getvariableofnpc( getd(".dota_sql_"+ getcharid(2) +"_h"), "DOTAPVP" ) == 0 ) {
  406. query_sql "select currentown, highestown, unix_timestamp(owntime) from ownladder where guild_id = "+ getcharid(2), .@c, .@h, .@t;
  407. set getvariableofnpc( getd(".dota_sql_"+ getcharid(2) +"_c"), "DOTAPVP" ), .@c;
  408. set getvariableofnpc( getd(".dota_sql_"+ getcharid(2) +"_h"), "DOTAPVP" ), .@h;
  409. set getvariableofnpc( getd(".dota_sql_"+ getcharid(2) +"_t"), "DOTAPVP" ), .@t;
  410. }
  411. mes "["+ .@npcname$ +"]";
  412. if ( getvariableofnpc( getd(".dota_sql_"+ getcharid(2) +"_h"), "DOTAPVP" ) == 0 ) {
  413. mes "Your guild not yet kill any player.";
  414. } else {
  415. mes "Your guild name : ^006699"+ strcharinfo(2) +"^000000";
  416. mes "Current Owning : ^00AAAA("+ getvariableofnpc( getd(".dota_sql_"+ getcharid(2) +"_c"), "DOTAPVP" ) +")^000000";
  417. mes "Longest Ownage was ^00AAAA("+ getvariableofnpc( getd(".dota_sql_"+ getcharid(2) +"_h"), "DOTAPVP" ) + ")^000000 on :";
  418. query_sql "select date_format( from_unixtime("+ getvariableofnpc( getd(".dota_sql_"+ getcharid(2) +"_t"), "DOTAPVP" ) +"),'%a %e/%c/%y %r')", .@time2$;
  419. mes " ^EE8800"+ .@time2$ +"^000000";
  420. }
  421. next;
  422. }
  423. break;
  424. case 5:
  425. mes "["+ .@npcname$ +"]";
  426. mes "Explanation for Most Kills:";
  427. mes " ";
  428. mes "^996600Rank. ^006699NAME ^00AA00[Total Kills] ^FF0000<Deaths>^000000";
  429. mes " ";
  430. mes "--------------------------------";
  431. mes " ";
  432. mes "The ^00AA00Kills^000000 added when a player kills another player.";
  433. mes " ";
  434. mes "^FF0000Deaths^000000 count increase when a player killed by another player, or suicide (eg: Grand Cross).";
  435. mes " ";
  436. mes "A player killed by monsters, homunculus or pets will not add the kills or deaths count.";
  437. next;
  438. mes "["+ .@npcname$ +"]";
  439. mes "Explanation for Highest Streak:";
  440. mes " ";
  441. mes "^996600Rank. ^006699NAME ^70AC11{Highest Streak} ^000000on :";
  442. mes " ^EE8800TIME^000000";
  443. mes " ";
  444. mes "--------------------------------";
  445. mes " ";
  446. mes "The ^70AC11Streak^000000 are added every time a player kills another player. It will reset upon log out, killed by another player, or suicide (eg: Sacrifice).";
  447. mes " ";
  448. mes "Then it record in the server the ^EE8800TIME^000000 when that player got that highest streak.";
  449. mes " ";
  450. mes "A player killed by monsters, homunculus or pets will not reset the streak.";
  451. mes " ";
  452. mes "--------------------------------";
  453. mes " ";
  454. mes "The numbers of straight kills to get these announcements are :";
  455. mes "^70AC11"+ getvariableofnpc(.killingspree,"DOTAPVP") +"^000000 : Killing Spree";
  456. mes "^70AC11"+ getvariableofnpc(.dominating,"DOTAPVP") +"^000000 : Dominating";
  457. mes "^70AC11"+ getvariableofnpc(.megakill,"DOTAPVP") +"^000000 : Mega Kill";
  458. mes "^70AC11"+ getvariableofnpc(.unstoppable,"DOTAPVP") +"^000000 : Unstoppable";
  459. mes "^70AC11"+ getvariableofnpc(.wickedsick,"DOTAPVP") +"^000000 : Wicked Sick";
  460. mes "^70AC11"+ getvariableofnpc(.monsterkill,"DOTAPVP") +"^000000 : Monster Kill";
  461. mes "^70AC11"+ getvariableofnpc(.godlike,"DOTAPVP") +"^000000 : Godlike";
  462. mes "^70AC11"+ getvariableofnpc(.holyshit,"DOTAPVP") +"^000000 : Beyond Godlike";
  463. next;
  464. mes "["+ .@npcname$ +"]";
  465. mes "Explanation for Longest Ownage:";
  466. mes " ";
  467. mes "^996600Rank. ^006699NAME ^00AAAA(Longest Ownage) ^000000on :";
  468. mes " ^EE8800TIME^000000";
  469. mes " ";
  470. mes "--------------------------------";
  471. mes " ";
  472. mes "The ^00AAAAOwnage^000000 added every time any guild members killed another player that doesn't belong to his/her guild. It will reset when any of the guild member was killed by ANY player, including his/her guild member.";
  473. mes " ";
  474. mes "Then it record in the server the ^EE8800TIME^000000 when the guild got that longest ownage.";
  475. mes " ";
  476. mes "If the server went under maintainance, the current ownage will survive after the server restart.";
  477. mes " ";
  478. mes "Any guild member killed by monster, homunculus or pets will not reset the ownage count.";
  479. next;
  480. if ( getvariableofnpc(.lvltokill,"DOTAPVP") ) {
  481. mes "["+ .@npcname$ +"]";
  482. mes "You must kill another player with minimum base level of "+ getvariableofnpc(.lvltokill,"DOTAPVP") +", in order to get an announcement or get in the ladder.";
  483. mes " ";
  484. mes "It's possible for a base level 1 novice kills a base level 99 player and still can get in the ladder.";
  485. mes "However when a player level 99 kills a level 1 novice will get nothing.";
  486. next;
  487. }
  488. if ( getvariableofnpc(.counttopunish,"DOTAPVP") ) {
  489. mes "["+ .@npcname$ +"]";
  490. mes "Some noob players try to kill the same person over and over again in hope of getting his/her name appear in the ladder.";
  491. mes "However if you trying to do the same thing on this ladder, your name will announce to the public, and your action will be recorded into the server to notify the GMs.";
  492. next;
  493. }
  494. if ( getvariableofnpc(.minlvlrange,"DOTAPVP") ) {
  495. mes "["+ .@npcname$ +"]";
  496. mes "When you kill another player thats lower base level than you, the base level gap between you and that player must not more than "+ getvariableofnpc(.minlvlrange,"DOTAPVP") +".";
  497. mes " ";
  498. if ( getvariableofnpc(.minlvlrange,"DOTAPVP") >= 200)
  499. mes "In other words, if your base level is 500, the player you killed must be at least level "+( 500 - getvariableofnpc(.minlvlrange,"DOTAPVP") )+" then only you will get the announcement and in the ladder.";
  500. else if ( getvariableofnpc(.minlvlrange,"DOTAPVP") >= 70)
  501. mes "In other words, if your base level is 255, the player you killed must be at least level "+( 255 - getvariableofnpc(.minlvlrange,"DOTAPVP") )+" then only you will get the announcement and in the ladder.";
  502. else
  503. mes "In other words, if your base level is 99, the player you killed must be at least level "+( 99 - getvariableofnpc(.minlvlrange,"DOTAPVP") )+" then only you will get the announcement and in the ladder.";
  504. mes "Higher base level kills lower level gets nothing, however lower level player kills higher level will get the announcement.";
  505. next;
  506. }
  507. break;
  508. }
  509. }
  510. }
Advertisement
Add Comment
Please, Sign In to add comment
Advertisement
Public Pastes
Advertisement
We use cookies for various purposes including analytics. By continuing to use Pastebin, you agree to our use of cookies as described in the Cookies Policy.  OK, I Understand
Not a member of Pastebin yet?
Sign Up, it unlocks many cool features!