// Author: alastrim

017-2.gat,26,27,0|script|PVP Master|126,{
    if ($@pvp_Status == 1)
        goto L_Existent_Challenge;
    if ($@pvp_Status == 2)
        goto L_During_Countdown;
    if ($@pvp_Status == 3)
        goto L_Existent_Fight;

    mes "[PVP master]";
    mes "\"Do you want to enter the ring?\"";
    next;
    menu
        "Yes", -,
        "No", L_Close;
    mes "\"You need to give me an amount in gold pieces first. Whoever decides to fight you have to deposit the same value. In the end, the one who wins will get all the money.\"";
    next;

L_GetGP:
    input @gp;
    if (@gp <= 0)
        goto L_GetGP;
    if (Zeny < @gp)
        goto L_No_Money;

    mes "[PVP master]";
    mes "\"Good! You have set up a PVP challenge with the minimum requirement of " + @gp + " GP.\"";
    warp "017-2.gat", 26, 23;
    set $@pvp_Status, 1;
    set $@pvp_Price, @gp;
    set $@pvp_StarterID, getcharid(3);
    set $@pvp_StarterName$, strcharinfo(0);
    goto L_Close;

L_During_Countdown:
    end;

L_Existent_Fight:
    // TODO: Create a label that offers the players the option to give up.
    if (getcharid(3) == $@pvp_StarterID || getcharid(3) == $@pvp_ChallengerID)
        goto L_Giveup_Offer;
    mes "[PVP master]";
    mes "\"Enjoy the fight.\"";
    close;

L_Giveup_Offer:
    mes "[PVP master]";
    mes "\"Do you want to give up?\"";
    menu
        "Yes", -,
        "No", L_Close;
    if (getcharid(3) == $@pvp_StarterID)
        set $@pvp_Winner, $@pvp_ChallengerID;
    if (getcharid(3) == $@pvp_ChallengerID)
        set $@pvp_Winner, $@pvp_StarterID;
    close;

L_Cancel_Challenge:
    mes "[PVP master]";
    mes "\"Do you want to cancel your challenge?\"";
    menu
        "Yes", -,
        "No", L_Close;
    close2;
    set Zeny, Zeny + $@pvp_Price;
    goto L_Clear_Vars;

L_Existent_Challenge:
    if ($@pvp_StarterID == getcharid(3))
        goto L_Cancel_Challenge;

    mes "[PVP master]";
    mes "\"Hello. " + $@pvp_StarterName$ + " started a PVP challenge worth " + $@pvp_Price + " Gold Pieces. Do you want to accept?\"";
    next;
    menu
        "Yes.", -,
        "No.", L_Close;
    if (Zeny < $@pvp_Price)
        goto L_No_Money;
    set Zeny, Zeny - $@pvp_Price;
    warp "017-2.gat", 26, 23;
    set $@pvp_Status, 2;
    set $@pvp_ChallengerID, getcharid(3);
    set $@pvp_ChallengerName$, strcharinfo(0);
    set $@pvp_Time, 11;
    initnpctimer;
    goto L_Close;

L_No_Money:
    mes "[PVP master]";
    mes "\"Sorry, but you don't have enough money.\"";
    close;

OnTimer1000:
    if ($@pvp_Status == 2) goto L_Count_Down;
    if ($@pvp_Status == 3) goto L_Handle_Fight;
    goto L_Continue_Timer;

L_Count_Down:
    set $@pvp_Time, $@pvp_Time - 1;

    if ($@pvp_Time == 10)
        npctalk $@pvp_StarterName$ + " Vs " + $@pvp_ChallengerName$ + "!";
    if ($@pvp_Time == 5)
        npctalk "Attention! The fight is starting in...";
    if ($@pvp_Time < 5 && $@pvp_Time > 0)
        npctalk $@pvp_Time;
    if ($@pvp_Time == 0)
        npctalk "Now!";
    if ($@pvp_Time == 0)
        goto L_Start_Fight;

L_Continue_Timer:
    setnpctimer 0;
    end;

L_Start_Fight:
    if (!(isloggedin($@pvp_StarterID)))
        goto L_Starter_Gaveup;
    if (!(isloggedin($@pvp_ChallengerID)))
        goto L_Challenger_Gaveup;

    attachrid($@pvp_StarterID);
    if (!(isin("017-2.gat", 22, 20, 31, 26)))
        goto L_Starter_Gaveup;
    attachrid($@pvp_ChallengerID);
    if (!(isin("017-2.gat", 22, 20, 31, 26)))
        goto L_Challenger_Gaveup;

    attachrid($@pvp_StarterID);
    gmcommand "@charkillable " + strcharinfo(0);
    set @killable, 1;
    attachrid($@pvp_ChallengerID);
    gmcommand "@charkillable " + strcharinfo(0);
    set @killable, 1;

    set $@pvp_Status, 3;
    goto L_Continue_Timer;

L_Handle_Fight:
    if ($@pvp_Winner != 0)
        goto L_End_Fight;

    if (isloggedin($@pvp_StarterID) == 0)
        set $@pvp_Winner, $@pvp_ChallengerID;
    if (isloggedin($@pvp_ChallengerID) == 0)
        set $@pvp_Winner, $@pvp_StarterID;

    attachrid($@pvp_StarterID);
    if (!(isin("017-2.gat", 22, 20, 31, 26)))
        set $@pvp_Winner, $@pvp_ChallengerID;
     if (@killable && !(isin("017-2.gat", 22, 20, 31, 26)))
        gmcommand "@charkillable " + strcharinfo(0);
    attachrid($@pvp_ChallengerID);
    if (!(isin("017-2.gat", 22, 20, 31, 26)))
        set $@pvp_Winner, $@pvp_StarterID;
    if (@killable && !(isin("017-2.gat", 22, 20, 31, 26)))
        gmcommand "@charkillable " + strcharinfo(0);

    goto L_Continue_Timer;

OnPCKilledEvent:
    if ($@pvp_Status != 3)
        end;
    npctalk @killerrid;
    attachrid(@killerrid);
    set $@pvp_Winner, getcharid(3);
    end;

L_Starter_Gaveup:
    npctalk "Sorry, but the player who started the challenge gave up from the fight";
    goto L_Clear_Vars;

L_Challenger_Gaveup:
    npctalk "Challenger gave up from the fight";
    set $@pvp_Time, 0;
    set $@pvp_ChallengerID, 0;
    set $@pvp_ChallengerName$, "";
    set $@pvp_Status, 1;
    end;

L_End_Fight:
    attachrid($@pvp_Winner);
    set Zeny, Zeny + $@pvp_Price * 2;
    npctalk "Congratulations " + strcharinfo(0) + "! You are the winner!";

L_Clear_Vars:
    set $@pvp_Status, 0;
    set $@pvp_Price, 0;
    set $@pvp_Winner, 0;
    set $@pvp_Time, 0;
    set $@pvp_StarterID, 0;
    set $@pvp_StarterName$, "";
    set $@pvp_ChallengerID, 0;
    set $@pvp_ChallengerName$, "";
    areatimer "017-2.gat", 22, 20, 31, 26, 10, "PVP Master::OnCleaning";
    stopnpctimer;
    setnpctimer 0;
    end;

OnCleaning:
    warp "017-2.gat", 26, 28;
    if (@killable)
        gmcommand "@charkillable " + strcharinfo(0);
    end;

L_Close:
    set @gp, 0;
    close;
}