--/build.gradle

apply from: 'defaults.gradle'
defaultTasks 'clean', 'build'

--/defaults.gradle

defaultTasks 'build'

repositories {
    mavenCentral()
}

def getAllDependentProjects(project) {
    if ( !project.configurations.hasProperty("runtime") ) {
        return []
    }
    def projectDependencies = project.configurations.runtime.getAllDependencies().withType(ProjectDependency)
    def dependentProjects = projectDependencies*.dependencyProject
    if (dependentProjects.size > 0) {
        dependentProjects.each { dependentProjects += getAllDependentProjects(it) }
    }
    return dependentProjects.unique()
}
gradle.projectsEvaluated {
    if (plugins.hasPlugin('ear')) {
        def deployProjectDependencies = configurations.deploy.getAllDependencies().withType(ProjectDependency)*.dependencyProject
        deployProjectDependencies.each {
            def cur = it
            def cur_deps = getAllDependentProjects(cur)
            def depJars = []
            deployProjectDependencies.each {
                def search = it
                if ( cur_deps.contains(search)) {
                    depJars += search.jar.archiveName
                }
            }
            depJars = depJars.unique()
            if ( depJars.size() > 0 ) {
                logger.info("META-INF Dependencies for deploy dependency " + cur.name + ": " + depJars)
                cur.jar.manifest.attributes(
                    'Class-Path': depJars.join(' ')
                )
            }
        }
    }
}



--/settings.gradle

include 'common-ejb'
include 'project1'
include 'project1-ejb'
include 'logging'

--/logging/build.gradle

apply from: '../defaults.gradle'

apply plugin: 'java'

dependencies {
    compile 'log4j:log4j:1.2.+'
}

--/common-ejb/build.gradle

apply from: '../defaults.gradle'

apply plugin: 'java'

dependencies {
    compile 'javax:javaee-api:6.0'

    compile project(':logging')
}

--/project1-ejb/build.gradle

apply from: '../defaults.gradle'

apply plugin: 'java'

dependencies {
    compile 'javax:javaee-api:6.0'

    compile project(':common-ejb')
    compile project(':logging')
}

--/project1/build.gradle

apply from: '../defaults.gradle'

apply plugin: 'ear'
apply plugin: 'java'

dependencies {
    deploy project(':project1-ejb')
    deploy project(':common-ejb')

    earlib project(':logging')
}