sample

//******** MAIN TAB

XML xml;
int it = 0;
Query q = new Query();
Prop[] proposicoes;

void setup() {

  q.setAno(2007);
  //q.setDatIni("01/05/2013");
  //q.setDatIni("15/05/2013");
 // q.setNumero(323);
  xml = q.makeQuery();
  XML[] temp_props = xml.getChildren("proposicao");
  proposicoes = new Prop[temp_props.length];
  if (xml != null) {
    for (int i = 0; i < temp_props.length; i++) {
        proposicoes[i] = new Prop(temp_props[i]);
        //println("q.url");
    }
  }
}
 void draw(){}

void keyReleased(){

  switch(key){
    case '.':
   println("\n\n\n\nitem " + it + "\n" + proposicoes[it]);
    if(it < proposicoes.length-1) it++;
    println(it);
    break;

   case ',':
    println("item " + it + "\n" + proposicoes[it]);
    if(it > 0) it--;
    break;
  }
}




//*********  Prop class



//                                                                           \\\\\\\\\
//                                                                           \\\\\\\\\
//                                                                           \\\\\\\\\
///////*************************** Class Prop    ****************************\\\\\\\\\
//                                                                           \\\\\\\\\
//                                                                           \\\\\\\\\
//                                                                           \\\\\\\\\




class Prop{
  int id;
  String nome;
  TipoProp tipoProp;
  int numero;
  int ano;
  OrgaoNum orgaoNum;
  String data;
  String textEmenta;
  String explicaEmenta;
  Regime regime;
  Aprecia aprecia;
  Autor autor;
  int qtdAutores;
  UltDespacho ultDespacho;
  Situa situa;
  String indicGenero;
  int qtdOrgaosComEstado;

  Prop (XML _prop){
    id            = int(_prop.getChild("id").getContent());
    nome          = _prop.getChild("nome").getContent();
    tipoProp      = new TipoProp(_prop.getChild("tipoProposicao"));
    numero        = int(_prop.getChild("numero").getContent());
    ano           = int(_prop.getChild("ano").getContent());
    orgaoNum      = new OrgaoNum(_prop.getChild("orgaoNumerador"));
    data          = _prop.getChild("datApresentacao").getContent();
    textEmenta    = _prop.getChild("txtEmenta").getContent();
    explicaEmenta = _prop.getChild("txtExplicacaoEmenta").getContent();
    regime        = new Regime(_prop.getChild("regime"));
    aprecia       = new Aprecia(_prop.getChild("apreciacao"));
    autor         = new Autor(_prop.getChild("autor1"));
    qtdAutores    = int(_prop.getChild("qtdAutores").getContent());
    ultDespacho   = new UltDespacho(_prop.getChild("ultimoDespacho"));
    situa         = new Situa(_prop.getChild("situacao"));
    indicGenero   = _prop.getChild("indGenero").getContent();
    qtdOrgaosComEstado = int(_prop.getChild("qtdOrgaosComEstado").getContent());
  }



  String toString(){
    return "                  id: " + nf(id,8) + "\n"          +
           "                nome: " + nome + "\n"              +
           "                 ano: " + ano + "\n"               +
           "              numero: " + numero +"\n"             +
           "    Orgão Numerador-> " + orgaoNum + "\n"          +
           "data de apresentação: " + data + "\n"              +
           "     texto da Ementa: " + textEmenta  + "\n"       +
           "   explicação Ementa: " + explicaEmenta +"\n"      +
           "             regime-> " + regime + "\n"            +
           "         apreciação-> " + aprecia + "\n"           +
           "     primeiro autor-> " + autor + "\n"             +
           "   número de autores: " + nf(qtdAutores, 2) + "\n" +
           "    último despacho-> " + ultDespacho +"\n"        +
           "           situação-> " + situa +"\n"             +
           " indicador de gênero: " +indicGenero + "\n"         +
           "qtd orgãos c/ estado: " +nf(qtdOrgaosComEstado, 4);
  }



}//eoc Prop






//                                                                           \\\\\\\\\
//                                                                           \\\\\\\\\
//                                                                           \\\\\\\\\
///////*************************** Field classes ****************************\\\\\\\\\
//                                                                           \\\\\\\\\
//                                                                           \\\\\\\\\
//                                                                           \\\\\\\\\





class TipoProp {
  int tp_id;
  String tp_sigla;
  String tp_nome;
  TipoProp(XML tp) {
    tp_id    = int(tp.getChild("id").getContent());
    tp_sigla = tp.getChild("sigla").getContent();
    tp_nome  = tp.getChild("nome").getContent();
  }
}//eoc TipoProp


//************************


class OrgaoNum {
  int oNum_id;
  String oNum_sigla;
  String oNum_nome;

  OrgaoNum(XML on) {
    oNum_id    = int(on.getChild("id").getContent());
    oNum_sigla = on.getChild("sigla").getContent();
    oNum_nome  = on.getChild("nome").getContent();
  }


  String toString() {
    return "\t   id orgão: " + nf(oNum_id, 8) + "\n" +
           "\t\tsigla orgão: " + oNum_sigla + "\n" +
           "\t\t nome orgão: " + oNum_nome ;
  }
}//eoc Orgao

class Regime {
  int codRegime;
  String textRegime;

  Regime(XML r) {
    codRegime  = int(r.getChild("codRegime").getContent());
    textRegime = r.getChild("txtRegime").getContent();
  }

  String toString() {
    return "\t   código do regime: " + nf(codRegime, 4) + "\n" +
           "\t\t             regime: " + textRegime;
  }
}//eoc Regime

class Aprecia {
  int apr_id;
  String textAprecia;

  Aprecia(XML a) {
    apr_id  = int(a.getChild("id").getContent());
    textAprecia = a.getChild("txtApreciacao").getContent();
  }

  String toString() {
    return "\t   id apreciação: " + nf(apr_id, 4) + "\n" +
           "\t\t      apreciação: " + textAprecia;
  }
}//eoc Aprecia

class Autor {
  String aut_nome;
  int aut_idCadastro;
  int aut_codPart;
  String aut_siglaPartido;
  String aut_uf;

  Autor(XML au) {
    aut_nome         = au.getChild("txtNomeAutor").getContent();
    aut_idCadastro   = int(au.getChild("idecadastro").getContent());
    aut_codPart      = int(au.getChild("codPartido").getContent());
    aut_siglaPartido = au.getChild("txtSiglaPartido").getContent();
    aut_uf           = au.getChild("txtSiglaUF").getContent();
  }


  String toString() {
    return "\t             nome: " + aut_nome + "\n" +
           "\t\t         cadastro: " + nf(aut_idCadastro, 8) + "\n" +
           "\t\tcódigo do Partido: " + nf(aut_codPart, 4) +"\n" +
           "\t\t          partido: " + aut_siglaPartido + "\n"              +
           "\t\t           estado: " + aut_uf
      ;
  }
}//eoc Autor

class UltDespacho {
  String ultD_data;
  String ultD_text;

  UltDespacho(XML ud) {
    ultD_data = ud.getChild("datDespacho").getContent();
    ultD_text = ud.getChild("txtDespacho").getContent();
  }


  String toString() {
    return "\tdata do despacho: " + ultD_data + "\n" +
           "\t\t  texto despacho: " + ultD_text;
  }
}//eoc UltDespacho

class Situa {
  int sit_id;
  String sit_descri;
  Sit_Orgao sit_orgao;
  Sit_Principal principal;

  Situa(XML sit) {
    sit_id             = int(sit.getChild("id").getContent());
    sit_descri         = sit.getChild("descricao").getContent();
    sit_orgao          = new Sit_Orgao(sit.getChild("orgao"));
    principal          = new Sit_Principal(sit.getChild("principal"));
  }


  String toString() {
    return "\t         id situação: " + nf(sit_id, 8) + "\n"    +
           "\t\t           descrição: " + sit_descri + "\n"     +
            sit_orgao + "\n" +
            principal
           ;
  }
}//eoc Situa
class Sit_Orgao {
  int codOrgEstado;
  String siglaOrgEstado;

  Sit_Orgao(XML so) {
    codOrgEstado  = int(so.getChild("codOrgaoEstado").getContent());
    siglaOrgEstado = so.getChild("siglaOrgaoEstado").getContent();
  }
  String toString() {
    return "\t\t código orgão estado: " + nf(codOrgEstado,8) + "\n" +
           "\t\t  sigla orgão estado: " + siglaOrgEstado ;
  }
}//oec Sit_Orgao

class Sit_Principal {
  int codPropPrincipal;
  String propPrincipal;

  Sit_Principal(XML sp) {
    codPropPrincipal  = int(sp.getChild("codProposicaoPrincipal").getContent());
    propPrincipal = sp.getChild("proposicaoPrincipal").getContent();
  }


    String toString() {
    return "\t     código proposição principal: " + nf(codPropPrincipal,8) + "\n" +
           "\t\tproposição principal: " + propPrincipal;
  }
}//eoc Sit_Principal




//********** Query class


class Query {


  String endPoint = "http://www.camara.gov.br/SitCamaraWS/Proposicoes.asmx/ListarProposicoes?";
  final String[] params = {
    "sigla=",
    "&numero=",
    "&ano=",
    "&datApresentacaoIni=",
    "&datApresentacaoFim=",
    "&autor=",
    "&parteNomeAutor=",
    "&siglaPartidoAutor=",
    "&siglaUFAutor=",
    "&generoAutor=",
    "&IdSituacaoProposicao=",
    "&IdOrgaoSituacaoProposicao=&",
    "&codEstado=",
    "&codOrgaoEstado=",
    "&emTramitacao="
  };
  String[] query = new String[params.length];
  int errors = 0;
  XML xml;


  Query() {

    for (int i = 0; i < params.length; i++) {
      query[i] = params[i];
    }
    setSigla("PL");
    setAno(year());
  }//eocontructor 01



  void setSigla(String sigla) {
    query[0] = params[0]+sigla;
  }

  void setNumero(int num) {
    query[1] = params[1]+num;
  }

  void setAno(int ano) {
    String anoString = ""+ano;
    if (anoString.length()== 4 && ano >= 1945 && ano <= year())
      query[2] = params[2]+ano;
    else {
      error(2);
    }
  }

  void setDatIni(String datIni) {
    query[3] = params[3]+datIni;
  }

  void setDatFin(String datFin) {
    query[4] = params[4]+datFin;
  }

  void setAutor(String aut) {
    query[5] = params[5]+aut;
  }

  void setAutIncomp(String autIncomp) {
    query[6] = params[6]+autIncomp;
  }

  void setAutPartido(String autPartido) {
    query[7] = params[7]+autPartido;
  }

  void setAutEstado(String autEstado) {
    query[8] = params[8]+autEstado;
  }

  void setAutGen(String autGen) {
    query[9] = params[9]+autGen;
  }

  void setIdSitua(int idSitua) {
    query[10] = params[10]+idSitua;
  }

  void setIdOrgaoSitua(int idOrgaoSitua) {
    query[11] = params[11]+idOrgaoSitua;
  }

  void setCodEstado(int codEstado) {
    query[12] = params[12]+codEstado;
  }

  void setCodOrgaoEstado(int codOrgaoEstado) {
    query[13] = params[13]+codOrgaoEstado;
  }

  void setCodTramita(int CodTramita) {
    query[14 ] = params[14]+CodTramita;
  }





  XML makeQuery() {
    println("requesting...");
    String temp = endPoint;
    for (int i = 0; i < query.length; i++) {
      temp = temp + query[i];
    }
    println(temp);
    xml = loadXML(temp);
    println("request sucessful!");
    return xml;
  }

  void error(int error) {
    if (error >= 0)
      errors++;

    switch(error) {
    case 2:
      println("O ano deve ser entre 1945 e hoje, com 4 algarismos. Ex: 2010");
      break;

    default:
      println("Aconteceu um erro não identificado. Por Favor confira os dados da pesquisa.");
    }
  }
  /*
  tipo = _tip;
   sigla = _sig;
   numero = _num;
   ano = _ano;
   datIni = _datIni;
   datFin = _datFin;
   aut = _aut;
   autIncomp = _autIncomp;
   autPartido = _autPartido;
   autEstado = _autEstado;
   autGen = _autGen;
   idSitua = _idOrgaoSitua;
   idOrgaoSitua = _idSitua;
   codEstado = _codEstado;
   codOrgaoEstado = _codOrgaoEstado;
   codTramita = _codTramita;
   */
}//eoc Query