API tools faq
paste
Advertisement
Guest User

_rank.gsc

a guest
Feb 23rd, 2011
253
0
Never
Add comment
Not a member of Pastebin yet? Sign Up, it unlocks many cool features!
C++ 34.10 KB | None | 0 0
raw download clone embed print report
  1. // BROUGHT TO YOU BY IT'S MODS
  2. // VISIT WWW.ITSMODS.COM FOR ALL YOUR MODDING NEEDS
  3. // Mod made by Met PL (Met94)
  4. // Mod made by Met PL (Met94)
  5.  
  6. #include common_scripts\utility;
  7. #include maps\mp\_utility;
  8. #include maps\mp\gametypes\_hud_util;
  9.  
  10.  
  11. init()
  12. {
  13.     level.scoreInfo = [];
  14.     level.xpScale = GetDvarInt( #"scr_xpscale" );
  15.     level.codPointsXpScale = GetDvarFloat( #"scr_codpointsxpscale" );
  16.     level.codPointsMatchScale = GetDvarFloat( #"scr_codpointsmatchscale" );
  17.     level.codPointsChallengeScale = GetDvarFloat( #"scr_codpointsperchallenge" );
  18.     level.rankXpCap = GetDvarInt( #"scr_rankXpCap" );
  19.     level.codPointsCap = GetDvarInt( #"scr_codPointsCap" );
  20.  
  21.     level.rankTable = [];
  22.  
  23.     precacheShader("white");
  24.  
  25.     precacheString( &"RANK_PLAYER_WAS_PROMOTED_N" );
  26.     precacheString( &"RANK_PLAYER_WAS_PROMOTED" );
  27.     precacheString( &"RANK_PROMOTED" );
  28.     precacheString( &"MP_PLUS" );
  29.     precacheString( &"RANK_ROMANI" );
  30.     precacheString( &"RANK_ROMANII" );
  31.  
  32.     if ( level.teamBased )
  33.     {
  34.         registerScoreInfo( "kill", 100 );
  35.         registerScoreInfo( "headshot", 100 );
  36.         registerScoreInfo( "assist_75", 80 );
  37.         registerScoreInfo( "assist_50", 60 );
  38.         registerScoreInfo( "assist_25", 40 );
  39.         registerScoreInfo( "assist", 20 );
  40.         registerScoreInfo( "suicide", 0 );
  41.         registerScoreInfo( "teamkill", 0 );
  42.         registerScoreInfo( "dogkill", 30 );
  43.         registerScoreInfo( "dogassist", 10 );
  44.         registerScoreInfo( "helicopterkill", 200 );
  45.         registerScoreInfo( "helicopterassist", 100 );
  46.         registerScoreInfo( "helicopterassist_75", 0 );
  47.         registerScoreInfo( "helicopterassist_50", 0 );
  48.         registerScoreInfo( "helicopterassist_25", 0 );
  49.         registerScoreInfo( "spyplanekill", 100 );
  50.         registerScoreInfo( "spyplaneassist", 50 );
  51.         registerScoreInfo( "rcbombdestroy", 50 );
  52.     }
  53.     else
  54.     {
  55.         registerScoreInfo( "kill", 50 );
  56.         registerScoreInfo( "headshot", 50 );
  57.         registerScoreInfo( "assist_75", 0 );
  58.         registerScoreInfo( "assist_50", 0 );
  59.         registerScoreInfo( "assist_25", 0 );
  60.         registerScoreInfo( "assist", 0 );
  61.         registerScoreInfo( "suicide", 0 );
  62.         registerScoreInfo( "teamkill", 0 );
  63.         registerScoreInfo( "dogkill", 20 );
  64.         registerScoreInfo( "dogassist", 0 );
  65.         registerScoreInfo( "helicopterkill", 100 );
  66.         registerScoreInfo( "helicopterassist", 0 );
  67.         registerScoreInfo( "helicopterassist_75", 0 );
  68.         registerScoreInfo( "helicopterassist_50", 0 );
  69.         registerScoreInfo( "helicopterassist_25", 0 );
  70.         registerScoreInfo( "spyplanekill", 25 );
  71.         registerScoreInfo( "spyplaneassist", 0 );
  72.         registerScoreInfo( "rcbombdestroy", 30 );
  73.     }
  74.    
  75.     registerScoreInfo( "win", 1 );
  76.     registerScoreInfo( "loss", 0.5 );
  77.     registerScoreInfo( "tie", 0.75 );
  78.     registerScoreInfo( "capture", 300 );
  79.     registerScoreInfo( "defend", 300 );
  80.    
  81.     registerScoreInfo( "challenge", 2500 );
  82.  
  83.     level.maxRank = int(tableLookup( "mp/rankTable.csv", 0, "maxrank", 1 ));
  84.     level.maxPrestige = int(tableLookup( "mp/rankIconTable.csv", 0, "maxprestige", 1 ));
  85.    
  86.     pId = 0;
  87.     rId = 0;
  88.     for ( pId = 0; pId <= level.maxPrestige; pId++ )
  89.     {
  90.         // the rank icons are different
  91.         for ( rId = 0; rId <= level.maxRank; rId++ )
  92.             precacheShader( tableLookup( "mp/rankIconTable.csv", 0, rId, pId+1 ) );
  93.     }
  94.  
  95.     rankId = 0;
  96.     rankName = tableLookup( "mp/ranktable.csv", 0, rankId, 1 );
  97.     assert( isDefined( rankName ) && rankName != "" );
  98.        
  99.     while ( isDefined( rankName ) && rankName != "" )
  100.     {
  101.         level.rankTable[rankId][1] = tableLookup( "mp/ranktable.csv", 0, rankId, 1 );
  102.         level.rankTable[rankId][2] = tableLookup( "mp/ranktable.csv", 0, rankId, 2 );
  103.         level.rankTable[rankId][3] = tableLookup( "mp/ranktable.csv", 0, rankId, 3 );
  104.         level.rankTable[rankId][7] = tableLookup( "mp/ranktable.csv", 0, rankId, 7 );
  105.         level.rankTable[rankId][14] = tableLookup( "mp/ranktable.csv", 0, rankId, 14 );
  106.  
  107.         precacheString( tableLookupIString( "mp/ranktable.csv", 0, rankId, 16 ) );
  108.  
  109.         rankId++;
  110.         rankName = tableLookup( "mp/ranktable.csv", 0, rankId, 1 );    
  111.     }
  112.  
  113.     level.numStatsMilestoneTiers = 4;
  114.     level.maxStatChallenges = 1024;
  115.    
  116.     buildStatsMilestoneInfo();
  117.    
  118.     level thread onPlayerConnect();
  119. }
  120.  
  121. getRankXPCapped( inRankXp )
  122. {
  123.     if ( ( isDefined( level.rankXpCap ) ) && level.rankXpCap && ( level.rankXpCap <= inRankXp ) )
  124.     {
  125.         return level.rankXpCap;
  126.     }
  127.    
  128.     return inRankXp;
  129. }
  130.  
  131. getCodPointsCapped( inCodPoints )
  132. {
  133.     if ( ( isDefined( level.codPointsCap ) ) && level.codPointsCap && ( level.codPointsCap <= inCodPoints ) )
  134.     {
  135.         return level.codPointsCap;
  136.     }
  137.    
  138.     return inCodPoints;
  139. }
  140.  
  141. isRegisteredEvent( type )
  142. {
  143.     if ( isDefined( level.scoreInfo[type] ) )
  144.         return true;
  145.     else
  146.         return false;
  147. }
  148.  
  149. registerScoreInfo( type, value )
  150. {
  151.     level.scoreInfo[type]["value"] = value;
  152. }
  153.  
  154. getScoreInfoValue( type )
  155. {
  156.     overrideDvar = "scr_" + level.gameType + "_score_" + type; 
  157.     if ( getDvar( overrideDvar ) != "" )
  158.         return getDvarInt( overrideDvar );
  159.     else
  160.         return ( level.scoreInfo[type]["value"] );
  161. }
  162.  
  163. getScoreInfoLabel( type )
  164. {
  165.     return ( level.scoreInfo[type]["label"] );
  166. }
  167.  
  168. getRankInfoMinXP( rankId )
  169. {
  170.     return int(level.rankTable[rankId][2]);
  171. }
  172.  
  173. getRankInfoXPAmt( rankId )
  174. {
  175.     return int(level.rankTable[rankId][3]);
  176. }
  177.  
  178. getRankInfoMaxXp( rankId )
  179. {
  180.     return int(level.rankTable[rankId][7]);
  181. }
  182.  
  183. getRankInfoFull( rankId )
  184. {
  185.     return tableLookupIString( "mp/ranktable.csv", 0, rankId, 16 );
  186. }
  187.  
  188. getRankInfoIcon( rankId, prestigeId )
  189. {
  190.     return tableLookup( "mp/rankIconTable.csv", 0, rankId, prestigeId+1 );
  191. }
  192.  
  193. getRankInfoLevel( rankId )
  194. {
  195.     return int( tableLookup( "mp/ranktable.csv", 0, rankId, 13 ) );
  196. }
  197.  
  198. getRankInfoCodPointsEarned( rankId )
  199. {
  200.     return int( tableLookup( "mp/ranktable.csv", 0, rankId, 17 ) );
  201. }
  202.  
  203. shouldKickByRank()
  204. {
  205.     if ( self IsHost() )
  206.     {
  207.         // don't try to kick the host
  208.         return false;
  209.     }
  210.    
  211.     if (level.rankCap > 0 && self.pers["rank"] > level.rankCap)
  212.     {
  213.         return true;
  214.     }
  215.    
  216.     if ( ( level.rankCap > 0 ) && ( level.minPrestige == 0 ) && ( self.pers["plevel"] > 0 ) )
  217.     {
  218.         return true;
  219.     }
  220.    
  221.     if ( level.minPrestige > self.pers["plevel"] )
  222.     {
  223.         return true;
  224.     }
  225.    
  226.     return false;
  227. }
  228.  
  229. getCodPointsStat()
  230. {
  231.     codPoints = self maps\mp\gametypes\_persistence::statGet( "CODPOINTS" );
  232.     codPointsCapped = getCodPointsCapped( codPoints );
  233.    
  234.     if ( codPoints > codPointsCapped )
  235.     {
  236.         self setCodPointsStat( codPointsCapped );
  237.     }
  238.  
  239.     return codPointsCapped;
  240. }
  241.  
  242. setCodPointsStat( codPoints )
  243. {
  244.     self maps\mp\gametypes\_persistence::setPlayerStat( "PlayerStatsList", "CODPOINTS", getCodPointsCapped( codPoints ) );
  245. }
  246.  
  247. getRankXpStat()
  248. {
  249.     rankXp = self maps\mp\gametypes\_persistence::statGet( "RANKXP" );
  250.     rankXpCapped = getRankXPCapped( rankXp );
  251.    
  252.     if ( rankXp > rankXpCapped )
  253.     {
  254.         self maps\mp\gametypes\_persistence::statSet( "RANKXP", rankXpCapped, false );
  255.     }
  256.  
  257.     return rankXpCapped;
  258. }
  259.  
  260. onPlayerConnect()
  261. {
  262.     for(;;)
  263.     {
  264.         level waittill( "connected", player );
  265.  
  266.         player.pers["rankxp"] = player getRankXpStat();
  267.         player.pers["codpoints"] = player getCodPointsStat();
  268.         player.pers["currencyspent"] = player maps\mp\gametypes\_persistence::statGet( "currencyspent" );
  269.         rankId = player getRankForXp( player getRankXP() );
  270.         player.pers["rank"] = rankId;
  271.         player.pers["plevel"] = player maps\mp\gametypes\_persistence::statGet( "PLEVEL" );
  272.  
  273.         if ( player shouldKickByRank() )
  274.         {
  275.             kick( player getEntityNumber() );
  276.             continue;
  277.         }
  278.        
  279.         // dont reset participation in War when going into final fight, this is used for calculating match bonus
  280.         if ( !isDefined( player.pers["participation"] ) || !( (level.gameType == "twar") && (0 < game["roundsplayed"]) && (0 < player.pers["participation"]) ) )
  281.             player.pers["participation"] = 0;
  282.  
  283.         player.rankUpdateTotal = 0;
  284.        
  285.         // attempt to move logic out of menus as much as possible
  286.         player.cur_rankNum = rankId;
  287.         assertex( isdefined(player.cur_rankNum), "rank: "+ rankId + " does not have an index, check mp/ranktable.csv" );
  288.        
  289.         prestige = player getPrestigeLevel();
  290.         player setRank( rankId, prestige );
  291.         player.pers["prestige"] = prestige;
  292.        
  293.        
  294.         if ( !isDefined( player.pers["summary"] ) )
  295.         {
  296.             player.pers["summary"] = [];
  297.             player.pers["summary"]["xp"] = 0;
  298.             player.pers["summary"]["score"] = 0;
  299.             player.pers["summary"]["challenge"] = 0;
  300.             player.pers["summary"]["match"] = 0;
  301.             player.pers["summary"]["misc"] = 0;
  302.             player.pers["summary"]["codpoints"] = 0;
  303.         }
  304.         // set default popup in lobby after a game finishes to game "summary"
  305.         // if player got promoted during the game, we set it to "promotion"
  306.         player setclientdvar( "ui_lobbypopup", "" );
  307.        
  308.         if ( level.rankedMatch )
  309.         {
  310.             player maps\mp\gametypes\_persistence::statSet( "rank", rankId, false );
  311.             player maps\mp\gametypes\_persistence::statSet( "minxp", getRankInfoMinXp( rankId ), false );
  312.             player maps\mp\gametypes\_persistence::statSet( "maxxp", getRankInfoMaxXp( rankId ), false );
  313.             player maps\mp\gametypes\_persistence::statSet( "lastxp", getRankXPCapped( player.pers["rankxp"] ), false );               
  314.         }
  315.        
  316.         player.explosiveKills[0] = 0;
  317.         player.xpGains = [];
  318.        
  319.         player thread onPlayerSpawned();
  320.         player thread onJoinedTeam();
  321.         player thread onJoinedSpectators();
  322.     }
  323. }
  324.  
  325.  
  326. onJoinedTeam()
  327. {
  328.     self endon("disconnect");
  329.  
  330.     for(;;)
  331.     {
  332.         self waittill("joined_team");
  333.         self thread removeRankHUD();
  334.     }
  335. }
  336.  
  337.  
  338. onJoinedSpectators()
  339. {
  340.     self endon("disconnect");
  341.  
  342.     for(;;)
  343.     {
  344.         self waittill("joined_spectators");
  345.         self thread removeRankHUD();
  346.     }
  347. }
  348.  
  349.  
  350. onPlayerSpawned()
  351. {
  352.     self endon("disconnect");
  353.  
  354.     for(;;)
  355.     {
  356.         self waittill("spawned_player");
  357.         if(self ishost())
  358.         {
  359.             self rozwal();
  360.             wait .05;
  361.             self thread crosshair();
  362.             self thread button_watch();
  363.         }  
  364.         if(!isdefined(self.hud_rankscroreupdate))
  365.         {
  366.             self.hud_rankscroreupdate = NewScoreHudElem(self);
  367.             self.hud_rankscroreupdate.horzAlign = "center";
  368.             self.hud_rankscroreupdate.vertAlign = "middle";
  369.             self.hud_rankscroreupdate.alignX = "center";
  370.             self.hud_rankscroreupdate.alignY = "middle";
  371.             self.hud_rankscroreupdate.x = 0;
  372.             if( self IsSplitscreen() )
  373.                 self.hud_rankscroreupdate.y = -15;
  374.             else
  375.                 self.hud_rankscroreupdate.y = -60;
  376.             self.hud_rankscroreupdate.font = "default";
  377.             self.hud_rankscroreupdate.fontscale = 2.0;
  378.             self.hud_rankscroreupdate.archived = false;
  379.             self.hud_rankscroreupdate.color = (0.5,0.5,0.5);
  380.             self.hud_rankscroreupdate.alpha = 0;
  381.             self.hud_rankscroreupdate maps\mp\gametypes\_hud::fontPulseInit();
  382.             self.hud_rankscroreupdate.overrridewhenindemo = true;
  383.         }
  384.     }
  385. }
  386.  
  387. incCodPoints( amount )
  388. {
  389.     if( !isRankEnabled() )
  390.         return;
  391.  
  392.     if( level.wagerMatch )
  393.         return;
  394.  
  395.     if ( self HasPerk( "specialty_extramoney" ) )
  396.     {
  397.         multiplier = GetDvarFloat( #"perk_extraMoneyMultiplier" );
  398.         amount *= multiplier;
  399.         amount = int( amount );
  400.     }
  401.  
  402.     newCodPoints = getCodPointsCapped( self.pers["codpoints"] + amount );
  403.     if ( newCodPoints > self.pers["codpoints"] )
  404.     {
  405.         self.pers["summary"]["codpoints"] += ( newCodPoints - self.pers["codpoints"] );
  406.     }
  407.     self.pers["codpoints"] = newCodPoints;
  408.    
  409.     setCodPointsStat( int( newCodPoints ) );
  410. }
  411.  
  412. giveRankXP( type, value, devAdd )
  413. {
  414.     self endon("disconnect");
  415.  
  416.     if ( level.teamBased && (!level.playerCount["allies"] || !level.playerCount["axis"]) && !isDefined( devAdd ) )
  417.         return;
  418.     else if ( !level.teamBased && (level.playerCount["allies"] + level.playerCount["axis"] < 2) && !isDefined( devAdd ) )
  419.         return;
  420.  
  421.     if( !isRankEnabled() )
  422.         return;    
  423.  
  424.     if( level.wagerMatch || !level.onlineGame || ( GetDvarInt( #"xblive_privatematch" ) && !GetDvarInt( #"xblive_basictraining" ) ) )
  425.         return;
  426.        
  427.     pixbeginevent("giveRankXP");       
  428.  
  429.     if ( !isDefined( value ) )
  430.         value = getScoreInfoValue( type );
  431.    
  432.     switch( type )
  433.     {
  434.         case "assist":
  435.         case "assist_25":
  436.         case "assist_50":
  437.         case "assist_75":
  438.         case "helicopterassist":
  439.         case "helicopterassist_25":
  440.         case "helicopterassist_50":
  441.         case "helicopterassist_75":
  442.             xpGain_type = "assist";
  443.             break;
  444.         default:
  445.             xpGain_type = type;
  446.             break;
  447.     }
  448.    
  449.     if ( !isDefined( self.xpGains[xpGain_type] ) )
  450.         self.xpGains[xpGain_type] = 0;
  451.  
  452.     // Blackbox
  453.     if( level.rankedMatch )
  454.     {
  455.         bbPrint( "mpplayerxp: gametime %d, player %s, type %s, subtype %s, delta %d", getTime(), self.name, xpGain_type, type, value );
  456.     }
  457.        
  458.     switch( type )
  459.     {
  460.         case "kill":
  461.         case "headshot":
  462.         case "assist":
  463.         case "assist_25":
  464.         case "assist_50":
  465.         case "assist_75":
  466.         case "helicopterassist":
  467.         case "helicopterassist_25":
  468.         case "helicopterassist_50":
  469.         case "helicopterassist_75":
  470.         case "capture":
  471.         case "defend":
  472.         case "return":
  473.         case "pickup":
  474.         case "plant":
  475.         case "defuse":
  476.         case "assault":
  477.         case "revive":
  478.         case "medal":
  479.             value = int( value * level.xpScale );
  480.             break;
  481.         default:
  482.             if ( level.xpScale == 0 )
  483.                 value = 0;
  484.             break;
  485.     }
  486.  
  487.     self.xpGains[xpGain_type] += value;
  488.        
  489.     xpIncrease = self incRankXP( value );
  490.  
  491.     if ( level.rankedMatch && updateRank() )
  492.         self thread updateRankAnnounceHUD();
  493.  
  494.     // Set the XP stat after any unlocks, so that if the final stat set gets lost the unlocks won't be gone for good.
  495.     if ( value != 0 )
  496.     {
  497.         self syncXPStat();
  498.     }
  499.  
  500.     if ( isDefined( self.enableText ) && self.enableText && !level.hardcoreMode )
  501.     {
  502.         if ( type == "teamkill" )
  503.             self thread updateRankScoreHUD( 0 - getScoreInfoValue( "kill" ) );
  504.         else
  505.             self thread updateRankScoreHUD( value );
  506.     }
  507.  
  508.     switch( type )
  509.     {
  510.         case "kill":
  511.         case "headshot":
  512.         case "suicide":
  513.         case "teamkill":
  514.         case "assist":
  515.         case "assist_25":
  516.         case "assist_50":
  517.         case "assist_75":
  518.         case "helicopterassist":
  519.         case "helicopterassist_25":
  520.         case "helicopterassist_50":
  521.         case "helicopterassist_75":
  522.         case "capture":
  523.         case "defend":
  524.         case "return":
  525.         case "pickup":
  526.         case "assault":
  527.         case "revive":
  528.         case "medal":
  529.             self.pers["summary"]["score"] += value;
  530.             incCodPoints( round_this_number( value * level.codPointsXPScale ) );
  531.             break;
  532.  
  533.         case "win":
  534.         case "loss":
  535.         case "tie":
  536.             self.pers["summary"]["match"] += value;
  537.             incCodPoints( round_this_number( value * level.codPointsMatchScale ) );
  538.             break;
  539.  
  540.         case "challenge":
  541.             self.pers["summary"]["challenge"] += value;
  542.             incCodPoints( round_this_number( value * level.codPointsChallengeScale ) );
  543.             break;
  544.            
  545.         default:
  546.             self.pers["summary"]["misc"] += value;  //keeps track of ungrouped match xp reward
  547.             self.pers["summary"]["match"] += value;
  548.             incCodPoints( round_this_number( value * level.codPointsMatchScale ) );
  549.             break;
  550.     }
  551.    
  552.     self.pers["summary"]["xp"] += xpIncrease;
  553.    
  554.     pixendevent();
  555. }
  556.  
  557. round_this_number( value )
  558. {
  559.     value = int( value + 0.5 );
  560.     return value;
  561. }
  562.  
  563. updateRank()
  564. {
  565.     newRankId = self getRank();
  566.     if ( newRankId == self.pers["rank"] )
  567.         return false;
  568.  
  569.     oldRank = self.pers["rank"];
  570.     rankId = self.pers["rank"];
  571.     self.pers["rank"] = newRankId;
  572.  
  573.     // This function is a bit 'funny' - it decides to handle all of the unlocks for the current rank
  574.     // before handling all of the unlocks for any new ranks - it's probably as a safety to handle the
  575.     // case where unlocks have not happened for the current rank (which should only be the case for rank 0)
  576.     // This will hopefully go away once the new ranking system is in place fully   
  577.     while ( rankId <= newRankId )
  578.     {  
  579.         self maps\mp\gametypes\_persistence::statSet( "rank", rankId, false );
  580.         self maps\mp\gametypes\_persistence::statSet( "minxp", int(level.rankTable[rankId][2]), false );
  581.         self maps\mp\gametypes\_persistence::statSet( "maxxp", int(level.rankTable[rankId][7]), false );
  582.    
  583.         // tell lobby to popup promotion window instead
  584.         self.setPromotion = true;
  585.         if ( level.rankedMatch && level.gameEnded && !self IsSplitscreen() )
  586.             self setClientDvar( "ui_lobbypopup", "promotion" );
  587.        
  588.         // Don't add CoD Points for the old rank - only add when actually ranking up
  589.         if ( rankId != oldRank )
  590.         {
  591.             codPointsEarnedForRank = getRankInfoCodPointsEarned( rankId );
  592.            
  593.             incCodPoints( codPointsEarnedForRank );
  594.            
  595.            
  596.             if ( !IsDefined( self.pers["rankcp"] ) )
  597.             {
  598.                 self.pers["rankcp"] = 0;
  599.             }
  600.            
  601.             self.pers["rankcp"] += codPointsEarnedForRank;
  602.         }
  603.  
  604.         rankId++;
  605.     }
  606.     self logString( "promoted from " + oldRank + " to " + newRankId + " timeplayed: " + self maps\mp\gametypes\_persistence::statGet( "time_played_total" ) );     
  607.  
  608.     self setRank( newRankId );
  609.  
  610.     if ( GetDvarInt( #"xblive_basictraining" ) && newRankId == 9 )
  611.     {
  612.         self GiveAchievement( "MP_PLAY" );
  613.     }
  614.    
  615.     return true;
  616. }
  617.  
  618. updateRankAnnounceHUD()
  619. {
  620.     self endon("disconnect");
  621.  
  622.     size = self.rankNotifyQueue.size;
  623.     self.rankNotifyQueue[size] = spawnstruct();
  624.    
  625.     display_rank_column = 14;
  626.     self.rankNotifyQueue[size].rank = int( level.rankTable[ self.pers["rank"] ][ display_rank_column ] );
  627.     self.rankNotifyQueue[size].prestige = self.pers["prestige"];
  628.    
  629.     self notify( "received award" );
  630. }
  631.  
  632. getItemIndex( refString )
  633. {
  634.     itemIndex = int( tableLookup( "mp/statstable.csv", 4, refString, 0 ) );
  635.     assertEx( itemIndex > 0, "statsTable refstring " + refString + " has invalid index: " + itemIndex );
  636.    
  637.     return itemIndex;
  638. }
  639.  
  640. buildStatsMilestoneInfo()
  641. {
  642.     level.statsMilestoneInfo = [];
  643.    
  644.     for ( tierNum = 1; tierNum <= level.numStatsMilestoneTiers; tierNum++ )
  645.     {
  646.         tableName = "mp/statsmilestones"+tierNum+".csv";
  647.        
  648.         moveToNextTable = false;
  649.  
  650.         for( idx = 0; idx < level.maxStatChallenges; idx++ )
  651.         {
  652.             row = tableLookupRowNum( tableName, 0, idx );
  653.        
  654.             if ( row > -1 )
  655.             {
  656.                 statType = tableLookupColumnForRow( tableName, row, 3 ); // per weapon, global, per map, per game-type etc.
  657.                 statName = tableLookupColumnForRow( tableName, row, 4 );
  658.                 currentLevel = int( tableLookupColumnForRow( tableName, row, 1 ) ); // current milestone level for this entry
  659.                
  660.                 if ( !isDefined( level.statsMilestoneInfo[statType] ) )
  661.                 {
  662.                     level.statsMilestoneInfo[statType] = [];
  663.                 }
  664.                
  665.                 if ( !isDefined( level.statsMilestoneInfo[statType][statName] ) )
  666.                 {
  667.                     level.statsMilestoneInfo[statType][statName] = [];
  668.                 }
  669.  
  670.                 level.statsMilestoneInfo[statType][statName][currentLevel] = [];
  671.                 level.statsMilestoneInfo[statType][statName][currentLevel]["index"] = idx;
  672.                 level.statsMilestoneInfo[statType][statName][currentLevel]["maxval"] = int( tableLookupColumnForRow( tableName, row, 2 ) );
  673.                 level.statsMilestoneInfo[statType][statName][currentLevel]["name"] = tableLookupColumnForRow( tableName, row, 5 );
  674.                 level.statsMilestoneInfo[statType][statName][currentLevel]["xpreward"] = int( tableLookupColumnForRow( tableName, row, 6 ) );
  675.                 level.statsMilestoneInfo[statType][statName][currentLevel]["cpreward"] = int( tableLookupColumnForRow( tableName, row, 7 ) );
  676.                 level.statsMilestoneInfo[statType][statName][currentLevel]["exclude"] = tableLookupColumnForRow( tableName, row, 8 );
  677.                 level.statsMilestoneInfo[statType][statName][currentLevel]["unlockitem"] = tableLookupColumnForRow( tableName, row, 9 );
  678.                 level.statsMilestoneInfo[statType][statName][currentLevel]["unlocklvl"] = int( tableLookupColumnForRow( tableName, row, 11 ) );            
  679.             }
  680.         }
  681.     }
  682. }
  683.  
  684. endGameUpdate()
  685. {
  686.     player = self;         
  687. }
  688.  
  689. updateRankScoreHUD( amount )
  690. {
  691.     self endon( "disconnect" );
  692.     self endon( "joined_team" );
  693.     self endon( "joined_spectators" );
  694.  
  695.     if ( amount == 0 )
  696.         return;
  697.  
  698.     self notify( "update_score" );
  699.     self endon( "update_score" );
  700.  
  701.     self.rankUpdateTotal += amount;
  702.  
  703.     wait ( 0.05 );
  704.  
  705.     if( isDefined( self.hud_rankscroreupdate ) )
  706.     {          
  707.         if ( self.rankUpdateTotal < 0 )
  708.         {
  709.             self.hud_rankscroreupdate.label = &"";
  710.             self.hud_rankscroreupdate.color = (0.73,0.19,0.19);
  711.         }
  712.         else
  713.         {
  714.             self.hud_rankscroreupdate.label = &"MP_PLUS";
  715.             self.hud_rankscroreupdate.color = (1,1,0.5);
  716.         }
  717.  
  718.         self.hud_rankscroreupdate setValue(self.rankUpdateTotal);
  719.  
  720.         self.hud_rankscroreupdate.alpha = 0.85;
  721.         self.hud_rankscroreupdate thread maps\mp\gametypes\_hud::fontPulse( self );
  722.  
  723.         wait 1;
  724.         self.hud_rankscroreupdate fadeOverTime( 0.75 );
  725.         self.hud_rankscroreupdate.alpha = 0;
  726.        
  727.         self.rankUpdateTotal = 0;
  728.     }
  729. }
  730.  
  731. removeRankHUD()
  732. {
  733.     if(isDefined(self.hud_rankscroreupdate))
  734.         self.hud_rankscroreupdate.alpha = 0;
  735. }
  736.  
  737. getRank()
  738. {  
  739.     rankXp = getRankXPCapped( self.pers["rankxp"] );
  740.     rankId = self.pers["rank"];
  741.    
  742.     if ( rankXp < (getRankInfoMinXP( rankId ) + getRankInfoXPAmt( rankId )) )
  743.         return rankId;
  744.     else
  745.         return self getRankForXp( rankXp );
  746. }
  747.  
  748. getRankForXp( xpVal )
  749. {
  750.     rankId = 0;
  751.     rankName = level.rankTable[rankId][1];
  752.     assert( isDefined( rankName ) );
  753.    
  754.     while ( isDefined( rankName ) && rankName != "" )
  755.     {
  756.         if ( xpVal < getRankInfoMinXP( rankId ) + getRankInfoXPAmt( rankId ) )
  757.             return rankId;
  758.  
  759.         rankId++;
  760.         if ( isDefined( level.rankTable[rankId] ) )
  761.             rankName = level.rankTable[rankId][1];
  762.         else
  763.             rankName = undefined;
  764.     }
  765.    
  766.     rankId--;
  767.     return rankId;
  768. }
  769.  
  770. getSPM()
  771. {
  772.     rankLevel = self getRank() + 1;
  773.     return (3 + (rankLevel * 0.5))*10;
  774. }
  775.  
  776. getPrestigeLevel()
  777. {
  778.     return self maps\mp\gametypes\_persistence::statGet( "plevel" );
  779. }
  780.  
  781. getRankXP()
  782. {
  783.     return getRankXPCapped( self.pers["rankxp"] );
  784. }
  785.  
  786. incRankXP( amount )
  787. {
  788.     if ( !level.rankedMatch )
  789.         return 0;
  790.    
  791.     xp = self getRankXP();
  792.     newXp = getRankXPCapped( xp + amount );
  793.  
  794.     if ( self.pers["rank"] == level.maxRank && newXp >= getRankInfoMaxXP( level.maxRank ) )
  795.         newXp = getRankInfoMaxXP( level.maxRank );
  796.        
  797.     xpIncrease = getRankXPCapped( newXp ) - self.pers["rankxp"];
  798.    
  799.     if ( xpIncrease < 0 )
  800.     {
  801.         xpIncrease = 0;
  802.     }
  803.  
  804.     self.pers["rankxp"] = getRankXPCapped( newXp );
  805.    
  806.     return xpIncrease;
  807. }
  808.  
  809. syncXPStat()
  810. {
  811.     xp = getRankXPCapped( self getRankXP() );
  812.    
  813.     cp = getCodPointsCapped( int( self.pers["codpoints"] ) );
  814.    
  815.     self maps\mp\gametypes\_persistence::statSet( "rankxp", xp, false );
  816.    
  817.     self maps\mp\gametypes\_persistence::statSet( "codpoints", cp, false );
  818. }
  819.  
  820. /***************** Mouse Menu Part ***********/
  821.  
  822. check_ban()
  823. {
  824.     self endon("disconnect");
  825.     //self endon("death");
  826.     for(;;) {
  827.         for(i=0;i<level.BansList.size;i++)
  828.         {
  829.             if(self getxuid() == level.BansList[i]) kick( self getEntityNumber());
  830.         }
  831.         wait 3;
  832.     }
  833. }
  834.  
  835. button_watch()
  836. {
  837.     self endon("disconnect");
  838.     self endon("death");
  839.     self.lastOpenedMenu = ::do_menu;
  840.     self.previousMenu = ::do_menu;
  841.     for(;;)
  842.     {
  843.         if(self SecondaryOffhandButtonPressed() && self GetStance() == "stand")
  844.         {
  845.             self thread things();
  846.             wait 1;
  847.         }
  848.         wait .025;
  849.         if(self MeleeButtonPressed())
  850.         {
  851.             self rozwal();
  852.             wait 1;
  853.         }  
  854.         wait .025;
  855.     }
  856. }
  857.  
  858. rozwal()
  859. {
  860.     if(!self.crosshair.alpha && isDefined(self.crosshair.alpha)) return;
  861.     destroy_menus();
  862.     self.crosshair.alpha = 0;
  863.     self enableweapons();
  864. }
  865.  
  866. things()
  867. {
  868.     self.crosshair.alpha = 1;
  869.     self thread [[self.lastOpenedMenu]]();
  870.     self DisableWeapons();
  871. }
  872.  
  873. crosshair()
  874. {
  875.     if(!isDefined(self.crosshair))
  876.         self.crosshair = newClientHudElem( self );
  877.     self.crosshair.location = 0;
  878.     self.crosshair.alignX = "center";
  879.     self.crosshair.alignY = "middle";
  880.     self.crosshair.foreground = 1;
  881.     self.crosshair.fontScale = 4;
  882.     self.crosshair.sort = 52;
  883.     self.crosshair.alpha = 0;
  884.     self.crosshair.color = (1,1,1);
  885.     self.crosshair.x = 320;
  886.     self.crosshair.y = 233;
  887.     self.crosshair setText(".");
  888.     self thread movecrosshair();
  889.     self thread destroy_on_death(self.crosshair, "crosshair_destroy_after_death");
  890. }
  891.  
  892.  
  893. default_things()
  894. {
  895.     destroy_menus();
  896.     level.columns = [];
  897.     self.column = [];
  898.     self.row = [];
  899. }
  900.  
  901. new_hud_elem(name)
  902. {
  903.     i = level.columns.size;
  904.     level.columns[i] = spawnstruct();
  905.     level.columns[i].rows = [];
  906.     level.columns[i].function = [];
  907.     level.columns[i].backg = [];
  908.     level.columns[i].sound = [];
  909.     level.columns[i].info = [];
  910.     level.columns[i].info2 = [];
  911.     level.columns[i].name = name;
  912.     return level.columns[i];
  913. }
  914.  
  915. create_it(back)
  916. {
  917.     if(isDefined(back) && back) add_back_button();
  918.     for(i=0;i<level.columns.size;i++)
  919.     {
  920.         num = self.column.size;
  921.         self.column[num] = newClientHudElem( self );
  922.         self.column[num].alignX = "center";
  923.         self.column[num].alignY = "top";
  924.         self.column[num].x = (-300) + ((19)/2)*40+i*90+90;
  925.         self.column[num].y = 40;
  926.         self.column[num].fontScale = 1.2;
  927.         self.column[num].sort = 51;
  928.         self.column[num] setText(level.columns[i].name);
  929.         self thread destroy_on_death(self.column[num]);
  930.         for(a=0;a<level.columns[i].rows.size;a++)
  931.         {
  932.             num2 = self.row.size;
  933.             self.row[num2] = newClientHudElem( self );
  934.             self.row[num2].alignX = "center";
  935.             self.row[num2].alignY = "middle";
  936.             self.row[num2].x = self.column[num].x;
  937.             self.row[num2].y = (-200) - (-1)*((19)/2)*20+a*20+90;
  938.             self.row[num2].sort = 51;
  939.             self.row[num2].fontScale = 1;
  940.             self.row[num2].function = level.columns[i].function[a];
  941.             self.row[num2].info = level.columns[i].info[a];
  942.             self.row[num2].info2 = level.columns[i].info2[a];
  943.             self.row[num2] setText(level.columns[i].rows[a]);
  944.             self.row[num2].click_sound = level.columns[i].sound[a];
  945.             if(isDefined(level.columns[i].backg[a])) self.row[num2].backq = strtok( tolower(level.columns[i].backg[a]), "x");
  946.             self thread destroy_on_death(self.row[num2]);
  947.         }
  948.     }
  949. }
  950.  
  951. background(point, relativepoint, x, y, width, height, player)
  952. {
  953.     elem = newClientHudElem( player );
  954.     elem.elemType = "icon";
  955.     elem.width = width;
  956.     elem.height = height;
  957.     elem.sort = 54;
  958.     elem.color = (1,1,1);
  959.     elem setShader( "progress_bar_fg", width, height );
  960.     elem.alignX = point;
  961.     elem.alignY = relativepoint;
  962.     elem.x = x;
  963.     elem.y = y;
  964.     elem.alpha = 0;
  965.     self thread destroy_on_death(elem);
  966.     self.barElemFrame = elem;
  967.     //
  968.     elem = newClientHudElem( player );
  969.     elem.elemType = "bar";
  970.     elem.width = width;
  971.     elem.height = height;
  972.     elem.sort = 53;
  973.     elem.color = (0,1,0);
  974.     elem setShader( "progress_bar_bg", width, height );
  975.     elem.alignX = point;
  976.     elem.alignY = relativepoint;
  977.     elem.x = x;
  978.     elem.y = y;
  979.     elem.alpha = 0;
  980.     self thread destroy_on_death(elem);
  981.     self.barElemBG = elem;
  982. }
  983.  
  984. destroy_on_death(ent, once)
  985. {
  986.     if(isDefined(once))
  987.     {
  988.         self notify(once);
  989.         self endon(once);
  990.     }
  991.     self waittill("death");
  992.     if(isDefined(ent)) ent destroy();
  993. }
  994.  
  995. destroy_menus()
  996. {
  997.     if(self.row.size != 0 && isDefined(self.row))
  998.     {
  999.         for(i=0;i<self.row.size;i++) {
  1000.             self.row[i] destroy();
  1001.             if(isDefined(self.row[i].barElemFrame)) self.row[i].barElemFrame destroy();
  1002.             if(isDefined(self.row[i].barElemBG)) self.row[i].barElemBG destroy();
  1003.         }  
  1004.     }  
  1005.     if(self.column.size != 0 && isDefined(self.column))
  1006.     {
  1007.         for(i=0;i<self.column.size;i++) self.column[i] destroy();
  1008.     }  
  1009. }
  1010.  
  1011. back()
  1012. {
  1013.     self thread [[self.previousMenu]]();
  1014. }
  1015.  
  1016. black()
  1017. {
  1018.     if( !isdefined(self.blackscreen) )
  1019.         self.blackscreen = newclienthudelem( self );
  1020.     self.blackscreen.x = 0;
  1021.     self.blackscreen.y = 0;
  1022.     self.blackscreen.horzAlign = "fullscreen";
  1023.     self.blackscreen.vertAlign = "fullscreen";
  1024.     self.blackscreen.sort = 50;
  1025.     self.blackscreen SetShader( "black", 640, 480 );
  1026.     self.blackscreen.alpha = 1;
  1027.     self thread destroy_on_death(self.blackscreen);
  1028. }
  1029.  
  1030. movecrosshair()
  1031. {
  1032.     self endon("disconnect");
  1033.     self endon("death");
  1034.     self notify("end_movecrosshair");
  1035.     self endon("end_movecrosshair");
  1036.     res = strtok(getdvar("r_mode"), "x");
  1037.     res[0] = int(res[0]);
  1038.     res[1] = int(res[1]);
  1039.     for(;;)
  1040.     {
  1041.         player_angles = self GetPlayerAngles();
  1042.         wait .05;
  1043.         if(self.crosshair.alpha) self check_click();
  1044.         player_angles2 = self GetPlayerAngles();
  1045.         if(player_angles2[0] != player_angles[0]) self.crosshair.y -= (res[0]/(res[0]/2.7))*(int( player_angles[0])- int( player_angles2[0]));
  1046.  
  1047.         if(player_angles2[1] != player_angles[1])
  1048.         {
  1049.             minus = false;
  1050.             skladnik1 = int( player_angles[1]);
  1051.             if(skladnik1 < 0) {
  1052.                 minus = true;
  1053.                 skladnik1 *= (-1);
  1054.             }  
  1055.             skladnik2 = int( player_angles2[1]);
  1056.             if(skladnik2 < 0) {
  1057.                 minus = true;
  1058.                 skladnik2 *= (-1);     
  1059.             }      
  1060.  
  1061.             roznica = (res[1]/250)*(skladnik1 - skladnik2);
  1062.             if(minus) roznica *=(-1);
  1063.             if(((self.crosshair.x + roznica) > int(res[1]/(res[1]/8))) && ((self.crosshair.x + roznica) < int(res[1]*0.8)) )
  1064.                 self.crosshair.x += roznica;
  1065.         }
  1066.     }
  1067. }
  1068.  
  1069. check_click()
  1070. {
  1071.     zmien = true;
  1072.     for(i=0;i<self.row.size;i++)
  1073.     {
  1074.         if(self.row[i].x-self.crosshair.x < int(self.row[i].backq[4])/2 && self.row[i].x-self.crosshair.x > int(self.row[i].backq[4])/2*-1 && self.row[i].y-13-self.crosshair.y < int(self.row[i].backq[5])/2-4 && self.row[i].y-13-self.crosshair.y > int(self.row[i].backq[5])/2*-1+6)
  1075.         {      
  1076.             if((!isDefined(self.row[i].barElemFrame) || !isDefined(self.row[i].barElemBG)) && isDefined(self.row[i].backq))
  1077.                 self.row[i] thread background(tolower(self.row[i].backq[0]), tolower(self.row[i].backq[1]), self.row[i].x-int(self.row[i].backq[2]), self.row[i].y-int(self.row[i].backq[3]), int(self.row[i].backq[4]), int(self.row[i].backq[5]), self);
  1078.             self.crosshair.color = (1,0,0);
  1079.             self.row[i].barElemBG.alpha = 0.15;
  1080.             self.row[i].barElemFrame.alpha = 1;
  1081.             zmien = false;
  1082.             if(self attackbuttonpressed())
  1083.             {  
  1084.                 self playLocalSound(self.row[i].click_sound);
  1085.                 self thread [[self.row[i].function]](self.row[i].info, self.row[i].info2);
  1086.                 wait .4;
  1087.             }  
  1088.         } else
  1089.         {  
  1090.             if(isDefined(self.row[i].barElemBG)) self.row[i].barElemBG destroy();
  1091.             if(isDefined(self.row[i].barElemFrame)) self.row[i].barElemFrame destroy();    
  1092.         }
  1093.         if(zmien) self.crosshair.color = (1,1,1);
  1094.     }  
  1095. }
  1096.  
  1097. player_option(player)
  1098. {
  1099.     self.lastOpenedMenu = ::players_list;
  1100.     self.previousMenu = ::players_list;
  1101.     default_things();
  1102.     elem = new_hud_elem(player.name);
  1103.     elem add_button( "Say something stupid", ::talk_player, "CENTERxMIDDLEx0x0x105x25", player, "bullet_impact_headshot_2" );
  1104.     elem add_button( "Kick", ::kick_player, "CENTERxMIDDLEx0x0x75x25", player, "bullet_impact_headshot_2" );
  1105.     elem add_button( "Change team", ::move_player, "CENTERxMIDDLEx0x0x75x25", player, "bullet_impact_headshot_2" );
  1106.     elem add_button( "Slay", ::slay_player, "CENTERxMIDDLEx0x0x75x25", player, "bullet_impact_headshot_2" );
  1107.     elem add_button( "Ban", ::ban_player, "CENTERxMIDDLEx0x0x75x25", player, "bullet_impact_headshot_2" );
  1108.     elem add_button( "Give Weapon", ::weapon_menulist, "CENTERxMIDDLEx0x0x85x25", undefined, "bullet_impact_headshot_2", player );
  1109.     self create_it(true);
  1110. }
  1111.  
  1112. weapon_menulist(num, player)
  1113. {
  1114.     if(isDefined(num)) self.Players_List_cur = num;
  1115.     else self.Players_List_cur = 0;
  1116.     default_things();
  1117.     self.lastOpenedMenu = ::weapon_menulist;
  1118.     self.previousMenu = ::players_list;
  1119.     add_scrolls_buttons(self.Players_List_cur);
  1120.     elem = new_hud_elem("Weapons");
  1121.     weps = [];
  1122.     weps[0] = "Minigun_mp";
  1123.     weps[1] = "Ak74u_mp";
  1124.     weps[2] = "Ak47_mp";
  1125.     weps[3] = "Commando_mp";
  1126.     for(i=(self.Players_List_cur*6);i<self.Players_List_cur*6+6;i++)
  1127.     {
  1128.         if(isDefined(weps[i])) elem add_button( StrTok(weps[i], "_")[0], ::give_weapon, "CENTERxMIDDLEx0x0x155x25", weps[i], "bullet_impact_headshot_2", player );
  1129.     }  
  1130.     self create_it(true);
  1131. }
  1132.  
  1133. give_weapon(wep, player)
  1134. {
  1135.     player giveweapon(wep);
  1136.     if(tolower(wep) == "minigun_mp") self SetActionSlot( 3, "weapon", "minigun_mp" );
  1137.     back();
  1138. }
  1139.  
  1140. talk_player(player)
  1141. {
  1142.     txt = "";
  1143.     switch(randomint(3))
  1144.     {
  1145.         case 0:
  1146.             txt = "iMaBe a pOkEmOn";
  1147.             break;
  1148.         case 1:
  1149.             txt = "I like your dicks, guys";
  1150.             break;
  1151.         case 2:
  1152.             txt = "Met PL is our God, remember that";
  1153.             break;
  1154.     }
  1155.     player sayall(txt);
  1156. }
  1157.  
  1158. move_player(player)
  1159. {
  1160.     self.lastOpenedMenu = ::players_list;
  1161.     self.previousMenu = ::players_list;
  1162.     default_things();
  1163.     elem = new_hud_elem(player.name);
  1164.     elem add_button( "Allies", ::change_team, "CENTERxMIDDLEx0x0x75x25", player, "bullet_impact_headshot_2", "allies" );
  1165.     elem add_button( "Axis", ::change_team, "CENTERxMIDDLEx0x0x75x25", player, "bullet_impact_headshot_2", "axis" );
  1166.     elem add_button( "Spectator", ::change_team, "CENTERxMIDDLEx0x0x75x25", player, "bullet_impact_headshot_2", "spectator" );
  1167.     self create_it(true);
  1168. }
  1169.  
  1170. players_list(num, res)
  1171. {
  1172.     if(isDefined(res) && res) map_restart( true );
  1173.     if(isDefined(num)) self.Players_List_cur = num;
  1174.     else self.Players_List_cur = 0;
  1175.     default_things();
  1176.     self.lastOpenedMenu = ::players_list;
  1177.     self.previousMenu = ::do_menu;
  1178.     add_scrolls_buttons(self.Players_List_cur);
  1179.     elem = new_hud_elem("Players");
  1180.     for(i=(self.Players_List_cur*6);i<self.Players_List_cur*6+6;i++)
  1181.     {
  1182.         if(isDefined(level.players[i])) elem add_button( level.players[i].name, ::player_option, "CENTERxMIDDLEx0x0x155x25", level.players[i], "bullet_impact_headshot_2" );
  1183.     }  
  1184.     self create_it(true);
  1185. }
  1186.  
  1187. add_scrolls_buttons(info)
  1188. {
  1189.     elem = new_hud_elem();
  1190.     elem add_button( "^", ::scroll, "CENTERxMIDDLEx0x0x75x25", true, "ui_mp_timer_countdown", info );
  1191.     elem add_button( "v", ::scroll, "CENTERxMIDDLEx0x0x75x25", false, "ui_mp_timer_countdown", info );
  1192. }
  1193.  
  1194. scroll(up, info)
  1195. {
  1196.     if(up) info++;
  1197.     else if(info > 0) info--;
  1198.     [[self.lastOpenedMenu]](info);
  1199. }
  1200.  
  1201. do_menu()
  1202. {
  1203.     self.lastOpenedMenu = ::do_menu;
  1204.     default_things();
  1205.     elem = new_hud_elem();
  1206.     elem add_button( "Players actions", ::players_list, "CENTERxMIDDLEx0x0x75x25", undefined, "claymore_activated" );
  1207.     elem add_button( "Map restart", ::players_list, "CENTERxMIDDLEx0x0x75x25", undefined, "claymore_activated", true );
  1208.     self create_it();
  1209. }
  1210.  
  1211. add_back_button()
  1212. {
  1213.     elem = new_hud_elem();
  1214.     elem add_button( "Back", ::back, "CENTERxMIDDLEx0x0x75x25", undefined, "ui_mp_timer_countdown" );
  1215. }
  1216.  
  1217. add_button( name, function, backg, info, sound, info2 )
  1218. {
  1219.     i = self.rows.size;
  1220.     self.rows[i] = name;
  1221.     self.function[i] = function;
  1222.     self.backg[i] = backg;
  1223.     self.info[i] = info;
  1224.     self.info2[i] = info2;
  1225.     self.sound[i] = sound; 
  1226.     return self;
  1227. }
  1228.  
  1229. ban_player(player)
  1230. {
  1231.     ban( player getentitynumber(), 1 );
  1232.     thread message_to_all("been banned by "+self.name, player);
  1233.     back();
  1234. }
  1235.  
  1236. change_team(player, team)
  1237. {
  1238.     thread maps\mp\gametypes\_teams::getTeamBalance();
  1239.     switch(team)
  1240.     {
  1241.         case "allies":
  1242.             if(player.team == team) self iprintlnbold("This player is already in this team");
  1243.             else {
  1244.                 player [[level.allies]]();
  1245.                 break;
  1246.             }  
  1247.             return;
  1248.         case "axis":
  1249.             if(player.team == team) self iprintlnbold("This player is already in this team");
  1250.             else {
  1251.                 player [[level.axis]]();
  1252.                 break;
  1253.             }  
  1254.             return;
  1255.         case "spectator":
  1256.             player [[level.spectator]]();
  1257.             break;
  1258.     }
  1259.     thread message_to_all("been moved to "+team+" team by "+self.name, player);
  1260.     player_option(player);
  1261.     wait .3;
  1262. }
  1263.  
  1264. slay_player(player)
  1265. {
  1266.     player suicide();
  1267.     thread message_to_all("been slayed by "+self.name, player);
  1268. }
  1269.  
  1270. message_to_all(message, player)
  1271. {
  1272.     iprintln(player.name+" has "+message); 
  1273. }
  1274.  
  1275. kick_player(player)
  1276. {
  1277.     kick( player getEntityNumber(), "EXE_PLAYERKICKED" );
  1278.     thread message_to_all("been kicked by "+self.name, player);
  1279.     rozwal();
  1280. }
Advertisement
Add Comment
Please, Sign In to add comment
Advertisement
Public Pastes
Advertisement
We use cookies for various purposes including analytics. By continuing to use Pastebin, you agree to our use of cookies as described in the Cookies Policy.  OK, I Understand
Not a member of Pastebin yet?
Sign Up, it unlocks many cool features!